Non so se intendi procedere come suggerito da Flash.
Comunque la cosa e' meno semplice di quanto si pensi.
Al momento ho messo in piedi la stampa dei file del tipo
http://www.lacucinaitaliana.it/stampari ... etta=10987, la cui stampa parte automaticamente al caricamento della pagina.
Devi pero' fare delle impostazioni manuali...
1.Devi avere installata la stampante virtuale PDFCreator
2.Personalizza PDFCreator in modo che stampi automaticamente:
-avvia PDFCreator
-Menu /Stampante /Opzioni; fai click su SalvataggioAutomatico
-spunta Utilizza salvataggio automatico
-spunta Utilizza questa cartella per il salvataggio automatico
-come cartella io ho usato D:\PIPPO\prova\
Puoi usare la cartella che vuoi; la cartella deve gia' esistere e non deve contenere file con nome del tipo 2015*.pdf; lo stesso nome va inserito in una riga del codice macro (vedi avanti)
-conferma con Salva e puoi chiudere la finestra PDFCreator
A questo punto inserisci in un nuovo "Modulo" del tuo file il seguente codice:
- Codice: Seleziona tutto
Dim IE As Object, objPDFCreator As Object
Sub stamparicette()
Dim I As Long, myF As String, myTim As Single
'
Call Shell("rundll32 printui.dll,PrintUIEntry /y /n ""PDFCreator""")
myWait (2)
Set IE = CreateObject("InternetExplorer.Application")
IE.Visible = True
Perc = "D:\PIPPO\prova\" '<<<< La directory di salvataggio automatico
For I = 2 To Cells(Rows.Count, 2).End(xlUp).Row
If Dir(Perc & "2015*.pdf") <> "" Then Stop '**** Vedi Testo
Cells(I, 2).Select
If InStr(1, Cells(I, 2).Value, "stamparicetta.aspx", vbTextCompare) > 0 Then
GetTabs (Cells(I, 2))
myWait (1.5)
Application.SendKeys "^{ENTER}"
myWait (1)
myTim = Timer
remyF:
myF = Dir(Perc & "2015*.pdf")
If myF = "" And Timer < (myTim + 8) Then GoTo remyF
myWait (2.5)
If myF <> "" Then Name (Perc & myF) As (Perc & Cells(I, 1).Value & ".pdf")
'Set IE = Nothing
xxxx = Timer - myTim
' Stop
End If
Next I
IE.Quit
Set IE = Nothing
MsgBox ("Completato...")
End Sub
Sub myWait(myStab As Single)
Dim myStTiM As Single
'
myStTiM = Timer
Do 'wait myStab
DoEvents
If Timer > myStTiM + myStab Or Timer < myStTiM Then Exit Do
Loop
End Sub
Sub GetTabs(ByVal MyUrl As String)
'
If IE Is Nothing Then Set IE = CreateObject("InternetExplorer.Application")
With IE
.navigate MyUrl
.Visible = True
Do While .Busy: DoEvents: Loop 'Attesa not busy
Do While .readyState <> 4: DoEvents: Loop 'Attesa documento
End With
'
myWait (1)
End Sub
Operativamente, da Excel:
Alt-F11 per aprire l' editor delle macro; Menu /Inserisci /Modulo; copia il codice e incollalo nel frame di dx.
La riga marcata <<< deve contenere la stessa directory su cui PDFCreator e' stato impostato per salvare automaticamente
Poi torna in excel, seleziona il foglio con gli indirizzi, lancia la macro " stamparicette": Alt-F8, seleziona stamparicette dall' elenco che ti propone, premi Esegui.
A questo punto la macro:
-apre InternetExplorer, carica la prima pagina, avvia la stampa con il nome file automatico (tipo aaaammgghhmmss.pdf), rinomina quel file con la descrizione di colonna A; ripete con la pagina successiva.
La macro lavora "alla cieca", cioe' assume che la finestra attiva sia quella che lei ha attivato; questo significa che durante tale processo e' meglio non toccare la tastiera o il mouse...
Qualora la macro trovi, prima dell' apertura della prossima pagina web, un file del tipo "2015*.pdf" nella directory di salvataggio, essa si ferma sulla riga marcata ****; in quel caso ispeziona la directory, controlla che il file della riga "Selezionata" sul foglio Excel esista; se non esiste allora probabilmente si tratta del "Rinomina" non andato a buon fine: controlla il contenuto del file pdf e se corrisponde alla riga selezionata fai un Rinomina manuale; altrimenti cancella il file (al massimo ti machera' una ricetta); torna sulla finesta delle macro e premi F5; l' esecuzione dovrebbe continuare.
Tieni presente che ogni ricetta porta via 6-10 secondi (solo quelle processate, cioe' del tipo lacucinaitaliana.it/stamparicetta.aspx)
Se il risultato e' idoneo vedremo come fare con le altre.
Finita la stampa e' opportuno togliere, in PDFCreator /Opzioni, l' impostazione "Utilizza salvataggio automatico"
Ciao