Condividi:        

blocco celle dopo modifica o invio msg + obbligo compilaz

Vuoi potenziare i tuoi documenti Word? Non sai come si fa una macro in Excel? Devi creare una presentazione in PowerPoint?
Oppure sei passato a OpenOffice e non sei sicuro di come lavorare al meglio?

Moderatori: Anthony47, Flash30005

blocco celle dopo modifica o invio msg + obbligo compilaz

Postdi lorenzele » 10/07/17 11:14

Buongiorno,
ho un file xls (2013) che gira su più sistemi operativi che è composto da 32 fogli (31 giorni di calendario + 1 riepilogo).
questo file viene utilizzato dall'ufficio tecnico per segnare le ore che gli uomini fanno nei cantieri.
successivamente il foglio viene stampato dall'ufficio personale per la gestione delle ore per le paghe.
capita che a volte vengano modificati i dati dopo che è stato stampato e non viene informato l'ufficio paghe.
c'è modo per dire ad excel:
1- "ho stampato il foglio ora blocca tutto in modo che non possano essere effettuate modifiche se non digitando una password" (considerando che alcune celle del foglio sono già bloccate per evitare che vengano eliminati riferimenti o formule e queste celle devono restare sempre bloccate)
Oppure:
2- "è stata fatta una modifica sul foglio dopo che era già stato stampato, manda un avviso all'ufficio del personale"

l'ufficio tecnico deve scrivere il cantiere di riferimento in una cella e nella cella sopra deve inserire il codice del cantiere (cosa che spesso non viene fatta...); c'è modo di dire ad excel: "se vedi che in quella cella viene scritto il cantiere, obbliga il geometra a scrivere anche il codice del cantiere nella cella sopra"??

http://www.filedropper.com/07luglio2017copia

grazie e buona giornata
lorenzele
Newbie
 
Post: 9
Iscritto il: 10/07/17 08:32

Sponsor
 

Re: blocco celle dopo modifica o invio msg + obbligo compila

Postdi Anthony47 » 10/07/17 15:59

Una ipotesi per impedire modifiche successive potrebbe essere di trasformare il file, al momento della stampa, in "accessibile in sola lettura".
Questo si puo' ottenere col seguente codice, da inserire nel modulo vba ThisWorkbook /QuestaCartellaDiLavoro:
Codice: Seleziona tutto
Private Sub Workbook_BeforePrint(Cancel As Boolean)
Dim cName As String, cForm As Integer, cPass As Long, Rispo
'
Rispo = MsgBox("Dopo la stampa il file verra' modificato in Sola Lettura" & vbCrLf & _
      "Premere OK per Continuare oppure ANNULLA per Annullare", vbOKCancel, "A V V I S O . . . .")
If Rispo <> vbOK Then
    Cancel = True
    Exit Sub
End If
cName = ThisWorkbook.FullName
cForm = ThisWorkbook.FileFormat
cPass = (Int(Sheets("totale").Range("C2")))
'
Application.DisplayAlerts = False
    ActiveWorkbook.SaveAs Filename:=cName, _
        FileFormat:=cForm, Password:="", WriteResPassword:=cPass, _
        ReadOnlyRecommended:=False, CreateBackup:=False
Application.DisplayAlerts = True
End Sub

Private Sub Workbook_Open()
If ThisWorkbook.ReadOnly Then
    MsgBox ("Il file e' stato gia' stampato e non puo' essere modificato" & vbCrLf & _
        "Se DEVE essere modificato, contattare PIPPO (tel 123-456) per ottenere la password di apertura")
End If
End Sub

Per identificare il modulo ThisWorkbook /QuestaCartellaDiLavoro, da Excel premere Alt-F11 e poi guarda questo messaggio:
viewtopic.php?f=26&t=103893&p=622593#p622593

Modifica il messaggio con il riferimento da contattare per avere la password di apertura del file.
La password inserita e' pari al valore numerico del primo giorno del mese che il file gestisce; per ottenerla basta inserire la data (es 1 lug 2017) in una cella excel e formattare come "Numero". Quindi per il file di Luglio sara' 42917.

Sara' cura di qualcuno rilasciare il file relativo al mese di Agosto senza la password di lettura, in modo che possa essere liberamente usato prima della stampa di fine mese.
Ti ricordo che l'impostazione della password sul file si fa usando il comando "Salva con Nome"; poi usi la casella "Strumenti" (a sx del pulsante Salva) e scegli Opzioni generali...; puoi inserire una password di Lettura (senza la password il file non si apre), oppure una password di Scrittura (senza la password il file puo' essere aperto in sola lettura).


Per evitare che vengano compilate le ore senza le descrizioni del cantiere, prova ad aggiungere questo codice nello stesso modulo
Codice: Seleziona tutto
ThisWorkbook /QuestaCartellaDiLavoro in cui hai inserito il codice precedente:
Private Sub Workbook_SheetChange(ByVal Sh As Object, ByVal Target As Range)
Dim mArea As String
'
mArea = "C5:J35"
If Application.Intersect(Target, Range(mArea)) Is Nothing Then Exit Sub
If Target.Count <> 1 Then Exit Sub
If Cells(4, Target.Column) = "" Or Cells(3, Target.Column) = "" Then
    Application.EnableEvents = False
        Application.Undo
        MsgBox ("Compilare prima la Descrizione del Cantiere, in testa")
        Application.EnableEvents = True
End If
End Sub


Un ultimo commento:
Ho visto che ne foglio Totale, per ottenere le somme usi una formula abbastanza articolata (='1'!N5+'2'!N5+'3'!N5+'4'!N5+etc etc); avresti potuto ottenere lo stesso risultato utilizzando il cosiddetto "indirizzamento 3d", con la formula
Codice: Seleziona tutto
=SOMMA('1:31'!N5)


Ciao
Avatar utente
Anthony47
Moderatore
 
Post: 19181
Iscritto il: 21/03/06 16:03
Località: Ivrea

Re: blocco celle dopo modifica o invio msg + obbligo compila

Postdi lorenzele » 11/07/17 08:34

Grazie Anthony,
1- il codice a livello di cartella di lavoro riguardante l'inserimento obbligatorio del codice cantiere è fantastico!!!
2- per quanto riguarda la formula del foglio di riepilogo, hai pienamente ragione, non ci avevo neanche mai pensato perchè l'ho ereditato così e così l'ho lasciato... ora che ci metto le mani modifico anche quella formula.
3- il codice sempre a livello di cartella di lavoro riguardante il blocco dopo la stampa è "quasi" quello che mi serve. ti direi che è fantastico ma il mio problema è che mi serve un blocco a livello di foglio e non di cartella.
mi spiego:
i geometri aprono ogni sera (a volte anche più volte al giorno) il file sia per inserire le ore sia per controllarle per loro conteggi.
l'ufficio paghe non stampa una sola volta, potrebbe stampare il giorno 5 (stampando i giorni dal 1 al 5 che quindi si dovrebbero "bloccare" lasciando liberi tutti gli altri) ed inserire nelle varie gestioni le ore che i geometri hanno indicato fino a quel giorno, poi potrebbe aprirlo il giorno 8 e stampare le ore che i geometri hanno indicato nei giorni 6 e 7 (si dovrebbero quindi "bloccare" i giorni 6 e 7 senza sbloccare i giorni precedenti ma lasciando liberi gli altri)... e via dicendo...
va da se che non posso bloccargli il file rendendolo in sola lettura e apribile con password.

è possibile modificare il codice che mi hai dato a livello di foglio?? sempre considerando che ci sono celle già bloccate che non si devono sbloccare mai...

Grazie mille,
Elena
lorenzele
Newbie
 
Post: 9
Iscritto il: 10/07/17 08:32

Re: blocco celle dopo modifica o invio msg + obbligo compila

Postdi Anthony47 » 15/07/17 23:43

Mi sembrava di averti chiesto una cosa sulla modalita' di stampa, ma me lo sono sognato...

Allora diciamo che una stampa fatta il giorno 8 protegge tutti i fogli fino al 7.

Per cominciare rimuovi dal modulo ThisWorkbook /QuestaCartellaDiLavoro le Sub Workbook_BeforePrint e Sub Workbook_Open che ti avevo fatto mettere.

Inserisci invece questa:
Codice: Seleziona tutto
Private Sub Workbook_BeforePrint(Cancel As Boolean)
Dim cName As String, cForm As Integer, cPass As Long, Rispo
Dim cuData As Long
'
cuData = Day(Now - 1)
If Month(Sheets(1).Range("G1")) <> Month(Now) Then cuData = 31
If cuData < 1 Then Exit Sub

Rispo = MsgBox("Dopo la stampa verranno protetti i fogli fino al numero " & cuData & vbCrLf & _
      "Premere OK per Continuare oppure ANNULLA per Annullare", vbOKCancel, "A V V I S O . . . .")
If Rispo <> vbOK Then
    Cancel = True
    Exit Sub
End If
On Error Resume Next
For i = 1 To cuData
    Sheets(CStr(i)).Unprotect ("PasswordSegreta")       '<<<La password di protezione/sprotezione
    Sheets(CStr(i)).Range("B5:M35").Locked = True
    Sheets(CStr(i)).Protect ("PasswordSegreta")         '<<<
Next i
On Error GoTo 0
End Sub
Personalizza le righe marcate <<< con la tua password

Poi crea un nuovo modulo vba (Menu /Inserisci /Modulo) e inseriscici questa macro:
Codice: Seleziona tutto
Sub deblock()
Dim KEY As Long
'
KEY = Application.InputBox("Codice di sblocco (da richiedere a sig PincoPalla, tel 123-456789)", , , , , , , 1)
On Error Resume Next
If KEY = Int(Range("G1")) + Application.WorksheetFunction.Weekday(2) Then
    ActiveSheet.Unprotect ("PasswordSegreta")       'La password di protezione/sprotezione
    Range("B5:M35").Locked = False
    ActiveSheet.Protect ("PasswordSegreta")
Else
    MsgBox ("Errore di sprotezione foglio; " & KEY)
End If
On Error GoTo 0
End Sub
Assegna alla macro un tasto di scelta rapida, ad esempio esempio il tasto R (come riabilita); per come farlo guarda la guida on line di Excel, alla voce "Eseguire una macro", e al suo interno cerca "Eseguire una macro premendo un tasto di scelta rapida in combinazione con CTRL"

Con quanto ti ho proposto, la macro Workbook_BeforePrint protegge l'intervallo B5:M35 dei fogli prima della data corrente (tutti, se stampi un file del mese precedente).

La Sub deblock rimuove questa protezione, ma l'esecuzione e' condizionata dal codice inserito in un inputbox: se il codice e' corretto questa protezione aggiuntiva viene rimossa e il foglio puo' essere modificato.
Il codice che abilita la macro si calcola i questo modo:
-Mettere la data che si vuole sbloccare in A2 di un foglio Excel
-Usare poi la formula
Codice: Seleziona tutto
=A2+GIORNO.SETTIMANA(A2;2)


La Sub debloc va eseguita dopo aver attivato il foglio che si vuole modificare; quindi se si vogliono modificare piu' fogli la Sub debloc va eseguita piu' volte, utilizzando su ogni foglio un codice diverso.

Si noti che questo codice non e' quello usato per la protezione, ma solo per l'esecuzione della sub debloc; la vera password va inserita nel codice della Sub debloc e della Sub Workbook_BeforePrint

Ciao
Avatar utente
Anthony47
Moderatore
 
Post: 19181
Iscritto il: 21/03/06 16:03
Località: Ivrea

Re: blocco celle dopo modifica o invio msg + obbligo compila

Postdi lorenzele » 17/07/17 09:55

Buongiorno Anthony,
ho provato le tue ultime istruzioni. Allora:
- "...Per cominciare rimuovi dal modulo ThisWorkbook ...." --> fatto
- "...Inserisci invece questa......." --> fatto
- "...Personalizza le righe marcate <<< ......." --> fatto
- "...Poi crea un nuovo modulo vba......." --> fatto
- "...Assegna alla macro un tasto di scelta rapida......." --> fatto (ctrl+r)
- "...Con quanto ti ho proposto, la macro Workbook_BeforePrint protegge l'intervallo B5:M35 dei fogli prima della data corrente......." --> infatti ho provato a stampare il giorno 8 e mi ha bloccato tutti i fogli fino al giorno 16 (oggi è appunto il 17) mentre dovrebbe bloccare i fogli fino al giorno 8 stesso e lasciare gli altri liberi.
inoltre quando lancio la stampa a video si vedono una serie di movimenti strani (tipo si evidenziano delle celle che poi tornano normali, poi diventa grigio una parte del foglio e poi torna normale... cose strane... immagino che siano i movimenti fatti mentre veniva registrata la macro...)
- "...La Sub deblock rimuove questa protezione......." --> devo aver sbagliato qlc perchè non riesco a farla funzionare... :( :-?

Pensavo che fosse più semplice avere un comando per il blocco/sblocco... :(
in ogni caso ti rimando il file con le modifiche fatte su vba.
http://www.filedropper.com/07luglio2017c
Grazie mille e buona settimana,
Elena
lorenzele
Newbie
 
Post: 9
Iscritto il: 10/07/17 08:32

Re: blocco celle dopo modifica o invio msg + obbligo compila

Postdi Anthony47 » 17/07/17 21:43

Il file ha un unico foglio di calcolo orario, che si chiama Totale.
In assenza di altre informazioni ho immaginato che la stampa riguardasse il foglio Totale.
Poiche' non e' cosi' allora devi spiegare in che cosa consiste il vostro processo di stampa; ad esempio che cosa significa "stampare il foglio 8" (anche se adesso me lo immagino).

Quanto all'esecuzione della Sub debloc, hai fatto tutto giusto, ma devi modificare la riga If KEY come segue:
Codice: Seleziona tutto
If KEY = Int(Range("G1")) + Application.WorksheetFunction.Weekday(Range("G1"), 2) Then


Ciao
Avatar utente
Anthony47
Moderatore
 
Post: 19181
Iscritto il: 21/03/06 16:03
Località: Ivrea

Re: blocco celle dopo modifica o invio msg + obbligo compila

Postdi lorenzele » 18/07/17 11:40

si scusa, pensavo di essermi spiegata meglio sul processo di stampa...

vediamo se riesco a chiarire aggiungendo qlc esempio:
- il file è composto da 32 fogli di cui 31 sono i giorni di calendario ed 1 è il Totale (quindi il foglio 1 è il giorno 1 del mese; il foglio 2 è il giorno 2 del mese e via dicendo...)
- i geometri compilano ogni sera quel file con le ore che gli operai fanno in cantiere (esempio: ieri era il 17 ed hanno compilato il foglio 17 con le ore che gli uomini hanno fatto nei vari cantieri, oggi è il 18 e stasera compileranno il foglio 18 con le ore che gli uomini hanno fatto in quel dato cantiere, domani è il 19 e compileranno alla sera il foglio 19...)
- l'ufficio paghe il 19 mattina potrebbe stampare il foglio 17 ed il foglio 18 inserendo le ore totali del cantiere (vedi riga 36 del foglio) in un altro programma; a questo punto il foglio 17 ed il foglio 18 dovrebbero "bloccarsi" mantenendo "liberi" tutti i successivi fogli/giorni ovvero il giorno 19, il 20, il 21 ecc devono restare compilabili
- le celle del foglio "totale" hanno tutte la spunta su "bloccata" (formato/protezione) perchè è un foglio di riepilogo che servirà ad inizio mese successivo all'ufficio paghe per il totale delle ore ma di fatto è la mera somma di tutti gli altri fogli.

ora ho modificato la sub debloc con il codice che mi hai dato (ho modificato anche i campi da sbloccare che non sono B5:M35 ma sono C5:M35, quindi solo le ore e non la descrizione degli uomini) e facendo tutto il procedimento che mi avevi mandato (altro foglio, scrivere la data in a2, aggiungo la formula, la trasformo in testo) si sblocca.
Domanda: siccome non lo gestirò direttamente io, è possibile gestire la psw di sblocco in maniera più "semplice", meno "trafficosa"?? credo che anche una semplice psw uguale per tutti i fogli e che sia conosciuta solo dalla persona che gestirà il file possa essere sufficente...
Curiosità: ho visto che la sub debloc funziona ma... come si legge il codice?? ovvero se dovessi tradurre quel codice in italiano come si leggerebbe?? così, per curiosità...

ho visto che stampando il foglio si bloccano nuovamente le celle ma rimane la questione che ho scritto ieri: "protegge l'intervallo B5:M35 dei fogli prima della data corrente......." che per la gestione che abbiamo invece non va bene... i fogli che non vengono stampati, devono essere compilabili.

Domanda: per questa questione invece si può fare qualcosa?? "...inoltre quando lancio la stampa a video si vedono una serie di movimenti strani (tipo si evidenziano delle celle che poi tornano normali, poi diventa grigio una parte del foglio e poi torna normale... cose strane... immagino che siano i movimenti fatti mentre veniva registrata la macro...)..."

Spero di aver chiarito il processo che abbiamo di stampa... in caso fammi sapere.
Grazie,
Elena
lorenzele
Newbie
 
Post: 9
Iscritto il: 10/07/17 08:32

Re: blocco celle dopo modifica o invio msg + obbligo compila

Postdi Anthony47 » 19/07/17 02:35

Vediamo se arriviamo alla penultima versione.

Quindi la stampa viene fatta foglio per foglio; quindi la protezione va applicata ai singoli fogli man mano che vengono stampati.
Allo scopo modifichiamo la Sub Workbook_BeforePrint come segue:
Codice: Seleziona tutto
Private Sub Workbook_BeforePrint(Cancel As Boolean)
Dim Rispo
'
Rispo = MsgBox("Dopo la stampa il foglio verra' protetto" & vbCrLf & _
      "Premere OK per Continuare oppure ANNULLA per Annullare", vbOKCancel, "A V V I S O . . . .")
If Rispo <> vbOK Then
    Cancel = True
    Exit Sub
End If
Application.ScreenUpdating = False      '******
On Error Resume Next
    ActiveSheet.Unprotect ("PASSWORD")       '<<<La password di protezione/sprotezione
    ActiveSheet.Range("B5:M35").Locked = True
    ActiveSheet.Protect ("PASSWORD")         '<<<
Application.ScreenUpdating = True       '******
On Error GoTo 0
End Sub
Sostituiscila alla precedente

Non so perche' durante la stampa il pc "si agita"; ho comunque inserito nella mia Sub Workbook_BeforePrint le istruzioni marcate ****** il cui significato leggerai nell'help on line del vba; male non fanno...

Se vuoi una gestione piu' semplice del codice di sblocco, allora usa un codice fisso che l'addetto sul posto conosce e fai affidamento al fatto che avvisera' sempre che i fogli x, y e z saranno modificati.
Per questo ti bastera' modificare la riga If KEY = etc etc in
If KEY = abc Then 'abc e' la chiave numerica fissa ma segreta di abilitazione del deblock


In italiano le due macro si leggono cosi':
1) Workbook_BeforePrint
-se l'utente conferma la stampa, allora
-...sproteggi il foglio corrente (in stampa)
-applica la protezione alle celle B5:M5
-proteggi nuovamente il foglio

2) deblock
-chiedi all'utente il codice numerico di sblocco
-se il codice e' corretto, allora...
-...sproteggi il foglio
-rimuovi la protezione alle celle B5:M5
-proteggi nuovamente il foglio

Ciao
Avatar utente
Anthony47
Moderatore
 
Post: 19181
Iscritto il: 21/03/06 16:03
Località: Ivrea

Re: blocco celle dopo modifica o invio msg + obbligo compila

Postdi lorenzele » 20/07/17 11:40

Buongiorno Anthony,
allora ho rifatto tutto da capo in un altro file perchè a forza di smanettare su quello credo di aver combinato danni e non funzionavano bene le sub.
facendo un paio di prove mi sembra che vada bene, domani faccio qlc altro test e poi ti do conferma in modo da poter chiuedere successivamente il post.
se tutto va come deve andare, sappi che ci saranno due persone molto molto felici :D :D e 3 invece (i geometri ....!!!) un pò meno!!!!! :lol: :lol: :lol: :lol:
Grazie e buona giornata.
Elena
lorenzele
Newbie
 
Post: 9
Iscritto il: 10/07/17 08:32

Re: blocco celle dopo modifica o invio msg + obbligo compila

Postdi lorenzele » 24/07/17 09:48

Buongiorno Anthony,
vediamo se riesco a spiegarmi
1- ho inserito dei dati nel foglio 1, nel foglio 2 e nel foglio 3
2- ho stampato i fogli 1 e 2, è apparso il msg "...verrà protetto..."; mentre il 3 che non ho stampato è rimasto compilabile
3- ho provato ad inserire dati nel foglio 1 e appare il msg di xls "la cella o il grafico che si sta tentando di modificare si trova in un foglio protetto. Per apportare modifiche, fare clic su Rimuovi protezione foglio...."
4- fatto clic su Rimuovi protezione foglio, inserito psw, tornato compilabile ma ovviamente tornato compilabile tutto, anche le celle che hanno il flag su protezione "bloccata"

manca un passaggio che dica al geometra di chiamare l'ufficio paghe per lo sblocco e che quindi permetta all'ufficio paghe di utilizzare la sub deblock perchè non saranno mai i geometri a premere ctrl+r per avviare la deblock.

immaginiamo la scena:
- i geometri compilano il foglio 1
- l'ufficio paghe stampa il foglio 1 che si blocca
- il geometra qlc giorno dopo prova a modificarlo e non riesce
- gli esce il msg di sistema ""la cella o il grafico che si sta tentando di modificare si trova in un foglio protetto........"
:arrow: se per caso ha scoperto la psw da inserire su "rimuovi protezione foglio" potrebbe accidentalmente cancellare qlc formula e cmq non ha un riferimento a cui chiedere
--> mentre se uscisse "il foglio è già stato stampato ed è bloccato, chiamare l'ufficio paghe per sbloccarlo"
:arrow: sarebbe costretto a chiamare l'ufficio paghe e farselo sbloccare

non mi interessa che l'ufficio paghe dica al geometra: "inserisci questa psw".
mi interessa di più che l'ufficio paghe possa dire "ok, chiudi il foglio che te lo sblocco..." in modo che poi possa premere la combinazione ctrl+r e avviare la deblock

secondo te è possibile?? se fosse troppo complesso o troppo lungo da fare, fa lo stesso, anche così com'è lo possiamo utilizzare lo stesso...
Ti ringrazio e buona settimana...
Elena
lorenzele
Newbie
 
Post: 9
Iscritto il: 10/07/17 08:32

Re: blocco celle dopo modifica o invio msg + obbligo compila

Postdi Anthony47 » 24/07/17 23:37

Allora cambiamo vieppiu' la modalita' di gestione....
In un Modulo standard oggi hai il codice della Sub deblock; IN TESTA a questo modulo inserisci questo codice:
Codice: Seleziona tutto
Public deacName As String, ufFlag As Boolean

Sub chiudi()
Unload UserForm1
deacName = ""
ufFlag = False
End Sub

La Sub deblock segue senza modifiche.

Nel modulo ThisWorkbook /QuestaCartellaDiLavoro aggiungi, dopo il codice della Sub Workbook_BeforePrint, questo codice:
Codice: Seleziona tutto
Private Sub Workbook_SheetActivate(ByVal Sh As Object)
If deacName <> "" And ufFlag Then
    Application.EnableEvents = False
        Sheets(deacName).Select
    Application.EnableEvents = True
    Exit Sub
End If
    shnum = CLng(Sh.Name)
    If shnum > 0 And shnum < 32 Then
        If Range("C5").Locked Then
            UserForm1.Show vbModeless
        End If
    End If
End Sub

Private Sub Workbook_SheetDeactivate(ByVal Sh As Object)
deacName = Sh.Name
End Sub

Infine scarica questo file zippato:
https://www.dropbox.com/s/3b2lgx2q61np6 ... 1.zip?dl=0

Estrai dal .zip i due file contenuti, inserendoli ovviamente nella stessa directory.

Vai sul vba del file e importa il file ELE_UserForm1.frm:
-Menu /Importa /File; scegli il file dalla directory in cui l'hai estratto, premi Apri

A questo punto il flusso di controllo sara':
-la stampa di un foglio protegge l'area di input (come prima)
-l'eventuale apertura di un foglio protetto nell'area di input provoca un messaggio informativo, che svanisce dopo 5 secondi.
-la Sub debloc si comporta come prima; puo' essere lanciata da un pulsante presente sul messaggio informativo o come gia' avviene ora.

Nel progetto vba ora e' presente la Userform1: doppioclick sulla scritta per vedere come e' disegnata; premere F7 per vedere il suo codice di gestione: qui potrai modificare il testo del messaggio informativo, per ora solo dimostrativo.

Ciao
Avatar utente
Anthony47
Moderatore
 
Post: 19181
Iscritto il: 21/03/06 16:03
Località: Ivrea

Re: blocco celle dopo modifica o invio msg + obbligo compila

Postdi lorenzele » 25/07/17 10:14

Anthony penso che ce l'hai fatta!!!
Lo metterò in utilizzo da Settembre... ormai tra un pò andiamo in ferie :) :)
magari da agosto potrei far partire il discorso dell'anagrafica dei cantieri obbligatoria e da settembre tutto il resto... giusto per farlo digerire ai geometri un pò alla volta!!! :lol: :lol:
intanto grazie mille e buona giornata!!
Elena
lorenzele
Newbie
 
Post: 9
Iscritto il: 10/07/17 08:32


Torna a Applicazioni Office Windows


Topic correlati a "blocco celle dopo modifica o invio msg + obbligo compilaz":

problema blocco note
Autore: carlin
Forum: Software Windows
Risposte: 7

Chi c’è in linea

Visitano il forum: Nessuno e 62 ospiti