[Excel]Macro per rinominare files in una cartella

[davide73]

Buona sera a tutti! Ho un problema che non riesco a risolvere data la mia incapacità con excel.

Ho una cartella su cui ho centinaia di fotografie che devo rinominare in base ad un elenco di nomi nuovi (codici numerici) che ho su un foglio di excel.

Come faccio?

su una colonna A di excel ho riportato tutti i nomi delle foto e sulla colonna B i nomi nuovi.

Esiste una macro per fare questo lavoro? ho provato con alcune trovate ma non riesco a farle funzionare...non so neanche se le colonne di excel debbano avere qualche proprietà che non ho messo.

Vi prego aiutatemi!

[Anthony47]

Ciao davide73, benvenuto nl forum.
Questa tua domana non l'avevo proprio letta...
Supponiamo che in A1 ci sia il percorso dove si trovano i file attualmente, con lo "slash" (\) finale; in B2 metti il percosro dove vuoi posizionare le immagini.
Da A2 verso il basso ci sono gli attuali nomi file (compreso di estensione); accanto, in B2 verso il basso, ci sono i nuovi nomi file (compreso di estensione).
Prova allora con questa macro:

Codice: Seleziona tutto

Sub rinoma()
Dim myIPath As String, myOPath As String, I As Long
'
myIPath = Range("A1")
myOPath = Range("B1")
For I = 2 To Cells(Rows.Count, 1).End(xlUp).Row
    If Dir(myIPath & Cells(I, "A").Value) = Cells(I, "A").Value Then
        Name myIPath & Cells(I, "A").Value As myOPath & Cells(I, "B").Value
    End If
Next I
End Sub


Da excel: premi Alt-F11 per aprire l' editor delle macro; Menu /Inserisci /Modulo; copia il codice e incollalo nel frame di dx
Compila A1 e B1 e gli elenchi in colonna A e B e lancia poi la Sub Rinoma: dal foglio contenente i dati, premi Alt-F8; seleziona Rinoma dall'elenco macro disponibili, premi Esegui.

La directory di Output deve gia' esistere.

Ciao, fai sapere...

[ROGSBI]

scusatemi, sto provando a fare questa operazione, ma mi dice "impossibile eseguire il codice in modalità interruzione"
come devo fare?

[Anthony47]

Significa che hai gia' avviato una macro che in quel momento ha le istruzioni in stato di interruzione. Completa prima quella macro; oppure fermala definitivamente col tasto "Ripristina" del vba (oppure tramite Menu /Esegui /Ripristina) prima di provare ad avviarne una nuova

Ciao

[xilofono]

scusate se riuppo questa vecchia discussione

la macro rinomina e sposta il file

ma se uno avesse bisogno di rinominare uno stesso file più volte in modi diversi?

poniamo di avere tre file, A B C
che vanno rinominati in:
A -> 1, 2 e 3
B -> 4 e 5
C -> 6

se cercassi di usare questa macro, mettendo più volte nella prima colonna dei file, mi rinominerebbe solo il primo, quindi invece di 6 output (da 1 a 6), ne riuscirei ad avere solo 3 (1, 4 e 6)

[Anthony47]

Quindi tu non vuoi rinominare il file ma vuoi crearne tante copie con nomi diversi...
Che tipo di file sono? Le regole di duplicazione /rinominazione dovo sono scritte?

Ciao

[xilofono]

Quindi tu non vuoi rinominare il file ma vuoi crearne tante copie con nomi diversi...
Che tipo di file sono? Le regole di duplicazione /rinominazione dovo sono scritte?

Ciao

i file sono immagini con estensione .jpg
per le regole, praticamente le medesime della macro già proposta, solo con la possibilità di creare più copie rinominate da uno stesso file
colonna A nell'intestazione la cartella dove son presenti le img e a seguire i nomi dei file di base, nella b nell'intestazione la cartella di destinazione e a seguire i nomi dei file di output

http://www.filedropper.com/rinomina

[Anthony47]

Qualche prova l'ho fatta ma il collaudo devi farlo tu, e non garantisco il risultato:

Codice: Seleziona tutto

Sub copyNrename()
Dim FsO As Object, I As Long
'
Set FsO = VBA.CreateObject("Scripting.FileSystemObject")
Sheets("Rinomina").Select
For I = 2 To Cells(Rows.Count, "A").End(xlUp).Row
    FsO.copyfile Range("A1").Value & Cells(I, 1).Value, Range("B1").Value & Cells(I, 2).Value
Next I
End Sub


Fai sapere

[xilofono]

Qualche prova l'ho fatta ma il collaudo devi farlo tu, e non garantisco il risultato:

Codice: Seleziona tutto

Sub copyNrename()
Dim FsO As Object, I As Long
'
Set FsO = VBA.CreateObject("Scripting.FileSystemObject")
Sheets("Rinomina").Select
For I = 2 To Cells(Rows.Count, "A").End(xlUp).Row
    FsO.copyfile Range("A1").Value & Cells(I, 1).Value, Range("B1").Value & Cells(I, 2).Value
Next I
End Sub


Fai sapere

fa il suo dovere! ti ringrazio!