Valutazione 4.87/ 5 (100.00%) 5838 voti

Condividi:        

Copiare dati da altri file excel

Vuoi potenziare i tuoi documenti Word? Non sai come si fa una macro in Excel? Devi creare una presentazione in PowerPoint?
Oppure sei passato a OpenOffice e non sei sicuro di come lavorare al meglio?

Moderatori: Anthony47, Flash30005

Copiare dati da altri file excel

Postdi Cattivick » 06/02/13 12:28

Ciao a tutti
come da titolo devo riuscire a copiare alcuni dati all'interno di file excel, questi dati sono presenti sempre nella cella B7
e poi dalla cella A14 B14, A15 B15 fino a quando non incontro una cella vuota.
I dati importati devono essere messi tutti sulla stessa riga per ogni singolo file elaborato.
Io ignorante in materia ho copiato spudoratamente questa macro cercando di adattarla al mio caso, ma non riesco a selezionare le celle in questione e copiarle in riga.


Codice: Seleziona tutto
Option Explicit
Public MioFile As String, MioPercorso As String, Wb1 As String, Wb2 As String, UR As Integer

Sub Leggi_File()
    Dim I As Integer
    I = 0
    Application.ScreenUpdating = False
    Foglio1.Select
    [A1] = "cod_im"
    [B1] = "A"
    [C1] = "B"
    [D1] = "C"
    [E1] = "D"
    [F1] = "E"
    [G1] = "F"

    MioPercorso = "C:\Users\administrator\Desktop\gina_elena\" ' << -------------- QUI devi inserire il tuo percorso
    MioFile = Dir(MioPercorso & "*.xls") ' << -------------- Il file che esegue questa macro non deve stare nella stessa cartella dove ci sono i files da importare
    Do While MioFile <> ""
        I = I + 1
       
        Copia_Dati
       
        MioFile = Dir()
    Loop

    Columns("A:A").ColumnWidth = 5
    Columns("B:B").ColumnWidth = 4
    Columns("C:C").ColumnWidth = 45
    Columns("D:D").ColumnWidth = 40
    Columns("E:E").ColumnWidth = 40
    Columns("F:F").ColumnWidth = 40
    Columns("G:G").ColumnWidth = 40
   
    Columns("C:G").Select
    With Selection
        .VerticalAlignment = xlTop
        .WrapText = True
    End With
    [A1].Select
   
    Application.ScreenUpdating = True
    Dim Cell
    For Each Cell In ActiveSheet.UsedRange
    Cell.Value = Replace(Cell.Value, Chr(10), " ")
    Next Cell
    MsgBox "Sono stati COPIATI i dati di   '" & I & "'   file" & Chr(10) & Chr(10) & _
        "presenti nel percorso:  '" & MioPercorso & "'"
End Sub

Sub Copia_Dati()
    Dim Matr1(1 To 7) As Integer
    Wb1 = ActiveWorkbook.Name
    Workbooks.Open Filename:=MioPercorso & MioFile
    Wb2 = ActiveWorkbook.Name
    UR = Range("A" & Rows.Count).End(xlUp).Row
       
    Range("A2", Cells(UR, 7)).Copy
    Windows(Wb1).Activate
    Sheets("Foglio1").Select
    UR = Range("A" & Rows.Count).End(xlUp).Row + 1
    Range("A" & UR).Select
    Selection.PasteSpecial Paste:=xlPasteValues
   
    Windows(Wb2).Activate
    Application.DisplayAlerts = False
    ActiveWindow.Close
    Application.DisplayAlerts = True
    Windows(Wb1).Activate
   
    With Selection
        .VerticalAlignment = xlTop
        .Orientation = 0
        .AddIndent = False
        .IndentLevel = 0
        .ShrinkToFit = False
        .ReadingOrder = xlContext
        .MergeCells = False
    End With
    With Selection
        .HorizontalAlignment = xlLeft
        .VerticalAlignment = xlTop
        .Orientation = 0
        .AddIndent = False
        .IndentLevel = 0
        .ShrinkToFit = False
        .ReadingOrder = xlContext
        .MergeCells = False
    End With

End Sub


Grazie anticipatamente per l'aiuto
Cattivick
Newbie
 
Post: 5
Iscritto il: 06/02/13 12:14

Sponsor
 

Re: Copiare dati da altri file excel

Postdi Anthony47 » 06/02/13 23:11

Ciao Cattivick, benvenuto nel forum.
Quindi riepiloghiamo:
-hai dei file (come sono identificabili?)
-da ognuno di essi vuoi leggere il contenuto delle celle B7, A14, B14, A15, B15, A16, B16 e cosi' in avanti fintanto che una delle celle nella serie sara' trovata vuota.
-il contenuto di queste celle vuoi metterlo sulla riga 2 di un foglio di riepilogo, ognuno in una cella diversa (quindi rispettivamente in A1, B1, C1, etc), per quanto riguarda il file n. 1
-sulla riga 3 (idem come sopra) per il file n. 2
-e cosi' via verso il basso per gli altri file
Il contenuto della macro non l' ho guardato, visto che personalmente non reputo saggio che si cerchi di capire cosa l' utente vuole ottenere decodificando una macro che quelle cose non le fa; ma se confermi quanto interpretato, oppure spieghi esttamente il bisogno, e rispondi anche al quesito sull' identificazione dei file qualcosa ti potremo proporre...

Chiarisci anche quale versione di Excel hai in uso.

Ciao, ti aspettiamo.
Anthony
Win7 + Office 2010 Ita; Win 7 + Office 2013 Ita
Xp + Office 2003 Ita
E voi cosa usate? (per istruzioni vedere viewtopic.php?f=26&t=97449)
Avatar utente
Anthony47
Moderatore
 
Post: 13899
Iscritto il: 21/03/06 16:03
Località: Ivrea

Re: Copiare dati da altri file excel

Postdi Cattivick » 07/02/13 09:23

Grazie Anthony
SI allora mi spiego meglio e mi correggo
i file con i dati sono contenuti in una cartella specifica, questa macro è applicata ad un file excel esterno a questa cartella, richiamando la macro devo riuscire a copiare i dati che mi interessano;
vale a dire B7 e poi da A14 - B14 - A15 - B15 fino a quando non trovo una cella vuota, inoltre dovrei copiare il valore della cella successiva alla cella contenente una parola specifica che anche questa non cambia e cioè "NMDP Codes:"; a questo punto dovrei passare al file successivo
I dati copiati all'esecuzione della macro devono essere visualizzati in questo modo
B7 A14 B14 (valore campo NMDP ....)
B7 A15 B15 (valore campo NMDP ....)
B7 A16 B16 (valore campo NMDP ....) ecc ecc
cosi fino a quando non ho letto tutti i file della cartella.
Spero di essermi spiegato
Ciao e grazie tante ......
Cattivick
Newbie
 
Post: 5
Iscritto il: 06/02/13 12:14

Re: Copiare dati da altri file excel

Postdi Cattivick » 07/02/13 09:37

Per capire meglio ti ho postato un file d'esempio con i dati
Immagine
e questo all'esecuzione della macro
Immagine

ciao e grazie per l'aiuto
Cattivick
Newbie
 
Post: 5
Iscritto il: 06/02/13 12:14

Re: Copiare dati da altri file excel

Postdi Flash30005 » 07/02/13 10:00

Ciao Cattivick e benvenuto nel Forum

Le due immagini da te pubblicate non sono visibili (link errato)
Un buon server host per le immagini è questo previa registrazione tramite email

ciao
Flash
Win7 + Office 2010 Ita
"Fotografica" al servizio dell'immagine

Ottime opportunità di lavoro (part-time o full-time) con guadagni immediati. Info in MP
Avatar utente
Flash30005
Moderatore
 
Post: 8460
Iscritto il: 27/09/07 11:44
Località: Roma +o-


Re: Copiare dati da altri file excel

Postdi Flash30005 » 07/02/13 13:50

Il file Riepilogo inseriscilo nella stessa cartella dei file dati e inserisci in un modulo del file Riepilogo questa macro
Codice: Seleziona tutto
Public perc As String, Ws1 As String, i As Integer, f As String, WB1 As String
Sub ElencoFileXls()
Application.ScreenUpdating = False
Application.Calculation = xlManual
perc = ThisWorkbook.Path
WB1 = ThisWorkbook.Name
Ws1 = "Foglio1"
Worksheets(Ws1).Select
Range("A1").Select
  With ActiveCell
    Worksheets("Foglio1").Range(.Cells(1, 50), .End(xlDown)).ClearContents
  End With
  ElencoFile Direct:=perc, Estens:="*.xls", Inicell:=ActiveCell
    Columns("A:AZ").EntireColumn.AutoFit
    Range("A1").Select
Application.Calculation = xlCalculationAutomatic
Application.ScreenUpdating = True
End Sub
Sub ElencoFile(Direct As String, Estens As String, Inicell As Range)
  Dim i As Integer, f As String
  ChDir Direct
  f = Dir(Estens)
  If f = "" Then Exit Sub
  While f <> ""
    If f <> ThisWorkbook.Name Then
    i = i + 1
        Application.Workbooks.Open perc & "\" & f
        Workbooks(WB1).Worksheets(Ws1).Range("A" & i).Value = Workbooks(f).ActiveSheet.Range("B7").Value
        For RR2 = 14 To 30
            If Workbooks(f).ActiveSheet.Range("A" & RR2).Value <> "" Then
                If Left(Workbooks(f).ActiveSheet.Range("A" & RR2).Value, 4) = "NMDP" Then
                    UC1 = Workbooks(WB1).Worksheets(Ws1).Cells(i, Columns.Count).End(xlToLeft).Column + 1
                    Workbooks(WB1).Worksheets(Ws1).Cells(i, UC1).Value = Workbooks(f).ActiveSheet.Range("B" & RR2).Value
                    GoTo SaltaR
                End If
                UC1 = Workbooks(WB1).Worksheets(Ws1).Cells(i, Columns.Count).End(xlToLeft).Column + 1
                Workbooks(WB1).Worksheets(Ws1).Cells(i, UC1).Value = Workbooks(f).ActiveSheet.Range("A" & RR2).Value
                Workbooks(WB1).Worksheets(Ws1).Cells(i, UC1 + 1).Value = Workbooks(f).ActiveSheet.Range("B" & RR2).Value
            End If
        Next RR2

SaltaR:
        Workbooks(f).Close savechanges:=False
    End If
    f = Dir
  Wend
End Sub


Avvia la macro "ElencoFileXls"

ciao
Flash
Win7 + Office 2010 Ita
"Fotografica" al servizio dell'immagine

Ottime opportunità di lavoro (part-time o full-time) con guadagni immediati. Info in MP
Avatar utente
Flash30005
Moderatore
 
Post: 8460
Iscritto il: 27/09/07 11:44
Località: Roma +o-

Re: Copiare dati da altri file excel

Postdi Anthony47 » 07/02/13 15:05

Flash, la tua macro produce un output come da richiesta iniziale (una riga per ogni file), mentre nei messaggi successivi la richiesta e' stata modificata.
Una macro come questa dovrebbe fare il lavoro:
Codice: Seleziona tutto
Sub ppp()
myDir = "C:\Users\User\Desktop\Dir\Subdir\"   '<<< La tua dir, con \ finale
myFile = Dir(myDir & "*.xls*")
Do While myFile <> ""
If myFile = ThisWorkbook.Name then Goto nextF
    Workbooks.Open (myDir & myFile)
    myCB7 = [B7]
    myNMDP = Application.Match("NMDP Codes:", Range("A1:A10000"), 0)
    If IsError(myNMDP) Then GoTo skipF    'skip file se missing NMDP
    myNMDP = Cells(myNMDP, "B")
    With ThisWorkbook.ActiveSheet
    For I = 14 To 10000
        If Len(Cells(I, "A")) = 0 Or Len(Cells(I, "B")) = 0 Then Exit For
        .Cells(Rows.Count, 1).End(xlUp).Offset(1, 0) = myCB7
        .Cells(Rows.Count, 1).End(xlUp).Offset(0, 1) = Cells(I, "A")
        .Cells(Rows.Count, 1).End(xlUp).Offset(0, 2) = Cells(I, "B")
        .Cells(Rows.Count, 1).End(xlUp).Offset(0, 3) = myNMDP
    Next I
    End With
skipF:
ActiveWorkbook.Close savechanges = False
nextF:
myFile = Dir
Loop
'
End Sub

La riga marcata <<< e' da personalizzare con la vera directory; poi eseguire.

Ciao a tutti.
Anthony
Win7 + Office 2010 Ita; Win 7 + Office 2013 Ita
Xp + Office 2003 Ita
E voi cosa usate? (per istruzioni vedere viewtopic.php?f=26&t=97449)
Avatar utente
Anthony47
Moderatore
 
Post: 13899
Iscritto il: 21/03/06 16:03
Località: Ivrea

Re: Copiare dati da altri file excel

Postdi Cattivick » 07/02/13 16:09

Ragazzi siete formidabili
Grazie 1000 per l'aiuto
Cattivick
Newbie
 
Post: 5
Iscritto il: 06/02/13 12:14

Re: Copiare dati da altri file excel

Postdi TeUzZz89 » 10/05/13 04:07

Ciao a tutti! Io ho un problema simile; sto svolgendo la mia tesi e vi spiego brevemente cosa devo fare. Devo analizzare la reazione dei mercati finanziari all'annuncio delle green policies in Sud Africa dal 2004 al 2012. In totale ho 54 file excel (ognuno rappresenta il singolo annuncio, per esempio il 16/02/2004 vi è stato l annuncio #1, il 30/04/2004 il #2 e cosi via) e per ciascuno di questi al suo interno vi sono 38 fogli ( che rappresentano i 38 settori industriali su cui tale annuncio impatta). In pratica questi 54 file sono un modello statistico che sto usando e che sto applicando ad ogni singolo annuncio per ogni singolo settore industriale (quindi lo sto ripetendo 54x38 volte), ma ho altri 54 file simili per un altro modello e cosi via. Volevo quindi sapere se esiste un modo per far convergere tutti i risultati di questi modelli in un unico file cosi strutturato: 54 fogli, ognuno rappresentante il singolo annuncio e all'interno del quale vi è una matrice che abbia per righe ogni settore (38 righe) e per colonne i risultati delle variabili dei modelli che sto applicando. Quindi dovrei raccogliere tali valori dai singoli fogli (=settori) e disporli in colonna nel nuovo file. Forse non sono stato chiarissimo, però io non avendo mai usato macro non saprei nemmeno come impostare il problema. Ah dimenticavo che per ciascun foglio che devo prendere in considerazione, le celle sono sempre le stesse quindi la cosa dovrebbe semplificare il tutto. Per esempio so che devo sempre prendere GV4 e GV7 per il modello "a", A3 per il modello "b" e cosi via.
Ringrazio tutti per l'aiuto e la disponibilità.
TeUzZz89
Utente Junior
 
Post: 20
Iscritto il: 10/05/13 03:48

Re: Copiare dati da altri file excel

Postdi Anthony47 » 10/05/13 12:09

Ciao TeUzZz89, benvenuto nel forum.
Quello che possiamo fare e' creare un file per ognuno dei 38 settori industriali, ognuno contenente 54 fogli.

Per questo pero' dovresti dire quale e' la regola con cui sono nominati attualmente i 54 file e quale e' la regola con cui sono nominati i 38 fogli. E' anche utile che pubblichi un file zippato contenente alcuni file che possano essere usati come ambiente di test; per come fare vedi qui: viewtopic.php?f=26&t=80395

Ciao
Anthony
Win7 + Office 2010 Ita; Win 7 + Office 2013 Ita
Xp + Office 2003 Ita
E voi cosa usate? (per istruzioni vedere viewtopic.php?f=26&t=97449)
Avatar utente
Anthony47
Moderatore
 
Post: 13899
Iscritto il: 21/03/06 16:03
Località: Ivrea

Re: Copiare dati da altri file excel

Postdi TeUzZz89 » 11/05/13 03:00

Ciao! Grazie mille per l'aiuto!
ah ok quindi non si riesce a creare un file unico con 54 fogli al cui interno siano "raggruppati" i risultati dei modelli che devo utilizzare?
Comunque ora carico il tutto che cosi è più chiaro.
Questo è il link:

http://ul.to/vxqj26ft

Allora per quanto riguarda i file, sono nominati con la lettera iniziale che rappresenta il nome del modello (es. K) seguito dal numero dell'annuncio (es.08, quindi l'ottavo annuncio a partire da inizio del 2004) e dalla data dell'annuncio. Quindi vi sono in totale 54 file del modello K e 54 file del modello C. Poi ho inserito anche il file tables, con all'interno 54 fogli, per ciascun annuncio, in cui vi è una matrice contenente tutti i risultati che vorrei raggruppare.
Per quanto riguarda i fogli, i settori sono nominati in ordine alfabetico (Automobiles & Parts, Bank, Beverage etc.).
Per quanto riguarda il modello K (=file K08, etc), mi interessa copiare il valore GV4 e GV7 da ogni foglio e metterlo nel file tables rispettivamente da C10 in giù e da D10 in giù (nel file tables, il foglio 8 contiene dei valori solo perchè li stavo copiando a mano, ma mi sono reso conto che sarebbe stato troppo time consuming) Per quanto riguarda il modello C, copiare il valore B2 da ogni foglio e metterlo nel file tables da B10 in giù. E' fattibile?

Già che ci sono vi vorrei chiedere un'altra piccola cosa. Per quanto riguarda il modello K, i valori che devo copiare sono ottenuti mediante l'utilizzo del risolutore di excel. Il fatto è che per alcuni fogli arriva anche a 300 soluzioni di prova prima di darmi dei valori che rispettino i vincoli etc. e impiega quindi anche un ora e mezza solo per un singolo foglio. Mi domandavo quindi se c'era la possibilità di "automatizzare" l'avvio del solver per tutti i fogli di un file, senza che debba ogni volta manualmente cambiare foglio, aspettare un ora davanti al pc e premere nuovamente ok. E' un'attività che mi porta via anche molto tempo in quanto, quando excel è occupato con il solver, non riesco nemmeno a lavorare su altri file.
Grazie mille di cuore per l'aiuto, spero di essere stato chiaro. ;)
TeUzZz89
Utente Junior
 
Post: 20
Iscritto il: 10/05/13 03:48

Re: Copiare dati da altri file excel

Postdi Flash30005 » 11/05/13 08:02

Ciao TeUzZz89 e benvenuto

Ti informo che il link per il download del file è errato

ciao
Flash
Win7 + Office 2010 Ita
"Fotografica" al servizio dell'immagine

Ottime opportunità di lavoro (part-time o full-time) con guadagni immediati. Info in MP
Avatar utente
Flash30005
Moderatore
 
Post: 8460
Iscritto il: 27/09/07 11:44
Località: Roma +o-

Re: Copiare dati da altri file excel

Postdi TeUzZz89 » 11/05/13 14:39

Scusate, ho provato con questo e spero funzioni, grazie.

http://rapidshare.com/files/648209207/test.rar
TeUzZz89
Utente Junior
 
Post: 20
Iscritto il: 10/05/13 03:48

Re: Copiare dati da altri file excel

Postdi ricky53 » 11/05/13 15:51

Ciao, non va ancora bene.
Crcando di scaricare il tuo file si ottiene questo messaggio:
Il download di questo file non è stato abilitato. Il download può essere abilitato soltanto dall’utente che ha caricato il file.
Dice il vecchio saggio provare e riprovare è l'unica strada per imparare

Più chiara è la vostra spiegazione
Più immediata sarà la nostra soluzione


. . . . . . . . . .
S.O. W7; Office 2003-10-13-16
Avatar utente
ricky53
Utente Senior
 
Post: 4223
Iscritto il: 11/04/09 19:29
Località: Italia

Re: Copiare dati da altri file excel

Postdi TeUzZz89 » 11/05/13 16:57

Scusate forse erano le impostazioni del mio account di rapidshare. Ora dovrebbe andare, spero :)
Grazie!
TeUzZz89
Utente Junior
 
Post: 20
Iscritto il: 10/05/13 03:48

Re: Copiare dati da altri file excel

Postdi ricky53 » 11/05/13 23:47

Ciao,
adesso si scarica.
Dice il vecchio saggio provare e riprovare è l'unica strada per imparare

Più chiara è la vostra spiegazione
Più immediata sarà la nostra soluzione


. . . . . . . . . .
S.O. W7; Office 2003-10-13-16
Avatar utente
ricky53
Utente Senior
 
Post: 4223
Iscritto il: 11/04/09 19:29
Località: Italia

Re: Copiare dati da altri file excel

Postdi TeUzZz89 » 12/05/13 13:43

Ok perfetto! Grazie a tutti! spero ci sia un modo per risolvere il tutto! :)
TeUzZz89
Utente Junior
 
Post: 20
Iscritto il: 10/05/13 03:48

Re: Copiare dati da altri file excel

Postdi Anthony47 » 12/05/13 22:04

Rileggendo (e rileggendo) i messaggi e guardando i file di esempio ho realizzato meglio la richiesta, che e' fattibile.
Un paio di difficolta' che hanno complicato le cose:
1) i nomi dei fogli non sono uguali tra i file tipo K e quelli tipo C; vedi questo elenco di differenze:
    Tipo C vd Tipo K
    Electronic & Electrical Equipm
    Electronic & Electrical Equipme

    Financial Services (Sector)
    Financial Services

    Food & Drug Retailers
    Food &Drugs Retailers

    Industrials Metals & Mining
    Industrial Metals & Mining

    Real Estate Investments & Servi
    Real Estate Investment & Servic
Per utilizzare un unico elenco di Fogli, che prelevo da un file di tipo K, la macro correggera' queste discrepanze, modificando i nomi dei file tipo C, senza pero' salvare queste modifiche.
Tutti i file di tipo C devono avere queste discrepanze sui nomi altrimenti ci saranno errori.

2) nei file di tipo C, il foglio Automobiles & Parts contiene il risultato in A2; gli altri fogli in B2. Poiche' solo A2 oppure B2 e' compilata, la macro sommera' queste due celle per calcolare il risultato da inserire in colonna B di Tables.xlsm

La macro ' pronta per gestire file di tipo K e di tipo C, ma e' predisposta per gestire altri tipi; a questo scopo:
-ampliare il contenuto di myTipo
-ampliare i "casi" elaborati all' interno del blocco Select Case /End Select
Le istruzioni coinvolte sono marcate <<<*

La macro cerca tutti i file di tipo K; per ogni file tipo K deve esistere il suo analogo tipo C (oltre che eventuali altri "tipi" che avrai aggiunto in myTipo come detto prima).
In B3 di ogni foglio viene scritto il nome del file che ha prodotto la tabella.
Dopo la selezione della directory la macro procede un file dopo l' altro; guarda il messaggio nella status bar per avere indicazioni sull' operazione in corso; il foglio selezionato su Tables.xlsm dara' l' idea del progresso complessivo.

Il codice della macro:
Codice: Seleziona tutto
Sub forTeo2()
Dim mySheets(1 To 50) As String, myPath As String, FName As String
Dim J As Long, myTipo, JJ As Long, KK As Long, LL As Long, WSh
'
myTipo = Array("K", "C")    '<<<* Tipi di file esistenti
'
MsgBox ("Premi Ok per effettuare la selezione della directory che contiene i file da unire")

'scegli la directory in cui sono i file
With Application.FileDialog(msoFileDialogFolderPicker)
    .AllowMultiSelect = False
    .Title = "..Seleziona la directory contenente i file da unire..."
    .ButtonName = "Confirm"
    .InitialView = msoFileDialogViewProperties
    .InitialFileName = ""
    .Show
    If .SelectedItems.Count < 1 Then
        MsgBox ("Nessuna selezione; aborted")
        Exit Sub
    End If
    myPath = .SelectedItems(1)
End With
'compila lista worksheets
FName = Dir(myPath & "\K*.xlsx")
Workbooks.Open myPath & "\" & FName
For Each WSh In ActiveWorkbook.Worksheets
DoEvents
    J = J + 1
    mySheets(J) = WSh.Name
Next WSh
ActiveWorkbook.Close savechanges:=False
FName = Dir(myPath & "\" & myTipo(LBound(myTipo)) & "*.xlsx")
While FName <> ""
    KK = KK + 1
    ThisWorkbook.Sheets(KK).Select
    For J = LBound(myTipo) To UBound(myTipo)
        FName = myTipo(J) & Mid(FName, 2, 999)
        Workbooks.Open myPath & "\" & FName
        If J = 1 + LBound(myTipo) Then
        'corregge nomi errati su file Cxxx; vedi testo
            Sheets("Electronic & Electrical Equipm").Name = "Electronic & Electrical Equipme"
            Sheets("Financial Services (Sector)").Name = "Financial Services"
            Sheets("Food & Drug Retailers").Name = "Food &Drugs Retailers"
            Sheets("Industrials Metals & Mining").Name = "Industrial Metals & Mining"
            Sheets("Real Estate Investments & Servi").Name = "Real Estate Investment & Servic"
        End If
        With ThisWorkbook.Sheets(KK)
            .Range("B3") = FName
            LL = 0
            For JJ = 1 To UBound(mySheets)
                DoEvents
                If mySheets(JJ) <> "" And (UCase(Left(mySheets(JJ), 5)) <> "SHEET") Then
                    Select Case myTipo(J)
                        Case "K"
                            .Range("C10").Offset(LL, 0) = Sheets(mySheets(JJ)).Range("GV4").Value
                            .Range("D10").Offset(LL, 0) = Sheets(mySheets(JJ)).Range("GV7").Value
                        Case "C"
                            On Error Resume Next
                            .Range("B10").Offset(LL, 0) = Sheets(mySheets(JJ)).Range("B2").Value + Sheets(mySheets(JJ)).Range("A2").Value
                            On Error GoTo 0
                        'Case "Xyz"         '<<<* Inserire altri casi se sono presenti
                        'Istruzioni Xyy
                        'Case "Abc"
                        'Istruzioni Abc
        ' etc
                        End Select
                    LL = LL + 1
                End If
            Next JJ
        End With
        ActiveWorkbook.Close savechanges:=False
    Next J
    FName = Dir()
Wend
MsgBox ("Completato...")
End Sub
Dal file Tables.xlsx:
-premi Alt-F11 per aprire l' editor delle macro; Menu /Inserisci /Modulo; copia il codice e incollalo nel frame di dx.
-personalizza eventualmente per la gestione di altri tipi di file.

Salva il file Tables con l' estensione "XLSM" (cartella di lavoro con macro).
Quando sei pronto a provare la fortuna, premi Alt-F8, seleziona forTeo2 dall' elenco delle macro che ti proporra', premi Esegui; scegli la directory e attendi il risultato.

Fai sapere, ciao.
Anthony
Win7 + Office 2010 Ita; Win 7 + Office 2013 Ita
Xp + Office 2003 Ita
E voi cosa usate? (per istruzioni vedere viewtopic.php?f=26&t=97449)
Avatar utente
Anthony47
Moderatore
 
Post: 13899
Iscritto il: 21/03/06 16:03
Località: Ivrea

Re: Copiare dati da altri file excel

Postdi TeUzZz89 » 14/05/13 02:12

Grazie mille!!!! funziona!!! gentilissimi!! mi avete aiutato davvero molto non so come ringraziarvi!!!! :)
TeUzZz89
Utente Junior
 
Post: 20
Iscritto il: 10/05/13 03:48

Prossimo

Torna a Applicazioni Office Windows


Topic correlati a "Copiare dati da altri file excel":


Chi c’è in linea

Visitano il forum: eliorimnap, patel e 13 ospiti