Aiuto Formula Ritardi

[Francesco6918]

Ciao Flash30005 sono Francesco potresti crearmi una formula ritardi ambi, range(T14:T8500)range ambo da ricercare(T8:T9) con excel per il programma Superenalotto_3 da tè corretto 20 giorni fa.
La formula la inserico nella cella sottostante a l'ambo, risultato ritardo recende.

Saluti

[Flash30005]

Formula?

Semmai una macro ma dovresti specificare quale ritardo vorresti ottenere:
Rit Attuale
Rit Max
Rit Min

Inoltre la cella da utilizzare per questo valore, in quanto la cella T10 (sotto l'ambo), è una cella unita ed occupata dalla stringa "Frequenze"

ciao

[Francesco6918]

Ciao Flash30005 ritardo attuale la cella occupata la riporto allo stato normale, la inserisco non con una macro con una formula excel.

Grazie

I più sinceri auguri

Francesco

[Flash30005]

Forse non mi sono espresso bene
Non conosco la formula per poter calcolare quel ritardo.
Ripeto se vuoi una macro, bene!
Altrimenti bisogna cambiare il titolo al topic, così, magari, qualcun' altro potrà aiutarti

ciao

[Francesco6918]

Va bene proviamo con una macro.

Saluti

[Flash30005]

Ecco!

Codice: Seleziona tutto

Sub CalRitA()
UR = Range("B" & Rows.Count).End(xlUp).Row
Application.Calculation = xlManual
For CCA = 20 To 55
    N1 = Cells(8, CCA).Value
    N2 = Cells(9, CCA).Value
    AmboC = N1 & "-" & N2
    If N1 > N2 Then AmboC = N2 & "-" & N1
    For RR = UR To 14 Step -1
        For CCB = 2 To 6
            NB1 = Cells(RR, CCB).Value
            For CCC = CCB + 1 To 7
                NB2 = Cells(RR, CCC).Value
                AmboB = NB1 & "-" & NB2
                If AmboB = AmboC Then
                Application.EnableEvents = False
                    Cells(10, CCA).Value = (UR - RR)
                Application.EnableEvents = True
                    GoTo SaltaCCA
                End If
            Next CCC
        Next CCB
    Next RR
SaltaCCA:
Next CCA
Application.Calculation = xlCalculationAutomatic
End Sub


Questa macro la puoi richiamare alla fine del ciclo della macro generale
In questo modo sarà tutto automatizzato

Edit:
Pensavo che se tu utlizzassi una riga superiore a quella degli ambi esempio la riga 4 (invece della 10)
potresti, con una formula situata a fianco (es: S4), avere il max ritardo attuale (o minimo) con una formula di questo tipo:

Codice: Seleziona tutto

=CERCA.ORIZZ(MAX(T4:BC4);T4:BC9;5;FALSO) &" " & CERCA.ORIZZ(MAX(T4:BC4);T4:BC9;6;FALSO)

Riassumendo:
attiva la macro postata e, per il momento come test, copia i risultati nel range T10:BC10, incollandoli in T4:BC10
poi copi la formula appena postata e incollala in S4

Ciao

EDIT ore 22:30 - Aggiunta considerazione...

[Francesco6918]

Grazie Flash30005 sei un mago,non vorrei essere ripetitivo ma so usare solo le formule sono solo alle prime armi con excel tutto quello che conosco riguardo le formule lo devo agli esempi riportati sul forum in questione dunque a volte devi avere pazienza se non so esprimermi per quello che cerco.
Comunque funziona tutto.

Saluti

[Flash30005]

Allego il file modificato come proposto nel post precedente
download

Ciao

[Francesco6918]

Grazie Flash30005 funziona tutto ci sentiamo presto.

Saluti

Francesco

[raimea]

ciao

tramite macro vorrei riuscire a calcolare il ritardo di ogni
numero da 1-->49 scritti in N11:N59 , analizzando solo la
piccola tabella a lato E11:K130.

di ogni numero vorrei calcolare il ritardo attuale
e metterlo in O11:O59, ed il ritardo max scivendolo
in P11:P59

vi allego il file

grazie

https://db.tt/Vd4cbn4A

[Anthony47]

Prova con questa macro:

Codice: Seleziona tutto

Sub mimax()
'Vedi http://www.pc-facile.com/forum/viewtopic.php?f=26&t=93777&p=591617#p591617
Dim WArr(1 To 49, 1 To 4) As Variant, myNums As Range, LastR As Long
Dim myR0 As Long, myC0 As Long, I As Long, J As Long, cCell, cRit As Long
'
Set myNums = Range("E11:K11")         '<<< Il top dell' area con le estrazioni
myR0 = myNums.Cells(1, 1).Row
myC0 = myNums.Cells(1, 1).Column
LastR = myNums.Cells(1, 1).End(xlDown).Row
For I = myR0 To LastR
If I = 130 Then Stop
    For J = myC0 To myC0 + myNums.Columns.Count - 1
        cCell = Cells(I, J).Value
        If IsEmpty(WArr(cCell, 4)) Then WArr(cCell, 4) = myR0 - 1
        cRit = I - WArr(cCell, 4) - 1
        WArr(cCell, 4) = I
        If cRit > WArr(cCell, 2) Then
            WArr(cCell, 2) = cRit
            WArr(cCell, 3) = I
        End If
    Next J
Next I
For J = LBound(WArr, 1) To UBound(WArr, 1)
    WArr(J, 1) = I - WArr(J, 4) - 1
Next J
'
Range("O11").Resize(49, 3) = WArr
Set myNums = Nothing
End Sub


Nota: ATTENZIONE, perche' viene anche compilata la colonna Q (Q11:Q59) con il numero di riga in cui si e' presentato il max ritardo, cosi' dovrebbe esserti piu' facile fare il debug...

Ciao

[raimea]

ciao
almomento si blocca qui:

Codice: Seleziona tutto

Dim WArr(1 To 49, 1 To 4) As Variant, myNums As Range, LastR As Long
Dim myR0 As Long, myC0 As Long, I As Long, J As Long, cCell, cRit As Long
'
Set myNums = Range("E11:K11")         '<<< Il top dell' area con le estrazioni
myR0 = myNums.Cells(1, 1).Row
myC0 = myNums.Cells(1, 1).Column
LastR = myNums.Cells(1, 1).End(xlDown).Row
For I = myR0 To LastR

If I = 130 Then Stop        ' <<< si blocca qui...

    For J = myC0 To myC0 + myNums.Columns.Count - 1
        cCell = Cells(I, J).Value
        If IsEmpty(WArr(cCell, 4)) Then WArr(cCell, 4) = myR0 - 1
        cRit = I - WArr(cCell, 4) - 1
        WArr(cCell, 4) = I
        If cRit > WArr(cCell, 2) Then
            WArr(cCell, 2) = cRit
            WArr(cCell, 3) = I
        End If
    Next J
Next I

ciao

[Anthony47]

Quella riga l' hanno aggiunta Godin, Suarez e Cavani per punizione aggiuntiva; io non c' entro...

Comunque la devi togliere (insieme ad altre servivano per ispezionare il risultato a fine ciclo, ed e' rimasta per errore nel listato)

Ciao...

[raimea]

ottima osservazione

ma ancora i conti non tornano...

ho tolto la riga incriminata come da immagine dice che i num.
2,3,4,6 hanno ritardo 0 ma e' errato.
1 ritr 5 invece deve essere 2
10 dice 3 invece e' zero
ecc....



ciao

[Anthony47]

Eh, caro... tutto sta a chiarire dove cominciano e dove finiscono le cose...
Per me cominciano a riga 11 e finiscono a riga 130; e siccome 2, 3, 4 e 6 (ma anche altri numeri) sono tra gli ultimi usciti (riga 130) il loro ritardo e' "zero".
Dall' esempio che fai devo invece immaginare che le estrazioni piu' vecchie sono in 130 e quelle piu' recenti sono in riga 11....
Se e' cosi', con qualche inversione la macro diventa

Codice: Seleziona tutto

Sub mimax2()
'Vedi http://www.pc-facile.com/forum/viewtopic.php?f=26&t=93777&p=591617#p591617
Dim WArr(1 To 49, 1 To 4) As Variant, myNums As Range, LastR As Long
Dim myR0 As Long, myC0 As Long, I As Long, J As Long, cCell, cRit As Long
'
Set myNums = Range("E11:K11")
myR0 = myNums.Cells(1, 1).Row
myC0 = myNums.Cells(1, 1).Column
LastR = myNums.Cells(1, 1).End(xlDown).Row
For I = LastR To myR0 Step -1
    For J = myC0 To myC0 + myNums.Columns.Count - 1
        cCell = Cells(I, J).Value
        If IsEmpty(WArr(cCell, 4)) Then WArr(cCell, 4) = LastR + 1 'myR0 - 1
        cRit = -(I - WArr(cCell, 4) + 1)
        WArr(cCell, 4) = I
        If cRit > WArr(cCell, 2) Then
            WArr(cCell, 2) = cRit
            WArr(cCell, 3) = I
        End If
    Next J
Next I
For J = LBound(WArr, 1) To UBound(WArr, 1)
    WArr(J, 1) = -(I - WArr(J, 4) + 1)
Next J

Range("O11").Resize(49, 3) = WArr
Set myNums = Nothing
End Sub


Nota che non puo' essere 0 il ritardo di 10 e 2 il ritardo di 1, come dici; ho interpretato corretto il valore di 0 per 10 (quindi il ritardo dell' 1 e' 1).

Ciao.

[raimea]

ciao

Eh, caro... tutto sta a chiarire dove cominciano e dove finiscono le cose...

nessuna obiezione, hai ragione.

ora "quadra" tutto
ti ringrazio

ciao