Valutazione 4.87/ 5 (100.00%) 5838 voti

Condividi:        

Shortcut tastiera per vedere la cella precedente

Vuoi potenziare i tuoi documenti Word? Non sai come si fa una macro in Excel? Devi creare una presentazione in PowerPoint?
Oppure sei passato a OpenOffice e non sei sicuro di come lavorare al meglio?

Moderatori: Anthony47, Flash30005

Shortcut tastiera per vedere la cella precedente

Postdi Brigitte » 30/11/17 18:01

Ciao a tutti, avrei bisogno di sapere qual è la scorciatoia da tastiera per vedere la cella precedente quando io inserisco una funzione in una cella in un altro foglio. Ad esempio se nella cella A1 del Foglio 1 inserisco =Foglio2!A2 vorrei sapere il comando da tastiera che mi porta dalla cella A1 del foglio 1 alla cella A2 del foglio 2.
Spero di essere stata chiara in questo esempio un pò ingarbugliato :)
Brigitte
Newbie
 
Post: 3
Iscritto il: 13/09/17 21:18

Sponsor
 

Re: Shortcut tastiera per vedere la cella precedente

Postdi Zer0Kelvin » 30/11/17 19:44

Ciao.
A meno che non sia stato aggiuto in versioni successive alla 2010 non mi risulta che esista un comando del genere.
Se proprio devi navigare fra una marea di fogli, ti posso proporre un componente aggiuntivo che ho realizzato anni fà che ti permette di navigare fra i fogli precedentemente visitati (quindi non quello che chiedi).
Non ti posso però garantire che funzioni con le versioni più recenti di Excel...
Eventualmente si potrebbe scrivere una macro ad hoc, ammesso che ne valga la pena.
[Win7,Office2010]
Condividere la conoscenza aumenta la ricchezza di tutti(Z0°K)
Dai ad un uomo un pesce e lo avrai sfamato per un giorno;insegnagli a pescare e lo avrai sfamato per sempre(Confucio)
Il sonno della ragione genera mostri(Francisco Goya)
Avatar utente
Zer0Kelvin
Utente Senior
 
Post: 373
Iscritto il: 08/04/12 11:23

Re: Shortcut tastiera per vedere la cella precedente

Postdi Marius44 » 30/11/17 21:38

Ciao
Concordo pienamente con Z0K (ciao). Ma se devi spostarti SOLO al foglio successivo o al foglio precedente (ponendo a base il foglio attivo) puoi utilizzare CTRL+PGGIU (sposta al foglio successivo) e CTRL+PGSU (sposta al foglio precedente).

Ciao,
Mario
Marius44
Utente Senior
 
Post: 388
Iscritto il: 07/09/15 22:00

Re: Shortcut tastiera per vedere la cella precedente

Postdi Anthony47 » 03/12/17 02:17

Non mi risulta che ci sia un comando per andare a un predecessor della cella, comunque si puo' fare qualcosa con una macro.

E' stato moolto piu' incasinato di come credevo, ma qualcosa e' uscito, cioe' questa macro:
Codice: Seleziona tutto
Sub GimmePredec()
'Elenca i Predecessor della ActiveCell
Dim PiPP As Range, cPos As Range, tWS As String, tWB As String, cCell As String
Dim pAdr As String, flExt As Boolean, I As Long, mySplit, J As Long, K As Long
Dim kArr(1 To 10, 1 To 2, 1 To 10), Mess As String
Dim Rispo, L As Long, lWB As String
'
Set cPos = ActiveCell
tWB = ThisWorkbook.Name
tWS = ActiveSheet.Name
cCell = ActiveCell.Address(0, 0, 1, True)
ActiveSheet.ClearArrows
ActiveCell.ShowPrecedents
For I = 1 To 10
    For J = 1 To 10
reExt:
        Application.Goto cPos
        Set PiPP = Nothing
        On Error Resume Next
        Set PiPP = ActiveCell.NavigateArrow(True, I, J)
        On Error GoTo 0
        If PiPP Is Nothing Then
            flExt = False
        Else
            If PiPP.Address(0, 0, 1, True) = cPos.Address(0, 0, 1, True) Then
                'nulla?
            Else
                pAdr = Replace(PiPP.Address(0, 0, 1, True), "[" & tWB & "]", "", , , vbTextCompare)
                If ActiveSheet.Name = tWS Then
                    pAdr = Replace(pAdr, tWS & "!", "", , , vbTextCompare)
                    pAdr = Replace(pAdr, tWS & "'!", "", , , vbTextCompare)
                End If
                pAdr = Replace(pAdr, "'", "", , , vbTextCompare)
                kArr(I, 1, J) = pAdr
                kArr(I, 2, J) = PiPP.Text
            'Debug.Print pAdr, PiPP.Text
            End If
        End If
    Next J
Next I
'
Mess = ""
For K = 1 To 10
    For J = 1 To 10
        If kArr(K, 1, J) <> "" Then
            L = L + 1
            Mess = Mess & vbCrLf & L & ",  " & kArr(K, 1, J) & ",    " & kArr(K, 2, J)
        End If
    Next J
Next K
If Len(Mess) < 5 Then
    Application.Goto cPos
    MsgBox ("La cella non ha PRECEDENTI")
    GoTo EXT
End If
Mess = Mess & vbCrLf & "Numero del link? (oppure Annulla)"
Rispo = Application.InputBox(Mess, "Scegli link:")
'
If Rispo = False Or Rispo = "" Or Rispo > UBound(kArr, 1) Then
    GoTo EXT
End If
mySplit = Split(Mess & "  ", vbCrLf, , vbTextCompare)
For I = 0 To UBound(mySplit)
lWB = ""
    If Left(mySplit(I), Len(Rispo)) = Rispo Then
        If InStr(1, mySplit(I), "]", vbTextCompare) > 0 Then
            lWB = Replace(Split(mySplit(I), "]", , vbTextCompare)(0), "[", "", , , vbTextCompare)
            lWB = Trim(Replace(lWB, Rispo & ",", "", , , vbTextCompare))
        End If
        mySplit = Split(Split(Replace(mySplit(I), "[" & lWB & "]", "", , , vbTextCompare) & " ", ",", , vbTextCompare)(1) & " ", "!", , vbTextCompare)
        If UBound(mySplit) = 1 Then
            If lWB = "" Then
                Set PiPP = Sheets(Trim(mySplit(0))).Range(Trim(mySplit(1)))
            Else
                Set PiPP = Workbooks(lWB).Sheets(Trim(mySplit(0))).Range(Trim(mySplit(1)))
            End If
            Application.Goto PiPP
            GoTo EXT
        Else
            Application.Goto Range(Trim(mySplit(0)))
            GoTo EXT
        End If
    End If
Next I
Application.Goto cPos
MsgBox ("Il link scelto non esiste")
EXT:
Workbooks(tWB).Sheets(tWS).ClearArrows
End Sub

Va inserita in un Modulo standard del vba:
-premi Alt-F11 per aprire l'editor delle macro
-Menu /Inserisci /Modulo
-Copia il codice e incollalo nel frame dx del modulo appena creato

Poi torna su Excel, posizionati su una cella di cui vuoi esaminare i "predecessor" e lancia la Sub GimmePredec:
-premi Alt-F8
-seleziona GimmePredec dall'elenco di macro disponibili
-premi Esegui
(oppure asociala a un pulsante, a un'icona sulla barra di accesso rapido, o a una combinazione di tastiera)

Si aprira' un Inputbox che elenca i predecessori della cella e il loro valore attuale, e chiede quale selezionare; col tasto Ok ci si spostera' su quel predecessore.
Si noti che se il predecessore e' su altro workbook al momento chiuso esso non viene individuato da Excel.

Spero sia di qualche utilita'...


keyw:
Identify and navigate cell predecessor
Anthony
Win7 + Office 2010 Ita; Win 7 + Office 2013 Ita
Xp + Office 2003 Ita
E voi cosa usate? (per istruzioni vedere viewtopic.php?f=26&t=97449)
Avatar utente
Anthony47
Moderatore
 
Post: 15978
Iscritto il: 21/03/06 16:03
Località: Ivrea

Re: Shortcut tastiera per vedere la cella precedente

Postdi Zer0Kelvin » 03/12/17 15:43

Ciao a tutti.
Prendendo alla lettera la richiesta, se la cella contiene solamente un singolo riferimento ad una cella, si potrebbe risolvere semplicemente con un Application.Goto.
Codice: Seleziona tutto
Application.Goto Replace(ActiveCell.FormulaR1C1, "=", ""), True
[Win7,Office2010]
Condividere la conoscenza aumenta la ricchezza di tutti(Z0°K)
Dai ad un uomo un pesce e lo avrai sfamato per un giorno;insegnagli a pescare e lo avrai sfamato per sempre(Confucio)
Il sonno della ragione genera mostri(Francisco Goya)
Avatar utente
Zer0Kelvin
Utente Senior
 
Post: 373
Iscritto il: 08/04/12 11:23


Torna a Applicazioni Office Windows


Topic correlati a "Shortcut tastiera per vedere la cella precedente":


Chi c’è in linea

Visitano il forum: Nessuno e 26 ospiti