Condividi:        

Excel Estrazione casuale testo da colonna per bingo ca**ate

Vuoi potenziare i tuoi documenti Word? Non sai come si fa una macro in Excel? Devi creare una presentazione in PowerPoint?
Oppure sei passato a OpenOffice e non sei sicuro di come lavorare al meglio?

Moderatori: Anthony47, Flash30005

Excel Estrazione casuale testo da colonna per bingo ca**ate

Postdi Dylan666 » 06/02/24 09:08

Ciao a tutti,
scusate la "volgarità" nel titolo ma la richiesta si ispira proprio al "bingo dell ca...volate", cioè la pratica di creare delle cartelle tipo bingo/tombola in cui vengono elencate tutte le frasi fatte e i luoghi comuni tipici di una riunione aziendale:
https://www.paroledimanagement.it/il-bi ... tenticita/

Lo scopo, proprio come nel popolare gioco natalizio, è quello di sentire "chiamati" tutti gli elementi della propria cartella, ma invece dei numeri estratti a caso ci saranno le frasi dette dall'ignaro speaker dell'evento/riunione.

Tramite Google sono riuscito a trovare il PDF della cartella, che a sua volta proveniva da un file Word:
https://uploads.tapatalk-cdn.com/files- ... -Mario.pdf

Ho riconvertito il file in Excel e messo tutte le frasi su un altro foglio (diciamo Foglio2), in una colonna da A2 ad A41 (ma potrebbero aumentare).
Nel Foglio1 (quello della cartella vera a propria) ho 4 righe di caselle testuali da 10 colonne ciascuna:

  1. da A2 a J2
  2. da A3 a J3
  3. da A4 a J4
  4. da A5 a J5

La mia idea era svuotare le 40 caselle e mettere in 6 di esse, a caso, 6 testi presi dal Foglio2 dall'intervallo A2:A41
Ovviamente molte caselle rimarranno vuote ma non mi importa, accade lo stesso anche nelle cartelle della tombola "vera".
Non mi interessa nemmeno dove vadano i testi (mentre nella tombola la prima colonna ospita i numeri da 1 a 9, la seconda da 10 a 19 e così via, in modo che sia più facile controllare) ma l'importante è che non ci siano frasi ripetute per singola cartella.

Sarebbe carino pure evitare cartelle identiche ma in questa fase non è così importante.

Volevo cimentarmi nella sfida, non essendo un mago di Excel ma avendo voglia di imparare pure da un progetto così "stupido".
Ma la domanda vera è: quale sarebbe la strada più corretta per la sua implementazione?
A occhio mi verrebbe da dire un VBS, che generi dei numeri random per la scelta delle frasi, li metta in array (credo sia più facile riempirli con elementi univoci) e poi sempre con una estrazione random mettere i valori nelle 6 celle casuali (segnandomi mano a mano quelle usate per non scriverci dentro 2 volte).

Ma è veramente la strada migliore?

Perché non conosco tutte le potenzialità di Excel e vedo che molto si raggiunge anche solo a formule:
https://www.valterborsato.it/excel/stat ... 0duplicati

Mi è quindi venuto il dubbio che la strada migliore possa essere una somma di formule (per la lista univoca) e VBS (per mettere i valori).

Voi come fareste?

Nota importante:
Il layout 4x10 delle caselle della cartella viene dal progetto originario.
L'idea di riempirne solo 6 è invece mia, dopo aver fatto una proporzione con la tombola reale.
Se nella tombola ci sono 90 numeri e ogni cartella ne ha 15 per avere la stessa proporzione con 40 frasi io ne devo mettere 6 (mantenendo una rapporto del 16% circa tra i propri numeri e il totale del tabellone).
Se pensate che sarebbe più comodo o corretto un layout righe/colonne diverso sono aperto alle proposte.

Grazie a chi vorrà darmi una mano
Avatar utente
Dylan666
Moderatore
 
Post: 39993
Iscritto il: 18/11/03 16:46

Sponsor
 

Re: Excel Estrazione casuale testo da colonna per bingo ca**

Postdi Anthony47 » 06/02/24 14:31

Questo gioco sembra affascinante, vedro' di proporre qualcosa
Trattandosi di cercare valori aleatori escludo l'uso di formule: ricalcolandosi in continuazione risulta difficile anche solo evitare che la stessa cartella contenga due volte la stessa ...Ca**ata. Per cui lavorero' di vba

Per ora ho importato l'elenco delle 40 pillole da https://uploads.tapatalk-cdn.com/files- ... -Mario.pdf , e lavorero' con quelle; conto di farmi vivo presto...
Altri contributi intanto son benissimo accetti
Avatar utente
Anthony47
Moderatore
 
Post: 19212
Iscritto il: 21/03/06 16:03
Località: Ivrea

Bingo Tombola Aziendale delle cazzate

Postdi Dylan666 » 06/02/24 15:40

Sono arrivato a un prototipo funzionante.
Sicuramente ci sono delle conversioni da Array a String e viceversa che si potevano evitare, ma mi erano utili durante il debug e le ho lasciate.

È tutto molto "veboso" e commentato sperando che se riapro il file a distanza di tempo si capisca qualcosa :P
Lascio qui pure il listato VBA nel caso il file XLSM allegato sotto andasse perso.
Come ho già detto c'è un primo foglio chiamato Schedina con le caselle da A2 a J5 dove andranno le frasi sorteggiate.
Nello stesso foglio nella cella R2 ci va il numero di quante frasi si vogliono sorteggiare e vicino ci ho messo il bottone che avvia la sub CreaCartella().
Nel secondo foglio chiamato FRASI da A2 in poi (in A3, A4, A5 ecc.) c'è l'elenco di tutte le frasi possibili per il sorteggio, una per ogni cella.
Ovviamente nella cella R2 non si può mettere un numero superiore a 40 (che sono le celle a disposizione) e nemmeno un numero superiore alle frasi a disposizione (ce ne sono già 40 e si possono aumentare)

Schedina.png


FRASI.png


Codice: Seleziona tutto
Sub CreaCartella()
'Pulisci i valori precedenti
Worksheets("Schedina").Range("A2:J5").Value = ""

'Variabile di QUANTE frasi sorteggiare (la variabile determina anche quante caselle riempire)
Dim NumFrasi As Integer
NumFrasi = Worksheets("Schedina").Range("R2").Value

'Variabile col numero totale delle frasi possibili tra cui sorteggiare
Dim TotNumFrasi As Integer
TotNumFrasi = Application.WorksheetFunction.CountIf(Worksheets("FRASI").Range("A2:A1000"), "*")

'Creazione della lista casuale di frasi
Dim ListaFrasi As String
ListaFrasi = CreaNumeriUnivoci(NumFrasi, 1, TotNumFrasi)

'Creazione della lista casuale di caselle in cui mettere le frasi
Dim ListaCaselle As String
ListaCaselle = CreaNumeriUnivoci(NumFrasi, 1, 40) '40 è i numero delle caselle per ogni cartella

'Conversione da stringa a array delle frasi
Dim ArrayFrasi
ArrayFrasi = Split(ListaFrasi, ",")

'Conversione da stringa a array delle caselle
Dim ArrayCaselle
ArrayCaselle = Split(ListaCaselle, ",")

    'Chiamata della sub di riempimento delle celle per ogni elemento dei due array, che saranno sempre lunghi ugali
    For i = 0 To NumFrasi - 1
        Call RiempiCella(CInt(ArrayCaselle(i)), Worksheets("FRASI").Cells(ArrayFrasi(i) + 1, 1).Value) 'C'è il +1 perchè la colonna ha un header
    Next 'i
End Sub


Sub RiempiCella(CasellaDaRiempire As Integer, Testo As String)
'MsgBox ("Posizione: " & CasellaDaRiempire & vbCrLf & "Frase: " & Testo)

Dim Riga
Dim Colonna

'Seleziione della riga e della colonna da riempire
Select Case True
   Case CasellaDaRiempire >= 1 And CasellaDaRiempire <= 10
      Riga = 2
      Colonna = CasellaDaRiempire
   Case CasellaDaRiempire >= 11 And CasellaDaRiempire <= 20
      Riga = 3
      Colonna = CasellaDaRiempire - 10
   Case CasellaDaRiempire >= 21 And CasellaDaRiempire <= 30
      Riga = 4
      Colonna = CasellaDaRiempire - 20
   Case CasellaDaRiempire >= 31 And CasellaDaRiempire <= 40
      Riga = 5
      Colonna = CasellaDaRiempire - 30
End Select

'Posizionamento del testo
Worksheets("Schedina").Cells(Riga, Colonna).Value = Testo
End Sub

Function CreaNumeriUnivoci(NumeriDaTrovare As Integer, ValoreMinimo, ValoreMassimo) As String

'Questo è l'array che conterrà i valori univoci
Dim UniqueArray
UniqueArray = Array()

'Dichiarazione di una variabile booleana per vedere se il valore è già presente nell'array
Dim isFound As Boolean

'Contatore numeri unici trovati
Dim TotNumeriUnici As Integer
TotNumeriUnici = 0

'Numero casuale generato a ogni passaggio
Dim NumeroCasuale As Integer

'Ciclo di comparazione che imposta isFound come TRUE quando gli elementi comparati sono uguali
Do While TotNumeriUnici < NumeriDaTrovare
isFound = False 'Reset della variabile
NumeroCasuale = Int((ValoreMassimo - ValoreMinimo + 1) * Rnd + ValoreMinimo) 'Generazione del numero casuale da valutare
   
    For i = 0 To UBound(UniqueArray)
        If NumeroCasuale = UniqueArray(i) Then
            isFound = True
        End If
    Next 'i


    If isFound = False Then
       'Se il valore non è stato trovato nell'array di partenza viene aggiunto alla lista array degli univoci
        ReDim Preserve UniqueArray(UBound(UniqueArray) + 1) 'Allargo l'array
        UniqueArray(UBound(UniqueArray)) = NumeroCasuale 'Aggiungo il nuovo elemento

        CreaNumeriUnivoci = NumeroCasuale & "," & CreaNumeriUnivoci 'METTO IL TESTO

        'Aggiungo 1 al numeto di numero univoci trovati
        TotNumeriUnici = TotNumeriUnici + 1
    End If
Loop

'eliminazione virgola finale
If Right(CreaNumeriUnivoci, 1) = "," Then
   CreaNumeriUnivoci = Mid(CreaNumeriUnivoci, 1, Len(CreaNumeriUnivoci) - 1)
End If

End Function
Allegati
MOD Bingo delle Cazzate.xlsm
(26.31 KiB) Scaricato 29 volte
Avatar utente
Dylan666
Moderatore
 
Post: 39993
Iscritto il: 18/11/03 16:46

Re: Excel Estrazione casuale testo da colonna per bingo ca**

Postdi Anthony47 » 06/02/24 19:40

Dylan, il gioco proposto mi piaceva così tanto, e soprattutto e' socialmente utile :D , che mi ci son messo subito di impegno e già prima di pranzo avevo uno schema abbozzato, per cui non ho sfruttato il tuo approccio.

Il mio schema e' scaricabile qui: https://www.dropbox.com/scl/fi/yv9ipl7t ... rkxag&dl=0

Il foglio "Archivio" contiene una tabella con le 40 "perle" scaricate dalla pagina da te indicata.
Tale tabella dovrebbe ora essere ampliata con le perle che la saggezza popolare conosce; non c'è una procedura automatica per l'aggiunta di contenuti: si scrive nella prima cella libera, si avanza col tasto Tab, in modo che arrivati all'ultima colonna automaticamente una riga viene aggiunta alla tabella e si continua dalla prima colonna. Si possono anche lasciare celle vuote che verranno ignorate dalla macro.

Il foglio "Cartelle" contiene lo schema per 4 cartelle da stampare nel formato 4 righe * 4 colonne; ho voluto infatti evitare di sciupare un foglio intero per ogni cartella.
Il formato delle celle (altezza /larghezza, dimensione carattere) consente alle 4 schede di stare tutte in un foglio A4; piccole distorsioni dovute alle caratteristiche delle stampanti vengono risolte usando nella macro l'impostazione "Adatta la pagina al foglio"
Sul foglio Cartelle sono inoltre presenti 3 impostazioni (vedi celle colorate):
Immagine

1) TestOnly? Valori Sì/No; se diverso da "No" le schede verranno solo mostrate a schermo, max 4 alla volta
2) Numero di schede; numero tra 1 e 20 max; rappresenta quante cartelle devono essere stampate (a blocchi di 4 per foglio). Per riunioni con molti partecipanti il suggerimento e' di lavorare a blocchi di 20 schede. Per le megariunioni si puo' modificare la convalida per consentire la stampa di abbastanza cartelle senza perdere troppo tempo
3) Numero di Perle per scheda; numero tra 1 e 10; rappresenta quante voci saranno stampate su ogni cartella

Quando tutto e' pronto, il pulsante Crea Cards avvia la generazione e stampa delle schede

La macro contiene alcuni commenti essenziali per comprendere il flusso delle operazioni.
In linea di massima (ipotesi non TestOnly):
-carico le Perle da foglio Archivio su un Array; ogni Perla e' associata a un numero random sulla seconda colonna
-l'array viene ordinato per numero random crescente
-si estrae una perla tra i primi 5 valori in array, si incrementa di 1 la colonna 2, si riordina per colonna 2. In questo modo la scelta viene sempre fatta tra le perle che sono state estratte meno volte
-si ripete per il numero impostato di perle per ogni scheda
-si ripete per il numero di schede presenti nel "modello"
-esaurita la compilazione delle schede del modello (4 nell'impostazione) la pagina viene stampata, previa scelta di quale stampante utilizzare
-si procede fino al numero di schede impostato
-un msgbox avvisa del completamento del lavoro

Se invece e' stato impostato TestOnly allora invece di avviare la stampa viene visualizzato un messaggio che segnala le cartelle sono visibili e la macro viene "congelata" fino alla chiusura del messaggio (bottone oppure X) che consente di passare alle cartelle successive

Spero che sia di qualche utilità...

KWords: Bullshit Bingo BSBingo
Avatar utente
Anthony47
Moderatore
 
Post: 19212
Iscritto il: 21/03/06 16:03
Località: Ivrea

Re: Excel Estrazione casuale testo da colonna per bingo ca**

Postdi Dylan666 » 07/02/24 14:31

Prima di tutto grazie Anthony47, ho visto il tuo lavoro e per certi aspetti abbiamo fatto in maniera simile alcune cose rispetto alla seconda versione che allego a questo messaggio.
Ho ancora mantenuto il layout originario della cartella perché anche se molto grande è ormai tradizione e voglio "omaggiare" l'inventore, chiunque esso sia, dato che ci sono testimonianze già dal 2000 :D
https://www.bloom.it/vara22.htm

In questa "release" ho nascosto il foglio Schedina e messo i controlli sul foglio FRASI che ora è l'unico visibile.
Ovviamente nella parte VBA ho spostato di conseguenza il riferimento alla cella ove si imposta il numero di frasi da sorteggiare (ora è J1 di FRASI).
Poi ho aggiunto nuovi bottoni per:

  • Creare le nuove cartelle, ciascuna in un nuovo foglio di Excel
  • Stampare tutte cartelle in un PDF
  • Esportarle singolarmente in PNG (nella stessa cartella del file Excel)
  • Creare in un colpo solo tante cartelle quanti sono i giocatori che parteciperanno (prende in esame il numero in M1)
  • Cancellare tutte le cartelle create in un colpo solo

Per come sono fatte le SUB in questo momento i fogli Schedina e FRASI non possono essere rinominati (senza dover modificare il codice di conseguenza intendo)

Come prima lascio sia il file allegato che il codice VBA.

Versione 2.png


Codice: Seleziona tutto
Sub CreaSingolaCartella()
Call CreaCartella
End Sub

Sub CreaCartellePerTutti()

'Variabile di QUANTI giocatori partecipano
Dim NumeroGiocatori As Integer
NumeroGiocatori = Worksheets("FRASI").Range("M1").Value

'Variabile della cartelle già create
Dim CartelleEsistenti As Integer
CartelleEsistenti = ThisWorkbook.Sheets.Count - 2 'Tolgo dal conto i 2 folgi di lavoro che servono a funzionamento del progetto


Dim CartelleDaCreare As Integer
CartelleDaCreare = NumeroGiocatori - CartelleEsistenti 'Calcolo quante altre cartelle vanno create, rispetto a quelle già esistenti, per arrivare al numero desiderato

    For i = 1 To CartelleDaCreare
        Call CreaCartella
    Next 'i
End Sub


Sub CreaCartella()
'Pulisci i valori precedenti
Worksheets("Schedina").Range("A2:J5").Value = ""

'Variabile di QUANTE frasi sorteggiare (la variabile determina anche quante caselle riempire)
Dim NumFrasi As Integer
NumFrasi = Worksheets("FRASI").Range("J1").Value

'Variabile col numero totale delle frasi possibili tra cui sorteggiare
Dim TotNumFrasi As Integer
TotNumFrasi = Application.WorksheetFunction.CountIf(Worksheets("FRASI").Range("A2:A1000"), "*")

'Creazione della lista casuale di frasi
Dim ListaFrasi As String
ListaFrasi = CreaNumeriUnivoci(NumFrasi, 1, TotNumFrasi)

'Creazione della lista casuale di caselle in cui mettere le frasi
Dim ListaCaselle As String
ListaCaselle = CreaNumeriUnivoci(NumFrasi, 1, 40) '40 è i numero delle caselle per ogni cartella

'Conversione da stringa a array delle frasi
Dim ArrayFrasi
ArrayFrasi = Split(ListaFrasi, ",")

'Conversione da stringa a array delle caselle
Dim ArrayCaselle
ArrayCaselle = Split(ListaCaselle, ",")

    'Chiamata della sub di riempimento delle celle per ogni elemento dei due array, che saranno sempre lunghi ugali
    For i = 0 To NumFrasi - 1
        Call RiempiCella(CInt(ArrayCaselle(i)), Worksheets("FRASI").Cells(ArrayFrasi(i) + 1, 1).Value) 'C'è il +1 perchè la colonna ha un header
    Next 'i
   
Worksheets("Schedina").Copy After:=Worksheets(Sheets.Count)
Worksheets(Sheets.Count).Visible = xlSheetVisible
Worksheets("Frasi").Activate
   
End Sub


Sub StampaTuttoInPDF()
'Seleziona dal terzo foglio in poi
 Worksheets(3).Activate
 
     'Imposta la Microsoft PDF Printer come stampante predefintia
    Application.ActivePrinter = "Microsoft Print to PDF su Ne03:"
    'Debug.Print Application.ActivePrinter 'Metti come predefinita la stampante "Microsoft Print to PDF" e usa questo comando per scoprire il nome preciso da usare alla riga sopra

    For x = 3 To ThisWorkbook.Sheets.Count
        Sheets(x).Select False  'False to extend the current selection to includeany previously selected objects and the specified object
        Sheets(x).PageSetup.Orientation = xlLandscape 'Set orientation to landscape
        Sheets(x).PageSetup.CenterHorizontally = True 'Center horizontally on page
        Sheets(x).PageSetup.CenterVertically = True 'Center vertically on page
        Sheets(x).PageSetup.PaperSize = xlPaperA4 ' Set paper size to A4
        Sheets(x).PageSetup.TopMargin = Application.CentimetersToPoints(1.91)
        Sheets(x).PageSetup.BottomMargin = Application.CentimetersToPoints(1.91)
        Sheets(x).PageSetup.LeftMargin = Application.CentimetersToPoints(0.64)
        Sheets(x).PageSetup.RightMargin = Application.CentimetersToPoints(0.64)
        Sheets(x).PageSetup.HeaderMargin = Application.CentimetersToPoints(0.76)
        Sheets(x).PageSetup.FooterMargin = Application.CentimetersToPoints(0.76)
        Sheets(x).PageSetup.Zoom = False  'If the selected range doesn't fit on one page, adjust the content's scale to fit on one page
        Sheets(x).PageSetup.FitToPagesWide = 1
        Sheets(x).PageSetup.FitToPagesTall = 1
    Next
'Lancia la stampa
Application.Dialogs(xlDialogPrint).Show
   
'Seleziona nuovamente il foglio delle Frasi
Worksheets("Frasi").Activate
End Sub


Sub SalvaComePNG()
If ThisWorkbook.Sheets.Count > 2 Then 'Se ci sono 32 folgi sono quelli di base e non c'è nulla da salvare!
For Each xWs In Application.ActiveWorkbook.Worksheets
    If xWs.Name <> "Schedina" And xWs.Name <> "FRASI" Then
       Dim table As Range
       Set table = xWs.Range("A1:J6")
           
       Dim myPath As String
       myPath = ThisWorkbook.Path & "\"

       Dim myPic As String
       myPic = xWs.Name & ".png"

       table.CopyPicture xlScreen, xlPicture

       Dim myWidth As Long
       myWidth = table.Width

       Dim myHeight As Long
       myHeight = table.Height
           
       Dim cht As ChartObject
       Set cht = xWs.ChartObjects.Add(Left:=0, Top:=0, Width:=myWidth, Height:=myHeight)
 
       cht.Activate

       cht.Chart.Paste
       cht.Chart.Export Filename:=myPath & myPic, Filtername:="png"

       cht.Delete
    End If
Next

Worksheets("Frasi").Activate

MsgBox ("Salvataggio PNG terminato!")

Else
MsgBox ("Non ci sono cartelle da salvare!")
End If
End Sub

Sub CancellaSchede()
Application.DisplayAlerts = False

    For Each xWs In Application.ActiveWorkbook.Worksheets
        If xWs.Name <> "Schedina" And xWs.Name <> "FRASI" Then
            xWs.Delete
        End If
    Next
Application.DisplayAlerts = True
     
Worksheets("Frasi").Activate
End Sub

Sub RiempiCella(CasellaDaRiempire As Integer, Testo As String)
'MsgBox ("Posizione: " & CasellaDaRiempire & vbCrLf & "Frase: " & Testo)

Dim Riga
Dim Colonna

'Seleziione della riga e della colonna da riempire
Select Case True
   Case CasellaDaRiempire >= 1 And CasellaDaRiempire <= 10
      Riga = 2
      Colonna = CasellaDaRiempire
   Case CasellaDaRiempire >= 11 And CasellaDaRiempire <= 20
      Riga = 3
      Colonna = CasellaDaRiempire - 10
   Case CasellaDaRiempire >= 21 And CasellaDaRiempire <= 30
      Riga = 4
      Colonna = CasellaDaRiempire - 20
   Case CasellaDaRiempire >= 31 And CasellaDaRiempire <= 40
      Riga = 5
      Colonna = CasellaDaRiempire - 30
End Select

'Posizionamento del testo
Worksheets("Schedina").Cells(Riga, Colonna).Value = Testo
End Sub

Function CreaNumeriUnivoci(NumeriDaTrovare As Integer, ValoreMinimo, ValoreMassimo) As String

'Questo è l'array che conterrà i valori univoci
Dim UniqueArray
UniqueArray = Array()

'Dichiarazione di una variabile booleana per vedere se il valore è già presente nell'array
Dim isFound As Boolean

'Contatore numeri unici trovati
Dim TotNumeriUnici As Integer
TotNumeriUnici = 0

'Numero casuale generato a ogni passaggio
Dim NumeroCasuale As Integer

'Ciclo di comparazione che imposta isFound come TRUE quando gli elementi comparati sono uguali
Do While TotNumeriUnici < NumeriDaTrovare
isFound = False 'Reset della variabile
NumeroCasuale = Int((ValoreMassimo - ValoreMinimo + 1) * Rnd + ValoreMinimo) 'Generazione del numero casuale da valutare
   
    For i = 0 To UBound(UniqueArray)
        If NumeroCasuale = UniqueArray(i) Then
            isFound = True
        End If
    Next 'i


    If isFound = False Then
       'Se il valore non è stato trovato nell'array di partenza viene aggiunto alla lista array degli univoci
        ReDim Preserve UniqueArray(UBound(UniqueArray) + 1) 'Allargo l'array
        UniqueArray(UBound(UniqueArray)) = NumeroCasuale 'Aggiungo il nuovo elemento

        CreaNumeriUnivoci = NumeroCasuale & "," & CreaNumeriUnivoci 'METTO IL TESTO

        'Aggiungo 1 al numeto di numero univoci trovati
        TotNumeriUnici = TotNumeriUnici + 1
    End If
Loop

'eliminazione virgola finale
If Right(CreaNumeriUnivoci, 1) = "," Then
   CreaNumeriUnivoci = Mid(CreaNumeriUnivoci, 1, Len(CreaNumeriUnivoci) - 1)
End If

End Function
Allegati
MOD Bingo delle Cazzate.xlsm
(37.09 KiB) Scaricato 30 volte
Avatar utente
Dylan666
Moderatore
 
Post: 39993
Iscritto il: 18/11/03 16:46

Re: Excel Estrazione casuale testo da colonna per bingo ca**

Postdi Anthony47 » 08/02/24 13:06

Benfatto e ben detto
Dai, ci vediamo al prossimo kick-off aziendale a vendere le schede a 1€ l'una, anche gli oratori ci ringrazieranno.

Ho cercato anche io la storia di questo gioco cercando "bullshit bingo", e la piu' vecchia testimonianza e' datata 15 feb 1996 (non so quanto e' precisa la datazione di google), sulla pagina https://komplexify.com/blog/math-humor- ... l-nerdery/
Il fatto che le "testimonianze" siano quasi le stesse che leggiamo oggi fa pensare che il gioco fosse gia' stato inventato

Ciao a tutti
Avatar utente
Anthony47
Moderatore
 
Post: 19212
Iscritto il: 21/03/06 16:03
Località: Ivrea

Re: Excel Estrazione casuale testo da colonna per bingo ca**

Postdi Dylan666 » 08/02/24 17:46

Partendo dalla tua pagina mi sono messo a cercare "BS Bingo" e sono arrivato qui:
https://en.wikipedia.org/wiki/Buzzword_bingo

Sembra quindi che il gioco sia chiamato anche "Buzzword bingo" o "turkey bingo" in ambiente universitario.

Ho deciso che cambierò un po' l'intestazione della mia cartella perché il regolamento originario si basava sulla distribuzione di cartelle tutte identiche e si vinceva alla chiamata di 5 parole (e in alcune versioni dovevano essere consecutive e tutte allineate in orizzontale o verticale o diagonale).

Da un lato le cartelle identiche avevano il vantaggio che la vittoria era "collettiva" di tutti i partecipanti e così pure l'esultanza (che probabilmente veniva scambiata dallo speaker per entusiasmo provocato dalle proprie parole) ma dall'altra viene a mancare la competitività propria del Bingo :D

PS: anche la ricerca in Google Immagini dà le sue soddisfazioni:
https://www.google.com/search?q=bs+bingo&tbm=isch
Avatar utente
Dylan666
Moderatore
 
Post: 39993
Iscritto il: 18/11/03 16:46

Re: Excel Estrazione casuale testo da colonna per bingo ca**

Postdi Dylan666 » 08/02/24 18:03

Ulteriore aggiornamento (sì, mi sono appassionato alla questione...).
Esiste un sito dedicato al gioco che dal 2005 crea schede personalizzate anche per il confronto dei candidati per il presidente Americano
https://www.buzzwordbingogame.com/cards ... umpbiden2/

Qui la storia secondo il suo webmaster:
https://www.buzzwordbingogame.com/about/
Avatar utente
Dylan666
Moderatore
 
Post: 39993
Iscritto il: 18/11/03 16:46


Torna a Applicazioni Office Windows


Topic correlati a "Excel Estrazione casuale testo da colonna per bingo ca**ate":


Chi c’è in linea

Visitano il forum: Nessuno e 33 ospiti