Calcolo numero giorni settimana nel periodo

[Ricky0185]

Buongiorno, vorrei, per esempio, calcolare quante volte il giorno "lunedì" compare in un determinato periodo. Il periodo è da quello inserito in una cella qualsiasi =OGGI() a fine mese. Usando la formula

Codice: Seleziona tutto

=GIORNI.LAVORATIVI.TOT.INTL(DATA(ANNO(A1);MESE(A1);1);FINE.MESE(A1;0);
RIPETI("1";B1-1) & "0" & RIPETI("1";7-B1))

dove A1 è =OGGI() e B1 è l'indicatore 1 del giorno settimana =lunedì, ma risulta #NOME?. Manca forse qualche componente aggiuntivo?
Grazie.
Cordiali saluti
R
XP+Office2003

[Marius44]

Ciao
Ma da dove hai preso quella formula?
Se non ricordo male nella tua versione (2003) non esiste quella funzione ed ecco perchè ti risponde in quel modo.
Credo sia stata inserita nella versione 2010.

Ciao,
Mario

[Anthony47]

Eh sì, con Office2003 certe funzioni si vedono col cannocchiale...

Prova con

Codice: Seleziona tutto

=SOMMA(--(GIORNO.SETTIMANA(RIF.RIGA(INDIRETTO(A2&":"&FINE.MESE(A2;0))))=B2))

Contr-Maiusc-Enter; la data iniziale e' in A2, il Giorno da contare e' in B2

Ciao

[Ricky0185]

Niente da fare, sempre #NOME? risulta seppur inserito come matriciale Ctrl+Shift+Enter. Ho controllato nei componenti aggiuntivi e non è spuntato Strumenti di analisi. Cercando di installarlo compare prima il messaggio centrale, poi quello sopra ed infine quello sotto, nonostante l'xll sia proprio in quella dir.

Vedo di risolvere questo problema poi riverifico.
Grazie ad entrambi.
Saluti
R

[Anthony47]

In effetti FINE.MESE e' nell'addin "Strumenti di analisi"...
Se non riesci ad installarlo allora prova con

Codice: Seleziona tutto

=MATR.SOMMA.PRODOTTO(--(GIORNO.SETTIMANA(RIF.RIGA(INDIRETTO(A2&":"&(A2+32)));2)=B2);--(MESE(RIF.RIGA(INDIRETTO(A2&":"&(A2+32))))=MESE(A2)))

Non serve Contr-Maiusc-Enter

Mi sono accorto che nella formula che ti avevo dato prima non ho indicato il "Tipo" per il risultato di Giorno.Settimana: per usare 1=Lun, 2=Mart etc la formula deve essere

Codice: Seleziona tutto

=SOMMA(--(GIORNO.SETTIMANA(RIF.RIGA(INDIRETTO(A2&":"&FINE.MESE(A2;0)));2)=B2))

(nota il ";2" che prima non avevo messo)

[Ricky0185]

Entrambe le formule danno il risultato sperato, 2 volte con l'1 (il lunedì) ed 1 volta con il 2, 3, etc, ma con il 365, con il 2003 non sono ancora riuscito ad installare il componente aggiuntivo. Conto di reinstallare Office tra oggi e domani. anche se quell'errore 1260 mi preoccupa.che si ripresenta anche dopo aver manipolato con la Personalizzazione avanzata applicazioni in Aggiungi/Rimuovi caratteristiche dell'Installazione Applicazioni.
Vi saluto
R

[Anthony47]

Con MATR.SOMMA.PRODOTTO non dovresti avere bisogno di Addin, prova

[Ricky0185]

Purtroppo ho già disinstallato Office e contavo di reinstallarlo stasera. Mi sono dato tante noci sulla testa che ora ho malditesta (le noci a Bologna sono dei cazzotti sulla testa dati con la nocca del dito medio). Ti spiego. Sull'excel che ho disinstallato e sul quale non sono riuscito ad attivare quel componente aggiuntivo, AMBEDUE le soluzioni da te suggerite davano come risultato 02/01/2000. Prova e riprova ma sempre 02/01/2000, quindi senza ragionare...sbagliato. Provo sull'altro portatile con win11 ed il 365 e tutte e due le formule davano un risultato corretto. E via a disinstallare Office sul portatile con winxp. Poi strada facendo (la disinstallazione dura un paio di minuti) mi si è accesa una lampadina: le celle su cui provavo le 2 formule si trovavano sulla prima colonna del foglio, quella delle date formattata interamente come data, vuoi vedere che le celle che mi davano 02/01/2000 se formattate come numero avrebbero dato il risultato corretto? Fatta verifica sul 365 e via con le noci, raddoppiate poichè la disinstallazione sull'altro portatile era ormai terminata.
Conclusione: le formule funzionavano perfettamente, ma il risultato appariva come data causa la formattazione della colonna.
Ciao ciao, mi è passata la voglia di reinstallare office, lo farò domani.
Buona Domenica.
R

[Ricky0185]

In effetti nel 2003 con

Codice: Seleziona tutto

=MATR.SOMMA.PRODOTTO(--(GIORNO.SETTIMANA(RIF.RIGA(INDIRETTO(H317&":"&(H317+32)));2)=I317);--(MESE(RIF.RIGA(INDIRETTO(H317&":"&(H317+32))))=MESE(H317)))

funziona anche senza Addin, che continua però a darmi Errore 1260 tentando di installarlo anche su una nuova installazione di Office2003.
Ma la mia domanda riguarda che valore/i debbo inserire come indicatore/i se volessi ricavare per esempio quante volte in un determinato periodo compaiono il martedì (2) ed il venerdì (5). Per esempio da oggi 24/07 al 31/07 sarebbe 2, 1 volta il 2 ed 1 volta il 5

[Anthony47]

Lavorando con la formula MATR.SOMMA.PRODOTTO, la cosa piu’ semplice e’ fare =FormulaLunedì + FormulaMartedì
Oppure lavori sul termine “Matrice1”; ad esempio:

Codice: Seleziona tutto

=MATR.SOMMA.PRODOTTO((GIORNO.SETTIMANA(RIF.RIGA(INDIRETTO(A2&":"&(A2+32)));2)=1)+(GIORNO.SETTIMANA(RIF.RIGA(INDIRETTO(A2&":"&(A2+32)));2)=2);--(MESE(RIF.RIGA(INDIRETTO(A2&":"&(A2+32))))=MESE(A2)))


Noterai che il termine “Matrice1” ora e’ la somma di due condizioni, e che i giorni della settimana (1 e 2) ora sono “cablati” nella formula; ovviamente se vuoi puoi riportarli su qualche cella. Anzi, se vuoi puoi preparare una formula che in “Matrice1” sommi N condizioni che scrivi in N celle e poi compili solo le celle con i gg che ti interessano e lasci vuote le altre

Non ti so aiutare per l'installazione dell'addin (per quel che ricordo era parte dell'installazione standard, poi andava solo abilitato)

[Ricky0185]

Perfetto. Grazie
R

[Ricky0185]

Buonasera, utilizzando MATR.SOMMA.PRODOTTO risolvo quando debbo ricavare i giorni della settimana, però il problema è se debbo ricavare, per esempio, l'ultimo venerdì del mese corrente.

Si tratta di un badget, molto ridotto e spersonalizzato, e speravo che giocherellando con il 32 della formula sarei riuscito nell'intento, ma debbo chiedere il Vs aiuto. Mi scuso per non essere riuscito ad allegare il file, ovviamente nell'immagine le formule nella colonna I non appaiono, ma sono tutte Matr.Somma.Prodotto
Ringrazio e saluto
R

[Anthony47]

Si, ma da quali dati si parte e che cosa bisogna calcolare?
Perche' nel quesito precedente bisognava calcolare quanti lunedì (esempio) ci sono da oggi a fine mese; mentre di "ultimo venerdì del mese si sa che ce n'è 1 al mese...

[Ricky0185]

Perche' nel quesito precedente bisognava calcolare quanti lunedì (esempio) ci sono da oggi a fine mese; mentre di "ultimo venerdì del mese si sa che ce n'è 1 al mese...

Giusto. Lo scopo di questo file, che come inizio è quello di verificare il numero delle ricorrenze di un preciso giorno della settimana nel periodo che va da una data (Adesso()) a fine mese, in seconda battuta tale numero poi viene moltiplicato (il numero delle ricorrenze) per un determinato valore in euro. Alla fine ho un totale, che ad inizio mese rappresenta il relativo budget. E fin qui con Matr.Somma.Prodotto viene reperito il numero delle ricorrenze (meno il giardino).
Il secondo obbiettivo di questo file sarà quello di depennare le spese "maturate" man mano che passano i giorni. Oggi è giovedì 27, nello schema del post precedente mi resterebbe da pagare il Giardino, il lunedì 31 per la colf, il venerdì 28 per il carburante e 4 giorni per alimentari. Oggi i soldi che debbo avere in tasca sono 245 euro, ma ad inizio mese (come specificato tra parentesi nelle righe della colonna H) dovevano essere 1.045 euro.
Per il giardino, oggi debbo ancora pagarlo, ma sabato 29 quei 130 euro non ci saranno più, ecco perchè mi serve reperire l'ultimo venerdì del mese. Spero di aver chiarito il tuo quesito.
Ti saluto
R

[Ricky0185]

Per esempio questa

Codice: Seleziona tutto

=ARROTONDA.ECCESSO(FINE.MESE(H317;0)-5;7)-1

che mi da la data dell'ultimo venerdì del mese. Ma poi per eliminare la spesa prevista per quel determinato giorno già trascorso, =Oggi() o =Adesso() che sta in H317, cerco aiuto.
Ciao

[Anthony47]

Ma "FINE.MESE" e' una funzione disponibile?
Se hai calcolato la data "soglia" (l'ultimo venerdì) allora potresti fare

Codice: Seleziona tutto

AncoraDaSpendere=Se(Oggi<DataCalcolata;LaQuotaGiardino;0)

Codice: Seleziona tutto

GiàSpeso=se(Oggi<DataCalcolata;0;LaQuotaGiardino)

Se invece serve usare Matr.Somma.Prodotto, allora calcoliamo quanti Venerdì mancano a fine mese; se >0 allora l'ultimo venerdì è ancora da venire.
In Formula:

Codice: Seleziona tutto

=--(MATR.SOMMA.PRODOTTO(--(GIORNO.SETTIMANA(RIF.RIGA(INDIRETTO(A2&":"&(A2+32)));2)=5);--(MESE(RIF.RIGA(INDIRETTO(A2&":"&(A2+32))))=MESE(A2)))>0)

A2 e' la cella che continene la data odierna

Senza i "--" iniziali ti darebbe Vero oppure Falso, che forse e' piu' comodo da usare poi in altre formule dove hai bisogno di fare calcoli sia nel caso di Vero che di Falso.

Esempio:

Codice: Seleziona tutto

AncoraDaSpendere = SE(VeroFalso;LaQuotaGiardino;0)

Codice: Seleziona tutto

GiàSpeso = SE(VeroFalso;0;LaQuotaGiardino)

(VeroFalso e' la cella dove hai calcolato l'ultimo venerdì del mese)

[Ricky0185]

Il pranzo porta consiglio. A scevellarmi per eliminare le spese man mano che maturano con il trascorrere dei giorni. Ma se la formula (di Anthony) che le registra e le fa sparire è legata al trascorrere dei giorni....scemo scemo....le registrazioni spariscono in automatico. In questo file appunto con le formule di Anthony e con qualche altra formuletta l'obbiettivo è raggiunto. Neee.
Provato anche cambiando la data di Oggi().
Salutandoti mi scuso per il tempo che ti ho fatto perdere.
R

[Ricky0185]

Buongiorno, purtroppo il link dell'ultimo post non funziona più e proprio quando il file linkato, che ho ampiamente utilizzato dal momento della sua elaborazione (con il Vs aiuto, in particolare di Anthony), stranamente questa mattina quando l'ho aperto al posto delle formule comparivano solo valori. Le ho provate tutte, dal ripristino a data precedente all'inserimento delle formule fino a cercare di ricompilare le formule, quasi tutte MATR.SOMMA.PRODOTTO, ma inutilmente causa la mia poca dimestichezza con le formule. Non so se sia possibile recuperare il file o se qualcuno lo conservi, io sono solo riuscito a compilare quella che mi trova l'ultimo martedì del mese in A1=Oggi(). La tabella è quella del post del 26/07/23 16:49 eliminando la riga che riguarda la colf, e cioè

Oggi è lunedì 14 settembre 2026
Giardino 29/09/26 170,00 qui l'ultimo martedì del mese x 170
Diesel 2,00 40,00 qui i venerdì del mese che restano a fine mese x 20
Spese 16,00 320,00 qui quanti giorni restano a fine mese x 20
Totale 530,00
Sono solo riuscito a sviluppare la formula che mi da l'ultimo martedì del mese

Codice: Seleziona tutto

=SE(GIORNO.SETTIMANA(DATA(ANNO(A1);MESE(A1)+1;1))=7;DATA(ANNO(A1);MESE(A1)+1;1)-1;DATA(ANNO(OGGI());MESE(OGGI())+1;1)-GIORNO.SETTIMANA(DATA(ANNO(OGGI());MESE(OGGI())+1;1))+3)

che tuttavia sicuramente dufferisce da quella di Anthony.
Se qualcuno ha voglia e tempo per aiutarmi a ricostruire la tabella, che insieme a molte altre voci rappresenta un budget mensile, gliene sono grato e lo ringraziofin d'ora.
Cordiali saluti
R
PS Se richiesto apro un nuovo 3d

[Anthony47]

Non ho copia di quel file (la cosa più recente è un file di Feb 2026 che si chiamava Verifica.xls)

Prova nella directory C:\Users\NOMEUTENTE\AppData\Roaming\Microsoft\Excel (questa però e' riferita a Win 11), dovresti trovare file strani di tipo .XAR; guarda le date e prova ad aprirli con Excel, magari sei fortunato e trovi qualcosa...

Per XP la directory potrebbe essere C:\Documents and Settings\NOMEUTENTE\Application Data\Microsoft\Excel\
Se non trovi niente vedremo come fare