Invio dati da foglio excel a pagina web ad ogni modifica

[systemcrack]

Andando a caso con risposte e considerazioni...

Per l'errore "Riferimento non valido o non qualificato": c'e' un motivo che ti ha fatto eliminare (all'interno della Sub OneMinuteMacro) l'istruzione With ActiveWorkbook.WebOptions? Reinseriscila e ti troverai bene.

Non mi sembrava di aver tolto nulla dalla tua macro..

Mi ero accorto di alcuni svarioni sul codice che avevo postato, ho trovato solo ora il tempo per ricontrollare e aggiustare.

Non ti preoccupare e non lo dire nemmeno.. sei più che gentilissimo!

Il codice complessivo delle macro "OnTime" dovrebbe essere:

Codice: Seleziona tutto

Public Next1Min As Date, Next15Min As Date, Next30Min As Date, Next60Min As Date
Dim StopAll As Boolean      'Stop all the schedules

'
'QUESTA E' LA TUA MACRO PRINCIPALE, quella che hai chiamato Macro3:
Sub OneMinuteMacro()                           'This is your 1 minute macro with amendments
If StopAll = False Then                        ' StopAll??
    If Next15Min < (Now - TimeSerial(0, 1, 0)) Then
        Next15Min = Now + TimeSerial(0, 14, 0)                   '15
        Application.OnTime Next15Min, "Macro15Min"
    End If
'
  With ActiveWorkbook.WebOptions
        .RelyOnCSS = True
        .OrganizeInFolder = True
        .UseLongFileNames = True
        .DownloadComponents = False
        .RelyOnVML = False
        .AllowPNG = True
        .ScreenSize = msoScreenSize1024x768
        .PixelsPerInch = 96
        .Encoding = msoEncodingWestern
    End With
    With Application.DefaultWebOptions
        .SaveHiddenData = True
        .LoadPictures = False
        .UpdateLinksOnSave = True
        .CheckIfOfficeIsHTMLEditor = True
        .AlwaysSaveInDefaultEncoding = False
        .SaveNewWebPagesAsWebArchives = True
    End With
'>>>>>>CORREGGI I PERCORSI COME DA TUA SITUAZIONE                                            <<<<<
    With ActiveWorkbook.PublishObjects.Add(xlSourceRange, _
        "D:\PROVA\schema-entrate.htm" _
        , "ENTRATE", "$A$1:$K$161", xlHtmlStatic, "schema entrate da dup1_6262", _
        "Schema Entrate")
        .Publish (True)
        .AutoRepublish = False
    End With
    ChDir "C:\Users\mrosini\Desktop\DA DUPLICARE schema entrate\online"                         '<<<<  SERVE??
'
'Then Reschedue myself:
    Next1Min = Now + TimeSerial(0, 1, 2)
    Debug.Print "Eseguo MacroOneMin", Now, Next1Min
    Application.OnTime Next1Min, "OneMinuteMacro"
Else
'Stop all schedules:
    On Error Resume Next
        Application.OnTime Next1Min, "OneMinuteMacro", , False
        Application.OnTime Next15Min, "Macro15Min", , False
        Application.OnTime Next30Min, "Macro30Min", , False
        Application.OnTime Next60Min, "OneHourMacro", , False
    On Error GoTo 0
End If
End Sub

Sub Macro15Min()                                 'MACRO DI CONTROLLO
If StopAll = False Then
    If Next1Min < (Now - TimeSerial(0, 0, 30)) Then
        Next1Min = Now + TimeSerial(0, 1, 2)
        Application.OnTime Next1Min, "OneMinuteMacro"
    End If
    If Next30Min < (Now - TimeSerial(0, 1, 0)) Then
        Next30Min = Now + TimeSerial(0, 30, 0)               '30
        Application.OnTime Next30Min, "Macro30Min"
    End If
'Reschedue myself:
    Next15Min = Now + TimeSerial(0, 14, 0)                   '15
    Debug.Print "Eseguo Macro15Min", Now, Next15Min
    Application.OnTime Next15Min, "Macro15Min"
Else
'Stop all schedules:
    On Error Resume Next
        Application.OnTime Next1Min, "OneMinuteMacro", , False
        Application.OnTime Next15Min, "Macro15Min", , False
        Application.OnTime Next30Min, "Macro30Min", , False
        Application.OnTime Next60Min, "OneHourMacro", , False
    On Error GoTo 0
End If
End Sub

Sub Macro30Min()                                 'MACRO DI CONTROLLO
If StopAll = False Then
    If Next15Min < (Now - TimeSerial(0, 1, 0)) Then
        Next15Min = Now + TimeSerial(0, 14, 0)               '15
        Application.OnTime Next15Min, "Macro15Min"
    End If
    If Next60Min < (Now - TimeSerial(0, 5, 0)) Then
        Next60Min = Now + TimeSerial(0, 59, 0)               '60
        Application.OnTime Next60Min, "OneHourMacro"
    End If
'Reschedue myself:
    Next30Min = Now + TimeSerial(0, 30, 0)
    Debug.Print "Eseguo Macro30Min", Now, Next30Min         '30
    Application.OnTime Next30Min, "Macro30Min"
Else
'Stop all schedules:
    On Error Resume Next
        Application.OnTime Next1Min, "OneMinuteMacro", , False
        Application.OnTime Next15Min, "Macro15Min", , False
        Application.OnTime Next30Min, "Macro30Min", , False
        Application.OnTime Next60Min, "OneHourMacro", , False
    On Error GoTo 0
End If

End Sub
Sub OneHourMacro()                                 'MACRO DI CONTROLLO
If StopAll = False Then
    If Next30Min < (Now - TimeSerial(0, 5, 0)) Then
        Next30Min = Now + TimeSerial(0, 30, 0)                   '30
        Application.OnTime Next30Min, "Macro30Min"
    End If
    If Next1Min < (Now - TimeSerial(0, 0, 30)) Then
        Next1Min = Now + TimeSerial(0, 1, 1)
        Application.OnTime Next1Min, "OneMinuteMacro"
    End If
'Reschedue myself:
    Next60Min = Now + TimeSerial(0, 59, 0)                       '60
    Debug.Print "Eseguo Macro60Min", Now, Next60Min
    Application.OnTime Next60Min, "OneHourMacro"
Else
'Stop all schedules:
    On Error Resume Next
        Application.OnTime Next1Min, "OneMinuteMacro", , False
        Application.OnTime Next15Min, "Macro15Min", , False
        Application.OnTime Next30Min, "Macro30Min", , False
        Application.OnTime Next60Min, "OneHourMacro", , False
    On Error GoTo 0
End If
End Sub


Ci sono due righe marcate <<< da esaminare e correggere

Anche il codice della Workbook_Open conteneva un errore; la macro completa:

Codice: Seleziona tutto

Private Sub Workbook_Open()
    Next1Min = Now + TimeSerial(0, 1, 2)
    Application.OnTime NextOneMin, "OneMinuteMacro"
    Next15Min = Now + TimeSerial(0, 14, 0)
    Application.OnTime Next15Min, "Macro15Min"
    Next30Min = Now + TimeSerial(0, 30, 0)
    Application.OnTime Next30Min, "Macro30Min"
    Next60Min = Now + TimeSerial(0, 59, 0)
    Application.OnTime Next60Min, "OneHourMacro"
End Sub


Ciao

Allora.. ho sostituito lo script corretto, come da te indicato dopo aver anche sistemato i vari percorsi.
Ho inoltre inserito questo codice in "Questa cartella di lavoro":

Codice: Seleziona tutto

Private Sub Workbook_Open()
    Next1Min = Now + TimeSerial(0, 1, 2)
    Application.OnTime NextOneMin, "OneMinuteMacro"
    Next15Min = Now + TimeSerial(0, 14, 0)
    Application.OnTime Next15Min, "Macro15Min"
    Next30Min = Now + TimeSerial(0, 30, 0)
    Application.OnTime Next30Min, "Macro30Min"
    Next60Min = Now + TimeSerial(0, 59, 0)
    Application.OnTime Next60Min, "OneHourMacro"
End Sub

Ora però all'apertura del file si genera questo errore:



P.s.
Mi ha dato errore due volte (dopo averlo aperto e chiuso 2 volte) poi ora non lo da più..

P.P.S.
Dicevo sul serio sul fare una donazione.. o al forum o direttamente a te..

[systemcrack]

Per quanto invece riguarda questo:

Codice: Seleziona tutto

'>>>>>>CORREGGI I PERCORSI COME DA TUA SITUAZIONE                                            <<<<<
    With ActiveWorkbook.PublishObjects.Add(xlSourceRange, _
        "D:\PROVA\schema-entrate.htm" _
        , "ENTRATE", "$A$1:$K$161", xlHtmlStatic, "schema entrate da dup1_6262", _
        "Schema Entrate")
        .Publish (True)
        .AutoRepublish = False
    End With
    ChDir "C:\Users\mrosini\Desktop\DA DUPLICARE schema entrate\online"                         '<<<<  SERVE??

Ed in particolar modo questa parte qui:

Codice: Seleziona tutto

ChDir "C:\Users\mrosini\Desktop\DA DUPLICARE schema entrate\online"                         '<<<<  SERVE??

Serve perchè è il percorso di dove salva il file una volta trasformato in html, che una cartella differente da quella di partenza.

[systemcrack]

Cercando nel vba quando mi da l'errore cliccando su debug mi dice dov'è l'errore.


In pratica c'è qualche cosa che non va in:

Codice: Seleziona tutto

With ActiveWorkbook.PublishObjects.Add(xlSourceRange, _
        "D:\PROVA\schema-entrate.htm" _
        , "ENTRATE", "$A$1:$K$161", xlHtmlStatic, "schema entrate da dup1_6262", _
        "Schema Entrate")

Ma questa parte me l'aveva restituita il registratore di macro insito in Excel.. ?!

P.S.
Credo di avere capito.. il file quando verrà utilizzato non si chiamerà schema entrate da dup1_6262 ma bensì schema entrate OGGI

P.P.S
Niente.. mi da errore anche così:

Codice: Seleziona tutto

With ActiveWorkbook.PublishObjects.Add(xlSourceRange, _
        "C:\Users\Marco\Documents\excel\schema entrate OGGI.htm", "ENTRATE", _
        "$A$1:$K$161", xlHtmlStatic, "schema entrate OGGI_28591", "Schema Entrate")

[Anthony47]

Le macro di workbook_open hanno la tendenza a segnalare errori se il file viene inizialmente aperto in modalità protetta; visto che è scomparso penso fosse questo il tuo caso.

L'ultimo errore: nel primo msg c'è ancora la directory che avevo usato per le mie prove. Quel che potrebbe dare errore è il percorso, se non esiste, non il nome file.
Quella parte di codice è tua, io avevo proposto di usare SalvaConNome.

Ciao

[systemcrack]

Le macro di workbook_open hanno la tendenza a segnalare errori se il file viene aperto in modalità protetta; visto che è scomparso penso fosse questo il tuo caso.

L'ultimo errore: nel primo msg c'è ancora la directory che avevo usato per le mie prove. Quel che potrebbe dare errore è il percorso, se non esiste, non il nome file.
Quella parte di codice è tua, io avevo proposto di usare SalvaConNome.

Ciao

Purtroppo non posso aggiungere lavoro ai ragazzi in ufficio ed il file deve salvarsi sempre col medesimo nome se voglio che venga sempre visualizzato allo stesso link.

Comunque non va..
Sono andato qui,

Vai sul vba e apri la "finestra Immediata" (dovrebbe bastare la combinazione Contr-g; oppure Menu /Visualizza /Finestra Immediata): qui dovresti trovare traccia di quando le macro vengono eseguite, con un messaggio tipo Eseguo OneMinuteMacro 02/02/2021 19:30;

come da tuo consiglio e c'è il vuoto assoluto.. un bianco talmente bianco, che nemmeno sulle Alpi svizzere!

L'ultimo errore: nel primo msg c'è ancora la directory che avevo usato per le mie prove. Quel che potrebbe dare errore è il percorso, se non esiste, non il nome file.
Quella parte di codice è tua, io avevo proposto di usare SalvaConNome.

Abbi pazienza, ma non ho capito a quale ti riferisci

[Anthony47]

NON STAI USANDO LE ULTIME MACRO, quelle di ieri sera tardi/stamattina PRESTO!
Almeno così sembrava nel msg prima che tu lo modificarsi.

[systemcrack]

NON STAI USANDO LE ULTIME MACRO, quelle di ieri sera tardi/stamattina PRESTO!
Almeno così sembrava nel msg prima che tu lo modificarsi.

Ho visto i messaggi solo sta mattina, perciò sono partito diretto con i codici corretti... più tardi ci riguardo meglio..

No no ciò che hai visto era un copia ed incolla mal riuscito fatto col cellulare

I codici che mi hai inviato questa mattina alle 2 li ho modificati, lì dove avevi indicato.. forse ho dimenticato qualcosa

[systemcrack]

Le macro di workbook_open hanno la tendenza a segnalare errori se il file viene inizialmente aperto in modalità protetta; visto che è scomparso penso fosse questo il tuo caso.

Non credo ha dato un altro errore dopo qualche ora che non lo aprivo:

L'ultimo errore: nel primo msg c'è ancora la directory che avevo usato per le mie prove. Quel che potrebbe dare errore è il percorso, se non esiste, non il nome file.
Quella parte di codice è tua, io avevo proposto di usare SalvaConNome.

Ciao

Ho fatto un copia ed incolla dei miei parametri, mi sembra tutto in ordine

Codice: Seleziona tutto

'>>>>>>CORREGGI I PERCORSI COME DA TUA SITUAZIONE                                            <<<<<
    With ActiveWorkbook.PublishObjects.Add(xlSourceRange, _
        "C:\Users\Marco\Documents\excel\schema entrate OGGI.htm", "ENTRATE", _
        "$A$1:$K$161", xlHtmlStatic, "schema entrate OGGI_28591", "Schema Entrate")
        .Publish (True)
        .AutoRepublish = False
    End With
    ChDir "C:\Users\mrosini\Desktop\DA DUPLICARE schema entrate\online"                         '<<<<  SERVE??

[systemcrack]

Ok.. ci siamo.. forse avevo smanettato troppo.. ora ricominciando su un file "vergine" funziona.. se clicco attiva la macro oneminutemacro, funziona o almeno.. ora visualizzo l'evento avvenuto.

Ora 2 cose.. la prima:
Se non avvio manualmente la macro non parte dopo che ho aperto il file excel

la seconda cosa è che ho ricevuto un altro tipo di errore ora ti allego di seguito due screen che spero siano esplicativi:



Scusami se ti faccio impazzire Anthony e grazie di cuore per tutto ciò che fai e hai fatto fino ad ora.

[Anthony47]

Grrrr
Continuo a darti il codice sbagliato della WorkBook_Open; vediamo se stavolta ci riesco (a sbagliare di nuovo):

Codice: Seleziona tutto

Private Sub Workbook_Open()
    Next1Min = Now + TimeSerial(0, 1, 2)
    Application.OnTime Next1Min, "OneMinuteMacro"
    Next15Min = Now + TimeSerial(0, 14, 0)
    Application.OnTime Next15Min, "Macro15Min"
    Next30Min = Now + TimeSerial(0, 30, 0)
    Application.OnTime Next30Min, "Macro30Min"
    Next60Min = Now + TimeSerial(0, 59, 0)
    Application.OnTime Next60Min, "OneHourMacro"
End Sub


E' determinante per avviare regolarmente le schedulazioni

Quanto ai problemi del Publish devi debuggare tu la situazione; certamente se il file da scrivere fosse in uso avresti un errore vba, ma dovrebbe essere di tipo 1004.
Prova comunque a mantenere solo i parametri fondamentali:

Codice: Seleziona tutto

    With ActiveWorkbook.PublishObjects.Add(SourceType:=xlSourceRange, _
        Filename:="C:\Users\mrosini\Desktop\DA DUPLICARE schema entrate.htm" _
        , Sheet:="ENTRATE", Source:="$A$1:$K$161", HtmlType:=xlHtmlStatic)
        .Publish (True)
    End With


Ciao

[systemcrack]

Di fatti.. ho il timore che perché ftpbox invia, non riesce a salvarlo e sovrascrivere il precedente file in quanto lo vede in uso

[systemcrack]

Dopo qualche esperimento di stamane credo che ci siamo quasi..
Correggendo il WorkBook_Open sembra che qualcosa in più si muova, ma:

1- non ho ancora capito, una volta aperto il file, quando si dovrebbero attivare i cicli delle macro, perchè mi pare che finchè non lancio io da vb non parta nulla..

2- Ho modificato come da te indicato la parte di codice riguardante la locazione del file che è diventata così:

Codice: Seleziona tutto

With ActiveWorkbook.PublishObjects.Add(SourceType:=xlSourceRange, _
        Filename:="C:\Users\mrosini\Desktop\DA DUPLICARE schema entrate\online\schema-entrate.htm" _
        , Sheet:="ENTRATE", Source:="$A$1:$K$161", HtmlType:=xlHtmlStatic)
        .Publish (True)
    End With

Ora fa 3 cicli della OneMinuteMacro, ma al terzo da sempre errore di pubblicazione di cui ti allego gli screen di seguito:


In pausa pranzo lascerò il file aperto così lo lascio lavorare un'ora e mezza e vedo che succede.

[systemcrack]

Niente.. anche dopo una volta da errore.. cioè quando fa partire la oneminutemacro per la seconda volta.
Ho notato che nella cartella di destinazione sul pc crea un file strano.. schema-entrate.ht_
potrebbe essere lì l'errore..? Per qualche strano motivo quando risalva, inserisce un'estensione sbagliata.. che sia per questo che non riesce a pubblicarlo?

[Anthony47]

Se il file e' bloccato da altre operazioni esce appunto Error 1004, e se l' ftp richiede parecchi secondi la probabilita' che succeda sono alte...
Metti una gestione dell'errore su quel blocco, modificando quella parte di codice in

Codice: Seleziona tutto

    With ActiveWorkbook.PublishObjects.Add(SourceType:=xlSourceRange, _
        filename:="C:\Users\mrosini\Desktop\DA DUPLICARE schema entrate.htm" _
        , Sheet:="ENTRATE", Source:="$A$1:$K$161", HtmlType:=xlHtmlStatic)
        On Error Resume Next
        .Publish (True)
        If Err.Number <> 0 Then
            Debug.Print Now, " - Publish failure, Err. " & Err.Number
            Debug.Print Err.Description
        End If
        On Error GoTo 0
    End With


Cioe' la macro prova a riscrivere il file, se non riesce si limita a scriverlo sulla "Finestra Immediata" del vba, dove tu puoi esaminare il log e capire quante volte riesce e quante fallisce.
Ricorda che nella finestra Immediata viene scritto anche il msg di macro eseguita, quindi non dovrebbe essere difficile farsi un'idea di quanto produttivo sia il processo

non ho ancora capito, una volta aperto il file, quando si dovrebbero attivare i cicli delle macro, perchè mi pare che finchè non lancio io da vb non parta nulla..

Le macro si dovrebbero attivare sull'apertura del file, con il codice giusto della Worlbook_Open.
Puoi ispezionare la Finestra Immediata e vedere se ci trovi le registrazioni del run delle macro; se non ci sono, aspetta 15 minuti e ricontrolla (la Macro15Min dovrebbe rischedulare la OneMinuteMacro)

Cial

[systemcrack]

Se il file e' bloccato da altre operazioni esce appunto Error 1004, e se l' ftp richiede parecchi secondi la probabilita' che succeda sono alte...
Metti una gestione dell'errore su quel blocco, modificando quella parte di codice in

Codice: Seleziona tutto

    With ActiveWorkbook.PublishObjects.Add(SourceType:=xlSourceRange, _
        filename:="C:\Users\mrosini\Desktop\DA DUPLICARE schema entrate.htm" _
        , Sheet:="ENTRATE", Source:="$A$1:$K$161", HtmlType:=xlHtmlStatic)
        On Error Resume Next
        .Publish (True)
        If Err.Number <> 0 Then
            Debug.Print Now, " - Publish failure, Err. " & Err.Number
            Debug.Print Err.Description
        End If
        On Error GoTo 0
    End With


Cioe' la macro prova a riscrivere il file, se non riesce si limita a scriverlo sulla "Finestra Immediata" del vba, dove tu puoi esaminare il log e capire quante volte riesce e quante fallisce.
Ricorda che nella finestra Immediata viene scritto anche il msg di macro eseguita, quindi non dovrebbe essere difficile farsi un'idea di quanto produttivo sia il processo

non ho ancora capito, una volta aperto il file, quando si dovrebbero attivare i cicli delle macro, perchè mi pare che finchè non lancio io da vb non parta nulla..

Le macro si dovrebbero attivare sull'apertura del file, con il codice giusto della Worlbook_Open.
Puoi ispezionare la Finestra Immediata e vedere se ci trovi le registrazioni del run delle macro; se non ci sono, aspetta 15 minuti e ricontrolla (la Macro15Min dovrebbe rischedulare la OneMinuteMacro)

Cial

A mezzo giorno girerà un'ora e poi ti dirò.
Altra cosa a cui ho pensato per ridurre il carico di lavoro per quanto riguarda l'upload ftp.. non si potrebbe fare in modo che le immagini immesse nello schema vengano escluse dal salvataggio? In questo modo l'upload interesserebbe solo il foglio, che è di pochi Kb.

[Anthony47]

Altra cosa a cui ho pensato per ridurre il carico di lavoro per quanto riguarda l'upload ftp.. non si potrebbe fare in modo che le immagini immesse nello schema vengano escluse dal salvataggio? In questo modo l'upload interesserebbe solo il foglio, che è di pochi Kb.

Ma in fatti io ti avevo detto: "salvi in un nuovo file le cose che ti interessano e poi salvi come pagina web questo nuovo file". Che poi sia "salva come pagina web" o "Publish" la cosa e' la stessa

Ciao

[systemcrack]

Altra cosa a cui ho pensato per ridurre il carico di lavoro per quanto riguarda l'upload ftp.. non si potrebbe fare in modo che le immagini immesse nello schema vengano escluse dal salvataggio? In questo modo l'upload interesserebbe solo il foglio, che è di pochi Kb.

Ma in fatti io ti avevo detto: "salvi in un nuovo file le cose che ti interessano e poi salvi come pagina web questo nuovo file". Che poi sia "salva come pagina web" o "Publish" la cosa e' la stessa

Ciao

Ah speravo che fosse possibile un comando direttamente in questo salvataggio.. ad ogni modo tra poco posterò i risultati del debug e vediamo.

P.s.
Buon pranzo!

[systemcrack]

Ok.. dopo la pausa ti riporto il log del debug


Comunque con l'aggiunta del tuo ultimo codice sembra non interrompersi più.
Potremmo quasi esserci.

[Anthony47]

Direi che va benone, nella maggior parte dei casi il salvataggio avviene regolarmente...
C'e' una spiegazione per quel blackout tra le 12:28 e le 13:00?
Ne' capisco quell'ingorgo alle 13:00 (tutte le 4 macro in esecuzione in pochi secondi); ti ricordi se avevi fermato l'esecuzione delle macro in qualche modo?

[systemcrack]

Direi che va benone, nella maggior parte dei casi il salvataggio avviene regolarmente...
C'e' una spiegazione per quel blackout tra le 12:28 e le 13:00?
Ne' capisco quell'ingorgo alle 13:00 (tutte le 4 macro in esecuzione in pochi secondi); ti ricordi se avevi fermato l'esecuzione delle macro in qualche modo?

Alle 13.00 l'ingorgo c'è perché il mio collega, che ricominciava a quell'ora ha chiuso lo schema in quanto doveva aprire l'altro. Chiamandosi nello stesso modo non possono convivere aperti insieme.

Per quanto riguarda il blackout alle 12:28.. non saprei dirti.. forse lo schermo del pc che è andato in standby