Estrarre Numeri Da Una stringa con condizione

[Francesco6918]

Buonasera a tutti gli amici del forum vi chiedo gentilmente é possibile modificare questa formula creata da D@nilo =SE.ERRORE(INDICE($H$4:$AA$4;AGGREGA(15;6;RIF.COLONNA($H$4:$AA$4)-7/(TROVA(TESTO($H$4:$AA$4;"00");$F$9)>0);RIF.COLONNA(A$1)));"") la funzione di questa formula è estrarre dalla stringa cella F9 tutti i numeri che corrispondano del intervallo H4:AA4, questa funziona benissimo , la mia modifica che vorrei applicare sarebbe quella di estrarre dalla stringa i numeri che partono uguale a 5 o maggiori di 5 corrispondente nel intervallo H4:AA4, se nella stringa ci sono uguale a 4 o meno di 4 numeri corrispondente nel intervallo H4:AA4 allora 0.

http://www.filedropper.com/prova01

Distinti Saluti

[Francesco6918]

Vi allego il file dove nella stringa ci sono 4 numeri rispetto al intervallo H4:AA4 dunque in questo caso la formula dovrebbe calcolare 0,se invece la stringa contiene numeri uguale 5 o maggiori di 5 corrispondente al intervallo H4:AA4 in questo caso la formula dovrebbe estrarre tali numeri.

http://www.filedropper.com/prova02

[Statix]

Ciao Francesco ,ho fatto delle piccole variazioni,
ho estratto dalla stringa i numeri
inserito H7 dove qui puoi modificare le presenze, in S9 i valori presenti nell'intervallo
vedi se va bene anche così,

http://www.filedropper.com/prova3

[Francesco6918]

Ciao Statix il procedimento è quello giusto però non vorrei estrarre la stringa vorrei possibilmente la formula con la stringa , si potrebbe creare una formula che somma la presenza di 5 numeri della stringa corrispondente al intervallo H4:AA4 e abbinare la formula di D@nilo ripropongono un mio esempio nella cella G9 o inserito come valore 9 che sarebbe la somma dei numeri presenti nella stringa corrispondente al intervallo H4:AA4 poi o inserito nella cella I9 la formula modificata di D@nilo =SE.ERRORE(SE($G$9>=5;INDICE($I$4:$AB$4;AGGREGA(15;6;RIF.COLONNA($I$4:$AB$4)-8/(TROVA(TESTO($I$4:$AB$4;"00");$F$9)>0);RIF.COLONNA(A$1))));"") vi allego il file.

Grazie

http://www.filedropper.com/prova03

[Statix]

Ciao, puoi usare questa formula per contare quanti numeri sono presenti in G9

Codice: Seleziona tutto

=CONTA.NUMERI(I9:AB9)

[D@nilo]

Ciao
con riferimento all'ultimo file postato puoi dire che risultati ti aspetti??

Per capire se i numeri presenti sono >= a 5 deve estrarre tutto altrimenti niente??

[Francesco6918]

Ciao dunque non è possibile creare una formula che somma i numeri presenti nella stringa confrontandoli con l intervallo H4:AA4, dovrei rinunciare.

[D@nilo]

Ciao
non ti seguo..sarebbe meglio un file di esempio....comunque se il tuo scopo è avere i campi vuoti se i numeri da estrarre sono < di 5 e eliminare la cella G9 puoi modificare la formula cosi

Codice: Seleziona tutto

=SE.ERRORE(SE(MATR.SOMMA.PRODOTTO(--VAL.NUMERO(--(TROVA(TESTO($I$4:$AB$4;"00");$F$9)>0)))>=5;INDICE($I$4:$AB$4;AGGREGA(15;6;RIF.COLONNA($I$4:$AB$4)-8/(TROVA(TESTO($I$4:$AB$4;"00");$F$9)>0);RIF.COLONNA(A$1)));"");"")

[Francesco6918]

Ciao D@nilo al momento funziona vorrei fare alcune prove ci risentiamo,comunque grazie.

Saluti

[Statix]

non mi ero accorto, ho visto che la formula è stata cambiata, per contare le presenze
In G9

Codice: Seleziona tutto

 =conta.numeri(I9:AB9)

[Statix]

un altra opzione che puoi fare,
e quello di filtrare le presenze modificando la formula,
sostituendo 5 con la cella G12, in questo modo puoi scrivere in G12 il valore che vuoi, esempio 5 , 7 ,8
così eviti di modificare ogni volta la formula

Codice: Seleziona tutto

=SE.ERRORE(SE(MATR.SOMMA.PRODOTTO(--VAL.NUMERO(--(TROVA(TESTO($I$4:$AB$4;"00");$F$9)>0)))>=$G$12;INDICE($I$4:$AB$4;AGGREGA(15;6;RIF.COLONNA($I$4:$AB$4)-8/(TROVA(TESTO($I$4:$AB$4;"00");$F$9)>0);RIF.COLONNA(A$1)));"");"")

[Francesco6918]

Ciao D@nilo funziona con l ultima formula =SE.ERRORE(SE(MATR.SOMMA.PRODOTTO(--VAL.NUMERO(--(TROVA(TESTO($I$4:$AB$4;"00");$F$9)>0)))>=5;INDICE($I$4:$AB$4;AGGREGA(15;6;RIF.COLONNA($I$4:$AB$4)-8/(TROVA(TESTO($I$4:$AB$4;"00");$F$9)>0);RIF.COLONNA(A$1)));"");"")
riguardo la formula di Statix e valida comunque come alternativa risolto vi ringrazio tutti

Saluti

http://www.filedropper.com/prova03_1