Riporta numeri diversi da range differenti

[contiend]

Buongiorno maestri jedi ,
ho provato a cercare sul forum ma devo aver inserito le chiavi di ricerca sbagliate.
Quindi vi richiedo, portate pazienza.

Semplicemente, ho questi valori da rispettare:

Minore di 11,99 (eccetto lo 0 o numeri inferiori allo 0) = riporta il dato 1
da 12,50 a 15,49 = riporta il dato 2
da 15,50 a 19,49 = 3

e via dicendo gli altri li inserisco io.

Vorrei poter inserire il tutto in una singola formula in una singola cella (senza dover fare tabelle pivot).

Vi ringrazio per l'attenzione

[contiend]

Se possibile utilizzerei sempre questo thread per un altra domanda.
Sarà la febbre ed il fatto che mi sono alzato alle 4 con questa grande voglia di fare tabelle ??

L'altro problema riguarda l'estrapolazione dei valori massimi da un gruppo di dati.

Ho una tabella strutturata più o meno in questo modo:

Pippo 19
Pippa 3
Strapippus 45
Franco 10
Francuzzo 13
Protozo 15
Pildo 10
Firoo 13
Purto 15


Dovrei, in un altra tabella (strutturata più o meno nello stesso modo),
avere i migliori 6
dal valore più alto al valore più basso.

Possibile senza macro o meglio farla?
In caso che formula usare?

Ancora grazie, anche per questo secondo quesito

[Flash30005]

prova

Codice: Seleziona tutto

=SE(E(A1<=11,99;A1>0);1;SE(E(A1>=12,5;A1<=15,49);2;SE(E(A1>=15,5;A1<=19,49);3;"Altro")))

ciao

[contiend]

prova

Codice: Seleziona tutto

=SE(E(A1<=11,99;A1>0);1;SE(E(A1>=12,5;A1<=15,49);2;SE(E(A1>=15,5;A1<=19,49);3;"Altro")))

ciao

Fantastico! Gentilissimo!

[Flash30005]

Per quanto riguarda la classifica
puoi semplicemente registrare una macro che copia la Tabella1 (non ordinata)
incolla in un altro foglio (o stesso foglio ma in altro range distante dalla prima tabella)
e fai l'ordinamento secondo i punteggi
poi elimini dalla 7° riga in poi (lasci i 6 migliori)
fermi la macro

A inizio macro metterai il codice per cancellare le due colonne della classifica ad esempio (colonne K e L):

Codice: Seleziona tutto

Range("K:L").Clear

ciao

[ninai]

Ciao
in alternativa alla formula proposta da Flash (soprattutto se gli scaglioni sono numerosi), io userei:

Codice: Seleziona tutto

=(A1>0)*CONFRONTA(A1;{0.12.15,5.19,5})

aggiungendo, separati dal punto, il valore di partenza di altri eventuali scaglioni.
Invece della costante di matrice ({0.12.15,5.19,5}) , si può usare anche un intervallo di celle (es. B1:B4), dove si riportano tali valori

edit
oppure:

Codice: Seleziona tutto

=(A1>0)+(A1>=12)+(A1>=15,5)+(A1>=19,5) ecc. ecc.

[Anthony47]

Molto bella la formula con costanti di matrice di ninai... Chi volesse usarla su versioni "ante Excel 2010" (per la verita' ho un dubbio su Excel 2007) tenga presente che il separatore di valori da usare e' "\" (invece del "punto").

Quanto alla domanda sull' ordinamento dei risultati, se si vuole fare via formule:
In E1 calcola il punteggio piu' alto con la formula

Codice: Seleziona tutto

=GRANDE($B$1:$B$100+RIF.RIGA($B$1:$B$100)/100000;RIF.RIGA(A1))

Formatta la cella con max 2 decimali.
In D1 calcola il giocatore con la formula

Codice: Seleziona tutto

=INDICE($A$1:$A$100;CONFRONTA(E1;($B$1:$B$100)+RIF.RIGA($B$1:$B$100)/100000;0))

Ambedue le formule vanno confermate usando Contr-Maiusc-Enter, non il solo Enter.

Poi copia D1:E1 sulle 5 righe successive, per avere il primi 6 risultati.

Ho immaginato che Nominativi e Punteggi si trovino in A1:B100.

Ciao

[contiend]

Non riesco a capire perché la tua funzione Anthony47 va alla perfezione se mantengo le tue celle selezionate (o le sposto di poco), ma se le cambio a mio piacimento, non va più!!!

Tipo così,
su D5 del mio foglio e la tabella con tutti i numeri è da B120 a B131, mentre i nomi sono in AQ120 : AQ131

Codice: Seleziona tutto

=GRANDE($BF$120:$BF$143+RIF.RIGA($BF$120:$BF$131)/100000;RIF.RIGA(AQ120))

[ricky53]

Ciao,
nella formula hai scritto un "143" invece che del solito "131".


Arrivo a soluzione trovata e, quindi, ti chiedo:
ordinando, dopo aver selezionato le colonne "A:B", in modo decrescente per il punteggio non avresti avuto quello che ti occorreva ?

[contiend]

In effetti ho trascritto male.
La formula era

Codice: Seleziona tutto

=GRANDE($BH$120:$BH$143+RIF.RIGA($BH$120:$BH$143)/100000;RIF.RIGA(AS120))

.

Ad ogni modo inserisco qui anche il file excel di prova per capire più a fondo dove sbaglio!

https://www.dropbox.com/s/z6c4d04dj96iw ... .xlsm?dl=0

Non posso semplicemente fare l'ordinamento, perché la colonna di riferimento (dalla quale prendo i dati) deve rimanere così perché poi va in stampa così com'è.

Invece, l'estrapolazione dei dati mi serve per ottenere altri dati che poi andranno in altri riquadri (non presenti nel file prova).

Grazie dell'aiuto intanto.

[ricky53]

Caio,
prova con questo modifica

Codice: Seleziona tutto

=GRANDE($BH$120:$BH$143+RIF.RIGA($BH$120:$BH$143)/100000;RIF.RIGA(BH120)-119)

alla formula che utilizzi ... dovrebbe andare bene.

Sempre matriciale.

[Anthony47]

Come ha puntualizzato Ricky, l' errore e' in questa parte: RIF.RIGA(AS120)
Poiche' quello e' il termine che indica "il 1° piu' grande" devi lasciare RIF.RIGA(A1)

Ciao

[contiend]

Ringrazio Anthony47 per avermi dato la formula che cercavo e Ricky per avermi dato un'altra grande soluzione .

Ho risolto!

Siete fantastici.

Se vi conoscessi, vi offrirei da bere

[ricky53]

Ciao,
faremo di tutto per conoscerci perché ... una bevuta non si rifiuta mai.

[contiend]

Scusate se riprendo questa discussione,
ma mi è spuntato un piccolo problemino che se fosse possibile risolvere con la formula, sarebbe molto utile.

Allora, riepilogando, la formula da voi datomi è questa:

Codice: Seleziona tutto

=GRANDE(BASE!$BG$120:$BG$143+RIF.RIGA(BASE!$BG$120:$BG$143)/100000;RIF.RIGA(BASE!AR120)-119)

In pratica, pesca da una tabella sita in un foglio chiamato "BASE"
controlla i numeri più alti, riferiti ai nomi che ci sono a fianco,
e me li riporta nella tabella di destinazione in ordine di grandezza.

Quindi, se in tabella BASE ho
Pippo 100
Luca 300
Sandro 200

Nella tabella di destinazione avrò
Luca 300
Sandro 200
Pippo 100

Fantastico.

Ora il problema mi sorge se ci sono nomi con numeri identici.
Esempio:
Pippo 50
Luca 50
Sandro 50

La formula, nella tabella di destinazione mi riporta i dati al contrario rispetto a come li ho inseriti originariamente:
Sandro 50
Luca 50
Pippo 50

E' possibile annullare questa inversione automatica per quei nomi che hanno numeri identici?

Grazie dell'attenzione e del supporto!

[Anthony47]

Allora

Codice: Seleziona tutto

=GRANDE(BASE!$BG$120:$BG$143-RIF.RIGA(BASE!$BG$120:$BG$143)/100000;RIF.RIGA(A1))


Ciao

[contiend]

Fantastico. Grazie