Se tra più valori

[zanzarino2009]

Gentilmente potreste spiegarmi che formula dovrei usare per rapportare 3 valori? Mi spiego vorrei una formula che mi dia come risultato A o B o C. quindi suppongo sia una funzione Se. A me serve che se la cella A1 è maggiore di A2 e A3 il risultato sia A; se la cella A2 è maggiore di A1 e A3 dia B. Se A3 è maggiore di A1 e A2 dia risultato C. Se invece le 2 o tre celle hanno valori uguali mi dia come risulta AB AC BC. Spero di essere stato chiaro e grazie.

[ricky53]

Ciao,
le prime tre condizioni più o meno mi tornano.
NON mi torna l'ultima !

Riporto la condizione

Se invece le 2 o tre celle hanno valori uguali mi dia come risulta AB AC BC

I confronti sono stati fatti sempre con tre celle e qui come vanno fatti perchè hai scritto "... le 2 o tre celle"?
Con "valori uguali" intendi direi che le tre celle abbiamo tutte lo stesso valore?
il risultato di questa condizione deve essere uguale al testo "AB AC BC" oppure ... e qui occorre il tuo intervento !!!


Puoi specificare meglio questa/queste condizione/i?

[zanzarino2009]

Premetto che non so tramutare in formula quello che ho precedentemente spiegato. Anche perchè il tutto mi servirebbe come soluzione in un'unica cella Risultato. Per quanto riguarda l'ultima condizione quello che vorrei dire è che se in A1 e A2 c'è il valore 1 e in A3 un valore diverso da 1 come risultato devo ottenere AB e cosi via facendo anche con le altre. Ovviamente se il valore è uguale in tutte e 3 le celle il risultato che devo ottenere è ABC. Spero di essermi spiegato abbastanza bene.

[ricky53]

Ciao,
premesso che con tre celle le condizioni possono essere le più disparate possibili e solo tu sai quali ti occorrono.

Detto ciò vorrei riepilogare per vedere se quello che ho capito è quello che ti occorre:


Chiamiamo "C1" la prima cella, "C2" la seconda e "C3" la terza

Riepilogo delle condizioni e dei risultati attesi:

1 . C1=C2=C3 risultato atteso "ABC"

2 . C1=C2 e C3 qualunque valore ma diverso da C1 e C2 risultato atteso "AB"

3 . C1=C3 e C2 qualunque valore ma diverso da C1 e C3 risultato atteso "AC"

4 . C2=C3 e C1 qualunque valore ma diverso da C2 e C3 risultato atteso "BC"

5. C1, C2 e C3 contengono tre valori diversi fra loro
5.1 C1>C2 e C1>C3 risultato atteso "A"
5.2 C2>C1 e C2>C3 risultato atteso "B"
5.3 C3>C1 e C3>C2 risultato atteso "C"


Attendo una tua conferma prima di proporti una soluzione.

[zanzarino2009]

Esatto!!!

[Flash30005]

Penso si possa fare meglio ma funziona

Codice: Seleziona tutto

=SE(E(A1=A2;A2=A3);"ABC";SE(A1=A2;"AB";SE(A1=A3;"AC";SE(A2=A3;"BC";SE(A1=MAX(A1:A3);"A";SE(A2=MAX(A1:A3);"B";SE(A3=MAX(A1:A3);"C")))))))

ciao

[ricky53]

Ciao,
leggi il messaggio di Flash ....

e poi ragioniamo perchè per me ci sono delle sovrapposizioni e le condizioni vanno implementate.
Esempio:
C1=2
C2=2
C3=4

Essendo C3>C1 e C3>C2 valore atteso "C" (vedi 5.3 del mio intervento precedente)

ma riflettendo meglio
C1=C2 e C3 diverso dai precedenti valore atteso "AB"

Quindi va cambiata la condizione
5.3 C3>C1 e C3>C2 risultato atteso "C"
in
5.3 C3>C1 e C3>C2 e C1<>C2 risultato atteso "C"

la modifica va fatta anche alle altre condizioni 5.1 e 5.2.

Ne convieni ???

[zanzarino2009]

In questo caso io vorrei avere C come risposta perchè è il valore maggiore.

[Flash30005]

Zanzarino l'hai provata la formula che ti ho inviato?
qui si sta confondendo un po' tra cella A1,A2,A3 come avevi detto e ora C1, C2, C3 mah...
Io mi sono rifatto al tuo primo post quindi le celle interessate sono A1, A2, A3 come vedasi in formula

[zanzarino2009]

L'ho provata. C'è un problema se A1 è maggiore di A2 e A3 che però hanno valore uguale non mi da come risultato A bensì BC. e io voglio avere come primo risultato quello maggiore e successivamente in caso di stesso valore il resto.

[Flash30005]

Si è vero manca un controllo
ma pensosi possa fare molto meglio

Codice: Seleziona tutto

=SE(E(A1=A2;A2=A3);"ABC";SE(E(A1=A2;A3<MAX(A1:A3));"AB";SE(E(A1=A3;A2<MAX(A1:A3));"AC";SE(E(A2=A3;A1<MAX(A1:A3));"BC";SE(A1=MAX(A1:A3);"A";SE(A2=MAX(A1:A3);"B";SE(A3=MAX(A1:A3);"C")))))))

ciao

[zanzarino2009]

Ottimo GRAZIE MILLE!!!!

[ricky53]

Ciao Zanzarino,
visto che la soluzione che ti ha soddisfatto l'hai ottenuta, vorrei proporti anche una mia formula:

Codice: Seleziona tutto

=SE(E(A1>A2; A1>A3); "A"; SE(E(A2>A1; A2>A3); "B"; SE(E(A3>A1; A3>A2); "C"; SE(E(A1=A2;A2=A3);"ABC"; SE(A1=A2; "AB"; SE(A1=A3; "AC"; "BC"))))))

Buon proseguimento ed alla prossima.

[zanzarino2009]

Salve a tutti. Ho un nuovo problema con excel che non sto riuscendo a trasformare in formula forse (anzi sicuramente ) per una mia incapacità. Ho bisogno di una formula simile a quella di questo post. In pratica ho bisogno di una formula che mi dia questo risultato:

- Se (A1=1) E A2 è MAGGIORE DI B2 allora restituisca A2 altrimenti B2+1
- Se (A1=2) E B2 è MAGGIORE DI A2 allora restituisca B2 altrimenti A2+1
- Se (A1=3) allora restituisca C2.

Spero di essere stato chiaro e confido nella vostra collaborazione come sembre. Grazie.

[Anthony47]

Bentornato tra noi...

La formula concettualmente piu' lineare:

Codice: Seleziona tutto

=SE(A1=1;SE(A2>B2;A2;B2+1);SE(A1=2;SE(B2>A2;B2;A2+1);SE(A1=3;C2;0)))

Quella piu' semplice, e anche facilmente adattabile a "casi" ulteriori:

Codice: Seleziona tutto

=SE(A2>B2;A2;B2+1)*(A1=1)+SE(B2>A2;B2;A2+1)*(A1=2)+C2*(A1=3)


Ciao

[zanzarino2009]

Bentornato tra noi...

La formula concettualmente piu' lineare:

Codice: Seleziona tutto

=SE(A1=1;SE(A2>B2;A2;B2+1);SE(A1=2;SE(B2>A2;B2;A2+1);SE(A1=3;C2;0)))

Quella piu' semplice, e anche facilmente adattabile a "casi" ulteriori:

Codice: Seleziona tutto

=SE(A2>B2;A2;B2+1)*(A1=1)+SE(B2>A2;B2;A2+1)*(A1=2)+C2*(A1=3)


Ciao

Grazie mille. Perfetto come sempre