Formattazione condizionale con set di icone

[fastbike73]

Buongiorno, desideravo sapere se è possibile ricopiare la formattazione condizionale con set di icone in altre celle, aggiornando contemporaneamente i riferimenti delle celle. Per spiegarmi meglio posto una immagine del mio foglio...

Premesso che nell'immagine è inquadrata solo una sezione del foglio, la regola della formattazione condizionale è la seguente:
corrente=>precedente freccina in alto;
corrente<precedente freccina in basso
Dovrei ricopiare questa formattazione condizionale per molte, molte righe.... per 13 colonne. E' possibile evitare di doverla inserire cella per cella?? Ho provato con copia formattazione ma mantiene i riferimenti alle celle assoluti...
Spero in un vostro aiuto.
Grazie.

[ricky53]

Ciao,
puoi riportare la regola della formattazione condizionale così come risultata nelle celle.

[fastbike73]

Ciao,
puoi riportare la regola della formattazione condizionale così come risultata nelle celle.

Ciao Ricky, ti allego l'immagine....


nell'immagine la formula fa riferimento alla cella D62, quindi la formattazione (freccine) viene inserita nella cella D61...
Grazie per l'interesse e l'eventuale aiuto!!

[ricky53]

Ciao,
la formattazione condizionale con le "Icone" impone l'obbligo all'utilizzo degli indirizzi assoluti.

Non conosco soluzione a questa problematica mediante le funzionalità native di excel ... penso che con il VBA si possa fare; non l'ho mai provato ... potrei provarci.

Dovresti dire l'intervallo su cui va applicata la formattazione condizionale.

[ricky53]

Ciao,
una prova al volo utilizzando il registratore di macro e qualche adattamento al codice ottenuto.

L'esempio vale per le colonne dalla "A" alla "E"
E' applicabile SOLO fino alla colonna "Z"
NON ci sono limiti per le righe

Codice: Seleziona tutto

Sub Imposta_Formattazione_Condizionale()
    Dim I As Long, J As Integer
   
    Cells.FormatConditions.Delete
    For I = 1 To 10 ' Righe da 1 a 10
        For J = 1 To 5 ' Colonne da "A"  fino all "E"
            Cells(I, J).Select
            Selection.FormatConditions.AddIconSetCondition
            Selection.FormatConditions(Selection.FormatConditions.Count).SetFirstPriority
            With Selection.FormatConditions(1)
                .ReverseOrder = False
                .ShowIconOnly = False
                .IconSet = ActiveWorkbook.IconSets(xl3Triangles)
            End With
            Selection.FormatConditions(1).IconCriteria(1).Icon = xlIconRedDownTriangle
            With Selection.FormatConditions(1).IconCriteria(2)
                .Type = xlConditionValueFormula
                .Value = "=Foglio1!$" & Chr(J + 64) & "$" & I + 1
                .Operator = 7
                .Icon = xlIconYellowDash
            End With
            With Selection.FormatConditions(1).IconCriteria(3)
                .Type = xlConditionValueFormula
                .Value = "=Foglio1!$" & Chr(J + 64) & "$" & I + 1
                .Operator = 5
                .Icon = xlIconGreenUpTriangle
            End With
        Next J
    Next I
End Sub


[fastbike73]

Beh, che dire.... SEI UN MITO!!!!
Solo una piccola spiegazione.... il mio foglio si chiama Kpi, quindi devo sostituire ...."=Foglio1!$".... con ....."=Kpi!$"...
corretto??
Per quanto riguarda la riga iniziale e le colonne ho già personalizzato.

[ricky53]

Ciao,
si la sostituzione che hai fatto è giusta.
"Foglio1" era un esempio ... andava messo il nome del foglio che utilizzi tu.


Ecco una versione più veloce e senza limiti sulle colonne se non quelle ... del foglio excel.

Codice: Seleziona tutto

Sub Imposta_Formattazione_Condizionale()
    Dim I As Long, J As Integer, Colonna As String
   
    Cells.FormatConditions.Delete
    For I = 1 To 10 ' Righe da 1 a 10
        For J = 1 To 5 ' Colonne da "A"  fino all "E"
           
            Colonna = Split(Cells(1, J).Address, "$")(1)
            Cells(I, J).FormatConditions.AddIconSetCondition
            Cells(I, J).FormatConditions(Selection.FormatConditions.Count).SetFirstPriority
            With Cells(I, J).FormatConditions(1)
                .ReverseOrder = False
                .ShowIconOnly = False
                .IconSet = ActiveWorkbook.IconSets(xl3Triangles)
            End With
            Cells(I, J).FormatConditions(1).IconCriteria(1).Icon = xlIconRedDownTriangle
            With Cells(I, J).FormatConditions(1).IconCriteria(2)
                .Type = xlConditionValueFormula
                .Value = "=Foglio1!$" & Colonna & "$" & I + 1
                .Operator = 7
                .Icon = xlIconYellowDash
            End With
            With Cells(I, J).FormatConditions(1).IconCriteria(3)
                .Type = xlConditionValueFormula
                .Value = "=Foglio1!$" & Colonna & "$" & I + 1
                .Operator = 5
                .Icon = xlIconGreenUpTriangle
            End With
        Next J
    Next I
End Sub


[fastbike73]

Ricky sei un grande!! Possiamo effettuare una modifica?
La formattazione la dovrei inserire partendo dalla riga 7 e alternado una riga si e l'altra no. Quindi la riga 7,
poi la 9, poi la 11, poi la 13 e così via. Fino alla riga 61 che è l'ultima che deve contenere la formattazione condizionale.
Questo perchè la formattazione la metto sulla riga che contiene il valore corrente.
Spero di essermi spiegato.

[ricky53]

Ciao,
nell'ultimo codice che ti ho scritto cambia

Codice: Seleziona tutto

 For I = 1 To 10 ' Righe da 1 a 10

con

Codice: Seleziona tutto

 For I = 1 To 10 Step 2 ' Righe da 1 a 10

[fastbike73]

Ciao Ricky, mi sono dovuto allontanare un attimo dalla postazione. Dunque con la versione "veloce" e senza limiti appena la macro arriva alla stringa:

Codice: Seleziona tutto

            Cells(I, J).FormatConditions(Selection.FormatConditions.Count).SetFirstPriority

rilascia il seguente errore:
Errore di Runtime '9'; indice non incluso nell'intervallo.
Se utilizzo il "vecchio" codice con le opportune modifiche funziona tutto.

Nel "nuovo" codice, prima di eseguirlo, ho apportato questa correzione:
da

Codice: Seleziona tutto

Colonna = Split(Cells(1, J).Address, "$")(1)

a

Codice: Seleziona tutto

Colonna = Split(Cells(I, J).Address, "$")(1)

[ricky53]

Ciao,
L' "1" serve a trovare la colonna su cui agire ma fa riferimento alla riga "1".
La "I" NON crea problemi.
Va bene anche l'i-esima riga.

Invece in

Codice: Seleziona tutto

Cells(I, J).FormatConditions(Selection.FormatConditions.Count).SetFirstPriority

devi sostituire "Selection" in questo modo

Codice: Seleziona tutto

Cells(I, J).FormatConditions(Cells(I, J).FormatConditions.Count).SetFirstPriority

... mi era sfuggita la sostituzione nel modificare il codice

[fastbike73]

Ricky funziona tutto,perfetto!! Grazie!!!