[Excel 2013] Macro aggiorna fogli nascosti

[fastbike73]

Buongiorno a tutto il forum, nel file excel Riclassificati.xlsm ho, nel foglio "Editor", un pulsante che esegue l'importazione e l'elaborazione di dati in fogli, dello stesso file, che per motivi di sicurezza devo tenere nascosti. Il problema è che se mando in esecuzione la macro, tramite il pulsante, mentre i fogli sono nascosti mi esce il seguente errore:
'errore 1004 Metodo select dell'oggetto Worksheet non riuscito'. I dati comunque vengono poi scritti ed elaborati. Mi sono accorto che con i fogli visibili l'errore non si presenta.
Dovendo consentire l'utilizzo del file ad altre persone, ma essendo obbligato a non mostrare i fogli nascosti vorrei trovare una soluzione per non far apparire quest'errore.
Spero nel vostro aiuto.

P.s.: Ricky ti ricorda niente??

[ricky53]

Ciao,
certo che mi ricorda qualcosa, anzi, tanto!

Devi sproteggere i foglio, elaborare, riproteggere. Ovviamente l'utente non vedrà nulla durante l'elaborazione.

C'è anche la possibilità di proteggere con

Codice: Seleziona tutto

Sheets("Foglio1").Protect Password:="LaTuaPassword", UserInterFaceOnly:=True

... vedi la guida sulle modalità di utilizzo ... da inserire in "Private Sub Workbook_Open()"

Ne avevamo già parlato forse ma qui dico: non ricordo!

[fastbike73]

Ciao Ricky, scusami se non ti ho risposto subito ma ho avuto problemi di salute...
Forse non sono stato chiaro nella spiegazione. Quando faccio partire la macro di aggiornamento dei dati, se il foglio "Db" è nascosto, mi viene proposto l'errore "Errore 1004 . Metodo select dell'oggetto 'worksheet' non riuscito" . Se il foglio lo scopro, l'errore non si presenta. Credo che faccia riferimento ai comandi Select che sono inseriti nelle macro di aggiornamento.

[Anthony47]

Nella stragrande maggioranza dei casi si puo' fare a meno di selezionare un foglio o un range; in questo caso le istruzioni devono sempre fare riferimento esplicito al foglio + intervallo.
Avendo il listing della macro si potrebbe suggerire una variante che lavora come detto.

Ciao

[fastbike73]

.....Avendo il listing della macro si potrebbe suggerire una variante che lavora come detto....

Buongiorno Anthony, sarei particolarmente grato a te e a tutto il forum se poteste aiutarmi. Le macro che aggiornano il foglio in questione sono sei... intanto ti posto la prima che è quella con cui importo i dati da un altra cartella di excel. Se tu ritieni che per aiutarmi ti sia necessario avere i file fammelo sapere che provvedo a inviare il link.

Codice: Seleziona tutto

Sub Import()
'
' Import Macro
'
' Scelta rapida da tastiera: CTRL+i
'
    Dim Percorso As String, Nome As String, Ur As Long
    Dim SH_In As Worksheet, SH_Out As Worksheet, WB_Out As Workbook, Rng_In As Range
   
    Set SH_In = Sheets("Editor")
    Set SH_Out = Sheets("Db")
    Set WB_Out = ActiveWorkbook
   
    Application.ScreenUpdating = False
    SH_Out.Cells.ClearContents
    Percorso = ActiveWorkbook.Path
    Nome = Worksheets("Editor").Range("E15")
    On Error GoTo Errore
    Workbooks.Open Filename:=Percorso & "\" & Nome
    Ur = Range("A" & Rows.Count).End(xlUp).Row
    Set Rng_In = Range("A1:I" & Ur)
    WB_Out.Activate
    Rng_In.Copy Destination:=SH_Out.Range("A1")
    SH_Out.Cells.EntireColumn.AutoFit
    SH_Out.Select
    SH_Out.Range("A1").Select
    SH_In.Select
   
    Application.DisplayAlerts = False
    Windows(Nome).Close SaveChanges:=False
    Application.DisplayAlerts = True
   
    MsgBox "Import di   '" & Ur - 1 & "'   dati correttamente effettuato", vbInformation
   
Fine:
    Application.ScreenUpdating = True
    Set SH_In = Nothing
    Set SH_Out = Nothing
    Set WB_Out = Nothing
    Set Rng_In = Nothing
    Exit Sub

'...............................................................
Errore:
    MsgBox "errore:  '" & Err & "'" & vbCrLf & Err.Description
    GoTo Fine:
End Sub