[excel] Somma di celle con prefisso alfabetico

[estaporpera]

Ciao ragazzi.
Mi trovo una serie di caselle che contengono lettere e numeri, io dovrei sommare solo i numeri.
Per esempio, ho 4 caselle che contengono: p1 p4 p1 p1, cerco una formula che mi restituisca come risultato 7.
Grazie

[Flash30005]

Ciao Estaporpera e benvenuto nel Forum

ammesso che tu abbia il dato P1 nella cella A2 e gli altri a seguire (A3, A4 etc)
inserisci questa formula in un'altra colonna sempre nella stessa riga del dato (es. B2)

Codice: Seleziona tutto

=VALORE(STRINGA.ESTRAI(A2;2;LUNGHEZZA(A2)-1))

trascina verso il basso fino a dove occorre
alla fine farai la somma di questa nuova colonna

Fai sapere
Ciao

[estaporpera]

ho inserito la formula che mi hai suggerito ma mi da errore, mi spiego meglio:

io mi trovo nella riga 4 ( b4:af4) una serie di numeri soli e numeri con la p ( 1 2 3 4 5 6 7 8 9 p1 11 12 13 14 15 p3 17 18 p5 20 21 22 23 ), e voglio che il programma mi restituisca in AI4 la somma dei numeri dove c'è la p, quindi nell'esempio scritto da me deve darmi, 9.
Grazie per l'aiuto.

[Flash30005]

Inserisci in B5 questa formula:

Codice: Seleziona tutto

=SE(VAL.ERRORE(TROVA("p";B4;1))=VERO;0;VALORE(STRINGA.ESTRAI(B4;2;LUNGHEZZA(B4)-1)))

la trascini fino alla colonna AF
in AL4 fai la somma della riga da B5 a AF5 con questa formula:

Codice: Seleziona tutto

=SOMMA(B5:AF5)

Ciao

[estaporpera]

ho fatto quello che mi hai suggerito, ma non va. mi da zero in tutta la riga 5 ,dove ho trascinato la formula, ovviamente ho provato a inserire nella riga 4 p1 p5 p3 a caso .
Grazie sempre

[CANAPONE]

Ciao, potresti provare con

Codice: Seleziona tutto

=MATR.SOMMA.PRODOTTO(--SOSTITUISCI(A4:BF4;"p";""))-SOMMA(A4:BF4)

A4:AF4 deve essere tutto compilato o con numeri o con Pnumeri (per intendersi).

Non fosse il caso, puoi inserire un controllo e provare con

Codice: Seleziona tutto

=SOMMA(SE(A4:BF4<>"";--SOSTITUISCI(A4:BF4;"p";"")))-SOMMA(A4:BF4)

La seconda formula è matriciale e per funzionare correttamnte deve essere inserita/confermata con control+maiusc+invio: se inserita bene comparirà abbracciata da due graffe.

Spero sia d'aiuto

Un caro saluto a tutti

[Flash30005]

Leggi quanto scritto da Canapone
perché la formula consigliata e adattata alla tua esigenza funziona
In AI4 quindi potrai mettere questo:

Codice: Seleziona tutto

=MATR.SOMMA.PRODOTTO(--SOSTITUISCI(B4:AF4;"p";""))-SOMMA(B4:AF4)

Comunque ti invio questo file
che è quello da me usato per il test (precedente)

ciao

[estaporpera]

Ragazzi grazie mille siete geniali.
C'è un però, spero di non farmi odiare.
Intanto ho usato l'ultima formula scritta da flash30005 suggerita da Canapone ma con le caselle diverse da quelle che servivano a me, tutto funzionava alla perfezione. Però ho dimenticato di dirvi che nella stessa riga dove vado ad inserire pnumero inserisco anche m ed f, ed a questo punto mi spunta #valore!. a me non serve sommare anche m o f però la formula dovrebbe ignorarli.
esempio: 1 2 3 4 5 p1 7 8 9 m 11 12 13 f 14 15 16 17 p3 18 19 f 21 22 23 f
in questo caso io voglio che nella casella AI4 mi spunti 4
Spero di essere stato chiaro.
Grazie per la disponibilità e la pazienza

[CANAPONE]

Ciao, ho uso sempre come intervallo di riferimento B4:AF4

Codice: Seleziona tutto

=MATR.SOMMA.PRODOTTO(--SOSTITUISCI(SOSTITUISCI(SOSTITUISCI(B4:AF4;"p";0);"f";0);"m";0))-SOMMA(B4:AF4)

Rispetto alla precedente formula, a parte la matrioska di SOSTITUISCI, la formula sostituisce le lettere e scrive 0 (zero): in questo modo accetta anche le singole p.

Spero sia d'aiuto

Saluti a tutti

[estaporpera]

grazie sei stato grandioso, complimenti per la conoscenza di excel.
gran bel forum