Salvare file in formato Word

[lone wolf]

Buon giorno, ho creato un semplice file per inserire alcuni dati, dati che vorrei salvare con macro in formato Word in una cartella specifica denominata “Articoli”, è possibile? Grazie per l’eventuale aiuto e un buon fine anno a tutto il forum.
Link del file:
https://www.dropbox.com/scl/fi/kc5y7igb ... 92myx&dl=0

[Raffaele53]

In Excel premi Sviluppo e dopo Visual Basic
In Strumenti/Riferimenti aggiungi "Microsoft Word xx.0 Object Library" (xx=16.0 per Office365)
Aggiungi un Modulo(X) ed inserisci il codice sulla destra.

Ti chiedera dove salvare, salva come Doc_ggmmaaaa + orario, se oltre le 20 righe, crea più pagine.

Codice: Seleziona tutto

Option Explicit
Sub CreadWord()
   Dim oFD As FileDialog
   Dim oAppWord As Word.Application
   Dim newDoc As Word.Document
   Dim sPercorso As String
   Dim nNome As String
   Dim rngTab As Range
   
nNome = "Doc_" & Replace(Replace(Now, "/", ""), ":", "")
Set rngTab = Worksheets("Foglio2").Range("B1:B20")
sPercorso = ThisWorkbook.Path
         If Right(sPercorso, 1) <> Application.PathSeparator Then
            sPercorso = sPercorso & Application.PathSeparator
         End If
   
   Set oFD = Application.FileDialog(msoFileDialogFolderPicker)
   With oFD
      .Title = "Seleziona il percorso di salvataggio del documento"
      .InitialFileName = sPercorso
      .AllowMultiSelect = False
      If .Show = -1 Then
         sPercorso = .SelectedItems(1)
         If Right(sPercorso, 1) <> Application.PathSeparator Then
            sPercorso = sPercorso & Application.PathSeparator
         End If
      End If
   End With
   
   Set oAppWord = New Word.Application
   With oAppWord
      .Visible = True
      Set newDoc = .Documents.Add
      With newDoc
         .SaveAs2 Filename:=sPercorso & nNome, FileFormat:=wdFormatDocumentDefault
         rngTab.Copy
         .Range.Paste 'ExcelTable False, False, False
         '.Tables(1).AutoFitBehavior (wdAutoFitWindow)
         .Save
      End With
      '.Activate
      .Quit
   End With
Set oAppWord = Nothing
Set newDoc = Nothing
Set rngTab = Nothing
MsgBox "Fatto"
End Sub

[Anthony47]

@LupoSolitario:
In aggiunta all'ottima macro di Raffaele, vedi sopra, ti suggerisco di verificare se la stampa in formato Pdf non risolva gia' il vero problema che stai cercando di risolvere.
Per questa prova si puo' usare la "stampante" Microsoft Print to Pdf" che dovrebbe essere integrata nel tuo windows; si chiama "stampante" ma in realtà crea un file pdf a cui puoi assegnare il nome che vuoi.
Se questo ti basta, allora prova a registrare una macro mentre esegui tutto il processo di stampa, e pubblicane il codice: ti aiuteremo a renderlo piu' flessibile e (speriamo) piu' facile da usare.

Per le istruzioni e i primi suggerimenti su come registrare una macro:
http://www.pc-facile.com/forum/viewtopi ... 93#p622593

Buon anno a tutti

[lone wolf]

Innanzitutto buon anno nuovo e grazie Raffaele53, per l’aiuto, In Strumenti/Riferimenti del mio excel (2010) non trovo "Microsoft Word xx.0 Object Library" (xx=16.0 per Office365), ma trovo invece “Microsoft Word 14.0 Object Library” non so se è la stessa cosa e se posso aggiungerla, quindi non ho potuto provare il tuo codice. Ringrazio anche Anthony47 per il suggerimento ma conosco la "stampante" Microsoft Print to Pdf", e in alcuni file utilizzo già un codice per salvare il file in pdf, purtroppo stavolta serve salvare il file in word, in attesa di conferme auguro un felice anno nuovo a tutto il forum

[Raffaele53]

Usa “Microsoft Word 14.0 Object Library”