Problema macro Excel

[falco646]

Salve a tutti, sono un nuovo utente, avrei bisogno di una mano, so che siete bravi ho letto un pò le discussioni simili ma non sono riuscito a far funzionare nulla =(
In pratica ho una tabella in excel 2010 colonne da A a I e vorrei fare una macro che copia in un altro foglio di lavoro la stessa tabella compilata solo con le righe che contengono un numero >=1 presente nella seconda colonna (ad esempio se in B5 c'è un valore copia la riga, se in B6 non c'è non la copia ecc..) Ci ho provato ma ho fatto solo dei gran casini,

Vi ringrazio!

[ricky53]

Ciao,
fare l'operazione con una macro è vincolante?

Potresti farla con il filtro automatico, filtrando per le condizioni che ti occorrono, poi copi i dati filtrati nell'altro foglio

[falco646]

Ciao,
fare l'operazione con una macro è vincolante?

Potresti farla con il filtro automatico, filtrando per le condizioni che ti occorrono, poi copi i dati filtrati nell'alto foglio

Sarebbe preferibile una macro, posso anche impostare che alcune righe vadano copiate ugualmente se mi serve? perchè ho notato ora che ci sono delle righe che servono da delimitazioni e il filtro me le toglierebbe...

[ricky53]

Ciao,
vada per la macro.

Riepilogo le condizioni:

1. i dati sono nel "Foglio1"
2. se nella colonna "B", nella i-esima cella, c'è un numero >= ad 1 allora copiare la riga per l'intervallo "A:I"
3. la copia va fatta nel "Foglio2"
4. si ipotizza che i dati iniziano dalla riga "2" percè la riga "1" e riservata alle intestazioni

Confermi?

[falco646]

Ciao,
vada per la macro.

Riepilogo le condizioni:

1. i dati sono nel "Foglio1"
2. se nella colonna "B", nella i-esima cella, c'è un numero >= ad 1 allora copiare la riga per l'intervallo "A:I"
3. la copia va fatta nel "Foglio2"
4. si ipotizza che i dati iniziano dalla riga "2" percè la riga "1" e riservata alle intestazioni

Confermi?

Yes, in realtà dalla riga 5, copia anche le intestazioni della tabella con la macro?

[ricky53]

Ciao,
vada per la riga "5".

Si si può copiare tutto basta sapere cosa copiare.

Le intestazioni in quale riga sono ?

[ricky53]

Ciao,
ecco un esempio che puoi modificare per adattarlo alla tua situazione reale

Codice: Seleziona tutto

Sub Copia_Selettiva()
    Dim UR As Long, I As Long, J As Long
    Dim WS1 As Worksheet, WS2 As Worksheet
   
    Set WS1 = Sheets("Foglio1")
    Set WS2 = Sheets("Foglio2")
   
    Application.ScreenUpdating = False
    WS2.Cells.ClearContents ' Cancella tutti i dati sul foglio2
   
    WS1.Range("A3:I3").Copy Destination:=WS2.Range("A1") ' copia la riga "3" come riga di intestazione
    UR = WS1.Range("A" & Rows.Count).End(xlUp).Row ' Ultima riga contenente dati
    J = 2 ' prima riga utile per i dati sul foglio2
    For I = 5 To UR ' i dati iniziano a riga 5
        If WS1.Cells(I, 2) >= 1 Then
            WS1.Range("A" & I & ":I" & I).Copy Destination:=WS2.Range("A" & J)
            J = J + 1
        End If
    Next I
    WS2.Select
    Application.ScreenUpdating = True
    MsgBox "Effettuata copia dei dati"
    Set WS1 = Nothing
    Set WS2 = Nothing
End Sub


[Flash30005]

Ciao Falco646 e benvenuto nel Forum

Abbiamo trattato questo argomento proprio pochi giorni fa e risolto tramite macro che puoi vedere in questo topic

in qual caso la macro cancellava il contenuto delle celle
nel tuo caso invece dovrebbe copiare quindi la macro adattata alle tue esigenze potrebbe essere questa

Codice: Seleziona tutto

Sub CopiaSe()
Set Ws1 = Worksheets("Foglio1")
Set Ws2 = Worksheets("Foglio2")
Ws2.Cells.Clear
Ws1.Range("A1:I4").Copy Destination:=Ws2.Range("A1")
UR1 = Ws1.Range("A" & Rows.Count).End(xlUp).Row
RR2 = 5
For RR1 = 5 To UR1
If Ws1.Cells(RR1, 2).Value >= 1 Then
Ws1.Range("A" & RR1 & ":I" & RR1).Copy Destination:=Ws2.Range("A" & RR2)
RR2 = RR2 + 1
End If
Next RR1
End Sub


Ciao

EDIT ci siamo accavallati nelle risposte, leggi anche ciò cha ha scritto Ricky qui sopra

[falco646]

Ciao,
vada per la riga "5".

Si si può copiare tutto basta sapere cosa copiare.

Le intestazioni in quale riga sono ?

3
Si come scritto sopra ho letto quel topic ma non sono in grado di adattarlo quindi ho dovuto chiedere aiuto =( ora provo la macro! Grazie intanto! =)
EDIT: eh ma le intestazioni sono senza filtro, c'è un modo oppure mi accontento?

[ricky53]

Ciao,
ho modificato il codice che ti avevo inviato.
Le modifiche le ho fatte in base alle tue informazioni che hai fornito successivamente alla mia pubblicazione.

Prova e ... siamo QUI


Flash: ormai abbiamo lo stesso stile di programmazione !
A parte l'indentazione del codice che consiglio a tutti di utilizzarla perchè aumenta TANTISSIMO la leggibilità del codice.
Per esempio:
1. diventano evidenti l'inizio e la fine dei cicli For/Next"
2. diventano evidenti l'inizio e la fine degli "If"
3. si capisce bene le istruzioni se sono dentro o fuori in comando
4. ecc. ecc.

[Flash30005]

La macro postata da me è stata modificata e adattata alle tue esigenze compreso copia della testata
ma evidentemente ti è sfuggito e quindi non l'hai nemmeno provata

ciao

[falco646]

Funziona tutto perfettamente! Grazie mille! ^^ Fantastico!