Formula Excel

[Lucio Peruggini]

Formuletta
Cortesemente, qual è la formula giusta per ottenere in BV2:FG2 il valore corrispondente a BV1:FG1 che trovasi da BB2:BU2?
A vista d’occhio ne vediamo sette che devo riportare per i novanta numeri (1:90 dell’intera stringa).
Grazie

https://dl.dropbox.com/u/18220462/IMMAGINI/Formula.PNG

[Anthony47]

Forse in BV2:

Codice: Seleziona tutto

=SE(CONTA.SE($BB2:$BU2;BV$1)>0;BV$1;"")


Da copiare poi verso destra, ed eventualmente anche verso il basso.

Ciao

[Lucio Peruggini]

=SE(CONTA.SE($BB2:$BU2;BV$1)

Mi ero arenato a questo punto.

Grazie molte Anthony
Ciao

[Lucio Peruggini]

https://dl.dropbox.com/u/18220462/FILE/Cartel1.xlsx

Ciao e buona serata
In J1:CU1 ho i numeri da uno a novanta.
In J2:CU2 ho valori numerici misti.

Questi ultimi, vorrei prenderne dieci con valore più basso e dieci con valore più alto inserendo prima i valori più bassi in CZ2:DI2; e due colonne più avanti DL2:DU2, dieci con valore più alto.
Questi valori andrebbero messi in ordine crescente piccolo-grande ma ognuno di essi deve riportare alla riga 1, il numero di appartenenza che trovasi in J1:Cu1.
Esempio:

Codice: Seleziona tutto

J……………………………………………………………………………………………………………………..X
1      2      3     4     5   6     7    8     9    10    11    12    13    14   15
204   487   161   209   368   94   296   97   393   346   177   287   353   146   153

I valori della riga due (dieci) vanno riporti in ordine crescente piccolo-grande in CZ2:DI2 e sopra di essi (riga 1) il numero di appartenenza. Così per i dieci valori più alti (dieci) in ordine decrescente grande-piccolo in DL:DU.

Ricordo che la stringa J2:CU2 comprende 90 colonne; numeri da 1 a 90.
Se dovessero riscontrarsi valori identici (caso piuttosto raro) si prenderanno i due numeri di pertinenza.

Allego file che è meglio!
Grazie

[Anthony47]

In CZ2:

Codice: Seleziona tutto

=PICCOLO($J$2:$CU$2;RIF.COLONNA(A1))

Poi copia verso dx

In DL2:

Codice: Seleziona tutto

=GRANDE($J$2:$CU$2;RIF.COLONNA(A1))

Idem copia verso dx

In CZ1:

Codice: Seleziona tutto

=INDICE($J$1:$CU$1;CONFRONTA(CZ2;$J$2:$CU$2;0))

Copia verso dx fino a DU1, saltando DJ:DK

Ciao

[Lucio Peruggini]

Troppo forte!!!
Grazie Anthony

[Lucio Peruggini]

"Se dovessero riscontrarsi valori identici (caso piuttosto raro) si prenderanno i due numeri di pertinenza."

Intendevo che, qualora si fossero riscontrati valori uguali alla riga 2, segnare i numeri corrispondenti; non lo stesso numero. Due somme uguali ma i numeri saranno diversi.

Ora ci sono questi risultati:

In una si doppia il 49, nell'altra il 66

https://dl.dropbox.com/u/18220462/FILE/Cattura.PNG

[Anthony47]

Peso dall' esame di come adattare la descrizione testuale al file evidentemente non ho letto fino all' ultima riga

Nelle formule date, modifica tutte le parti "$J$2:$CU$2" in "($J$2:$CU$2+RIF.COLONNA($J$2:$CU$2)/10000)" e conferma le formule con Contr-Maiusc-Enter

Se ti interessa mantenere l' ordine con cui i numeri si presentano in J:CU allora usa "+Rif.Colonna" per le formule con PICCOLO e "-Rif.Colonna" nelle formule con GRANDE.

I numeri in CZ2:DU2 hanno una componente decimale, che maschererai formattando le celle con 0 decimali; tienilo pero' presente se usi quei valori in altre formule, se e' il caso invece del semplice "CZ2" userai "Int(CZ2)".

Ciao

[Lucio Peruggini]

In CZ2:

Codice: Seleziona tutto

=PICCOLO($J$2:$CU$2;RIF.COLONNA(A1))

Poi copia verso dx

In DL2:

Codice: Seleziona tutto

=GRANDE($J$2:$CU$2;RIF.COLONNA(A1))

Idem copia verso dx

In CZ1:

Codice: Seleziona tutto

=INDICE($J$1:$CU$1;CONFRONTA(CZ2;$J$2:$CU$2;0))

Copia verso dx fino a DU1, saltando DJ:DK

Ciao

Ciao Anthony, sto rincretinendo dietro queste due formule che avevi fatto per l’atro foglio e che vorrei applicare a queste due righe.
Da EW 4575 in poi devo marcare in ordine grande-piccolo i valori da CZ a EV.
In EW 4574 devono corrispondere i numeri di appartenenza a questi valori trovati alla riga 4575.
Questa stringa va poi copiata per cinque volte di seguito e scendendo con un passo 18.

https://dl.dropbox.com/u/18220462/IMMAGINI/Cattura1.PNG

[Anthony47]

Trovi il piu' grande con

Codice: Seleziona tutto

=GRANDE($CZ4575:$EV4575;RIF.COLONNA(A1))

Copia verso dx per il secondo piu' grande, il terzo etc

Il piu' piccolo con

Codice: Seleziona tutto

=PICCOLO($CZ4575:$EV4575;RIF.COLONNA(A1))

Copia verso dx per il secondo piu' piccolo, il terzo etc

Per "i numeri di appartenenza" dei valori elencati, userai

Codice: Seleziona tutto

=INDICE($CZ4574:$EV4574;CONFRONTA(EW4575; $CZ4575:$EV4575;0))


Le formule sono copiabili anche verso il basso.

Non hai poi detto se la modifica del +RIF.COLONNA($J$2:$CU$2)/10000) ha risolto il problema dei doppioni; nota che essa non funziona se nell' intervallo di origine ci sono celle vuote.

Questa ultima considerazione rende inapplicabile la stessa modifica [+RIF.COLONNA($CZ4575:$EV4575)/10000)] a queste ultime formule, visto la presenza di celle vuote nelle origini.
Se ci sono doppioni in riga 4575 e vuoi riportare ambedue i numeri d appartenenza allora dimmelo che c' e' la formula anche per questo.

Ciao

[Flash30005]

In EW 4575 (per grande)
inserisci questa formula

Codice: Seleziona tutto

=GRANDE($CZ4575:$EV4575;RIF.COLONNA(A1))

Cambiando Grande in PICCOLO ottieni l'opposto

Mentre in EW4574 inserisci questa formula che fa riferimento a WW4575

Codice: Seleziona tutto

=INDICE($CZ4574:$EV4574;CONFRONTA(EW4575;$CZ4575:$EV4575;0))

Confermi con Ctrl+Maiu+Enter e trascini ambedue le formule verso destra

Ciao

EDIT mentre facevo le dovute prove ci siamo accavallati con Anthony e mi sembra che sia la stessa soluzione

[Lucio Peruggini]

Trovi il piu' grande con

Codice: Seleziona tutto

=GRANDE($CZ4575:$EV4575;RIF.COLONNA(A1))

Copia verso dx per il secondo piu' grande, il terzo etc

Il piu' piccolo con

Codice: Seleziona tutto

=PICCOLO($CZ4575:$EV4575;RIF.COLONNA(A1))

Copia verso dx per il secondo piu' piccolo, il terzo etc

Per "i numeri di appartenenza" dei valori elencati, userai

Codice: Seleziona tutto

=INDICE($CZ4574:$EV4574;CONFRONTA(EW4575; $CZ4575:$EV4575;0))


Le formule sono copiabili anche verso il basso.

Non hai poi detto se la modifica del +RIF.COLONNA($J$2:$CU$2)/10000) ha risolto il problema dei doppioni; nota che essa non funziona se nell' intervallo di origine ci sono celle vuote.

Questa ultima considerazione rende inapplicabile la stessa modifica [+RIF.COLONNA($CZ4575:$EV4575)/10000)] a queste ultime formule, visto la presenza di celle vuote nelle origini.
Se ci sono doppioni in riga 4575 e vuoi riportare ambedue i numeri d appartenenza allora dimmelo che c' e' la formula anche per questo.

Ciao

Cia Anthony
https://dl.dropbox.com/u/18220462/IMMAGINI/Cattura2.PNG

L'indice non va. =INDICE($CZ4574:$EV4574;CONFRONTA(EW4575; $CZ4575:$EV4575;0)) Probabilmente dovuto alle colonne vuote che intercorrono come da immagine?
Peraltro la formula inserita per il "grande" (adopero solo questa coprendo tutta la stringa dei numeri compresi da CZ.EV, mi salta l'81. Le due righe che si vedono sotto sono quelle giuste e con i numeri di appartenenza.

Per l'altra questione non funzionava; ma ho volutamente e per comodità spostato le medesime formule a queste nuove stringhe.

Grazie per l'aiuto continuo.
Ciao


Per Flesh
Le formule sono uguali ma il problema su spiegato e come si vede in foto rimane.

[Flash30005]

la formula non è posizionata nella stessa riga dei valori ma questo non comporta l'errore se in 4574/4575 hai la matrice corretta.
Comunque la formula va in errore perché non hai premuto Ctrl+Maiu+Enter dopo averla digitata
ovvero vai in edit della formula e premi contemporaneamente questi tre tasti (enter conferma) e avrai una parentesi graffa ai lati della formula.
Questa è una cosa che abbiamo ripetuto più volte sia io che Anthony ma non eseguita a dovere

ciao

[Lucio Peruggini]

Comunque la formula va in errore perché non hai premuto Ctrl+Maiu+Enter dopo averla digitata
ovvero vai in edit della formula e premi contemporaneamente questi tre tasti (enter conferma) e avrai una parentesi graffa ai lati della formula.

Altroché se lo fatto! E' una cosa che ben preso a mente. Non prende la conferma e non capisco il perché. Comunque funziona tutto bene e, poiché i valori sono con due decimali dopo la virgola difficilmente si troveranno numeri doppiati.
In realtà non funzionava solamente perché avevo inserito le formule nella riga sbagliata; non mi ero accorto.
Stavo lavorando su questo foglio e quindi (sbadato che sono) mi ero spostato.

Grazie molte per gli interventi provvidenziali
Ciao

[Flash30005]

Tieni presente che quei dati (archivio riportato e analizzato) è mobile
al prossimo "scatto" di modulo composto da 18 estrazioni dovrai inserire un'altra riga di formule
ma se fai una simulazione a ritroso e perdi un modulo le ultime formule non daranno errore

ciao

[Lucio Peruggini]

https://dl.dropbox.com/u/18220462/IMMAGINI/DOPPIONI.jpg

Ciao Anthony
Contrariamente a quanto pensavo, i doppioni si verificano.
Qual'è, dunque, la formula magica affinché risultino i numeri reali di appartenenza? Da CZ a EV le celle vuote le trovi solo a fine stringa perché ovviamente finiscono i numeri.

Ciao

[Anthony47]

Siamo partiti da queste formule (non da confermare con Contr-Maiusc-Enter)

Codice: Seleziona tutto

=GRANDE($CZ4575:$EV4575;RIF.COLONNA(A1))
=PICCOLO($CZ4575:$EV4575;RIF.COLONNA(A1))
=INDICE($CZ4574:$EV4574;CONFRONTA(EW4575; $CZ4575:$EV4575;0))


In tutte e tre sostituisci la parte
$CZ4575:$EV4575
con
Se($CZ4575:$EV4575<>"";$CZ4575:$EV4575+Rif.colonna($CZ4575:$EV4575);"")
Adesso confermerai le formule con Contr-Maiusc-Enter

Imposta anche la tua configurazione di lavoro, guarda qui: viewtopic.php?f=26&t=97449

Ciao

Edit: vedi CORREZIONE piu' avanti

[Lucio Peruggini]

Scusa ma ci sarebbe una ulteriore aggiunta che ho dimenticato di inserire.
E' spiegato in questo nuovo file.
Ciao

https://dl.dropbox.com/u/18220462/FILE/ ... vo%20.xlsx

[Anthony47]

Intanto mi correggo:

In tutte e tre sostituisci la parte
$CZ4575:$EV4575
con
Se($CZ4575:$EV4575<>"";$CZ4575:$EV4575+Rif.colonna($CZ4575:$EV4575);"")
Adesso confermerai le formule con Contr-Maiusc-Enter

La "sostituzione" giusta e':
Se($CZ4575:$EV4575<>"";$CZ4575:$EV4575+Rif.colonna($CZ4575:$EV4575)/1000000;"")
Visto che stavolta sono in gioco numeri piccoli ha aumentato il divisore a 1000000; inoltre e' opportuno inserire la formula in EW3 in un Se.Valore(Formula;"") per evitare l' errore #NUM quando si cerca l' Nesimo+1 in un gruppo di N valori.

Riepilogando quindi:
In EW3:

Codice: Seleziona tutto

=SE.ERRORE(GRANDE(SE($CZ3:$EV3<>"";$CZ3:$EV3+RIF.COLONNA($CZ3:$EV3)/1000000;"");RIF.COLONNA(A2));"")


In EW2:

Codice: Seleziona tutto

=INDICE($CZ2:$EV2;CONFRONTA(EW3; SE($CZ3:$EV3<>"";$CZ3:$EV3+RIF.COLONNA($CZ3:$EV3)/1000000;"");0))


Per la richiesta aggiuntiva, in EW1 e' come EW2 salvo la diversa "base" di Indice; cioe':

Codice: Seleziona tutto

=INDICE($CZ1:$EV1;CONFRONTA(EW3; SE($CZ3:$EV3<>"";$CZ3:$EV3+RIF.COLONNA($CZ3:$EV3)/1000000;"");0))


Tutte Contr-Maiusc-Enter


Ciao

[Lucio Peruggini]

Ok, è tutto in ordine ed è MAGNIFICO!!!

Ciao e ancora grazie.