CALC funzione arrotonda per numeri che finiscono con 3 o 8

[apprendistaIT]

Ciao a tutti, ho un'altro problema da sottoporvi, dovrei arrotondare i risultati di alcune celle a dei numeri che contengano o x3 o x8, (dove x è il numero della decina) cioè devono essere tipo, 53, 58, 63, 68 ecc

Il file è composto in questo modo:

Foglio 1 cella A1 si avra un valore tipo 115

In foglio 2 avremo:


A1 = 50%
A2 = 60%
A3 = 70%

Nella colonna B avremo il risultato della percentuale su A1 del foglio 1, quindi
B1 = 57,5
B2 = 69
b3 = 80,5

Bene, fin qui tutto normale, io avrei bisogno di avere il seguente risultato nel foglio 2:

B1 = 58
B2 = 68
B3 = 83

Ora, visto che mi è un po' difficile spiegare meglio vi posto anche il file con l'esempio

http://www.megaupload.com/?d=DX5PUNQJ

Io uso CALC di openoffice ma le stesse formule di excel funzionano, si riesce con solo le formule senza macro?

Se si, come?

Grazie mille
Ciao

[Avatar3]

In B1 del foglio2 inserisci questa formula

Codice: Seleziona tutto

=INT(Foglio1!B1/10)*10+SE(ASS(VALORE(DESTRA(INT(Foglio1!B1+0,5);1))-3)<ASS(VALORE(DESTRA(INT(Foglio1!B1+0,5);1))-8);3;8)

copiala verso il basso fino dove serve

ciao

[Anthony47]

Una certa semplificazione rispetto al suggerimento di avatar: in C1

Codice: Seleziona tutto

=ARROTONDA((B1-3)/5;0)*5+3


Ciao

[apprendistaIT]

Ciao a tutti
che dire, siete fantastici funzionano tutte e due, era proprio quello che volevo.

Grazie mille

Se non fosse troppo mi piacerebbe sapere come funzionano quste formule così imparo una cosa nuova

Grazie ancora

Ciao

[Avatar3]

La mia formula (molto più complicata) è costruita in questa maniera
1)

Codice: Seleziona tutto

INT(Foglio1!B1/10)*10

Prende il valore intero di (B1 diviso 10) quindi un 56,5 diventa 5 (azzerando il 6,5) e poi lo moltiplica per 10 quindi avrai 50
2) aggiunge a 50 il seguente calcolo

Codice: Seleziona tutto

DESTRA(INT(Foglio1!B1+0,5);1)

la parte intera dell'ultima cifra a destra dopo aver aggiunto 0,5
quindi 6,5 diventa 7 ma essendo una stringa è stata convertita in valore con appunto

Codice: Seleziona tutto

VALORE(DESTRA(INT(Foglio1!B1+0,5);1))

al quale detraggo 3 quindi 7 diventa 4 (nella prima parte della formula mentre detraggo 8 nella seconda parte ottenendo -1
di questi due valori prendo il valore assoluto quindi avrò 4 nella prima parte e 1 nella seconda
la condizione Se la prima parte è minore della seconda prendi 3 altrimenti prendi 8 per ottenere il valore più vicino a 3 o a 8 (in questo caso 4 non è minore di 1 quindi la condizione ammetterà il valore 8 che aggiungendosi a 50 fa appunto 58.

.....
La geniale formula di Anthony arrotonda il valore (56,5 -3)/5 (quindi avrai 53,5/5) con zero decimali

Codice: Seleziona tutto

=ARROTONDA((B1-3)/5;0)

ottenendo 10,7 che arrotondato in numero intero diviene 11
moltiplicato per 5 ottiene 55 al quale aggiunge 3
ottenendo così 58

Ciao

[ricky53]

Ciao Anthony,
ben tornato ed alla GRANDE vista la soluzione che hai proposto.
Posso aggiungere anche i miei complimenti ???

La riunione delle "Giovani Marmotte" ti ha fatto bene ... Eh, Eh !!!

[Anthony47]

Geniale.. alla grande.. ; per un Arrotonda mi sembra esagerato.

Le Giovani Marmotte si conservano bene e di buonumore.

Ciao a tutti

[ricky53]

Ciao,
no, perchè la "grande" - "genialità" sta nell'aver sottatto il valore minore, diviso/moltiplicato per la differenza dei due valori ed addizionato il minore.

Non è da tutti.
Lasciamelo scriveree !!!

[apprendistaIT]

@Avatar3
Ok, effettivamente la tua è un po' complicata, me la devo studiare un po', potrebbe essermi utile per applicazioni future, quella di Anthony è un po' più semplice da capire, solo un po'

Comunque grazie ancora
Ciao