completare serie storica senza perdere il dato corrispondent

[ineq]

Ciao,
ho un problema con excel:
ho scaricato da un database un foglio già riempito su cui devo lavorare. In colonna A c'è un elenco di paesi; in colonna B ci sono delle date; in colonna C ci sono delle osservazioni numeriche, che sono relative a quella specifica data. Ad esempio,per l'Argentina, per il 1961 l'osservazione è 32,5; sotto al 1961 c'è il 1974, poi il 1975, poi il 1983..con i rispettivi valori in colonna C (è un esempio), e queso vale per ognuno del centinaio di paesi inclusi nel foglio (sempre nella stessa colonna).
Il mio problema è questo: devo avere una serie storica completa (dal 1919 al 2006, poniamo), per ogni paese, (anche se per alcune date mi ritroverei la casella C vuota), e non devo perdere il legame tra anno e osservazione. E vorrei evitare di farlo meccanicamente.. perchè sono 3600 righe! ..e non oso immagine quante diventeranno!
Come posso fare?
Grazie mille!! Aspetto notizie

(ho provato a cercare un topic con un argomento simile, ma senza successo)

[ineq]

qualcuno sa come aiutarmi?
sto copiando a mano i dati in un altro foglio...help!

[Anthony47]

Ciao ineq, benvenuto nel forum.
La mia proposta:
-ti crei un foglio Riepilogo nuovo contenente un lungo elenco con Paese (col A) e Anno (col B); ad esempio da riga 2 verso il basso: Argentina /1919; Argentina /1920; . . . ;Bolivia /1919; Bolivia /1920; . . . ; Zambia /1919; Zambia 1920
-nel foglio di adesso, supponiamo si chiami Foglio1, continui a inserire i dati disponibili: Paese in col A, anno in col B, il dato in col C
-poi in C2 di Riepilogo metti la formula

Codice: Seleziona tutto

=SE(MAX(RIF.RIGA(Foglio1!A$1:A$10)*(Foglio1!A$1:A$10=A2)*(Foglio1!B$1:B$10=B2))>0;INDIRETTO("Foglio1!C"&MAX(RIF.RIGA(Foglio1!A$1:A$10)*(Foglio1!A$1:A$10=A2)*(Foglio1!B$1:B$10=B2)));"")

da confermare con Contr-Maiusc-Enter (non solo Enter)
-infine copi C2 verso il basso

Ti quadra?
Ciao

PS: sei su un forum, non su una chat; le risposte arrivano "a tempo debito"

[ricky53]

Ciao,
Anthony: ottima soluzione (a mio avviso un po' ... complessa).

Probablmente semplifico troppo oppure mi è sfuggito qualcosa nella richiesta:
io avrei utilizzato "CERCA.VERT" inserendo come dato della di ricerca
Nazione & Anno
ed una colonna di appoggio nella quale concatenare:
Nazione & Anno

Esempio:
1. in Foglio1 inserire una colonna davanti alla nazione
2. in A2 = B2 & C2
3. sul foglio Riepilogo in colonna "A" ci saranno le nazioni, in colonna "B" i vari anni
3. in "C2" del foglio riepilogo scrivi

Codice: Seleziona tutto

=SE(VAL.ERRORE(CERCA.VERT(A2 & B2; Foglio1!$A$2:$D$30; 4; 0)); "-"; CERCA.VERT(A2 & B2; Foglio1!$A$2:$D$30; 4; 0))

4. copi in basso sulle altre celle della colonna "C"

[ricky53]

Ciao Anthony,
nel mio "un po' ... complessa"
leggi
"Complimenti per averla scritta ... MA COME L'HAI PENSATA" !!!

Però ...

[Anthony47]

La formula e' nata annidando le varie componenti:
-MAX(RIF.RIGA(Foglio1!A$1:A$10)*(Foglio1!A$1:A$10=A2)*(Foglio1!B$1:B$10=B2)) calcola su quale riga si trova Paese & Anno
-INDIRETTO restituisce il valore cercato
-SE serve a gestire l' ipotesi che non ci sia Paese & Anno
Detto cosi' la complessita' e' ridimensionata.

TUTTAVIA l' uso di Cerca.Vert potrebbe essere vantaggioso nonostante che richieda una colonna di servizio e una formula da trascinare.
Infatti la formula che ho proposto e' "a matrice", quindi "mangia" memoria del pc: se l' hardware non e' ben dotato potrebbe rallentare visibilmente tutto il sistema.
Inoltre, nell' ipotesi che excel in uso sia una versione inferiore a XL2000 la funzione Indiretto sarebbe "volatile", quindi le formule si ricalcolerebbero in continuazione peggiorando vieppiu' le cose.

La fase preparatoria (creare un nuovo foglio con l' elenco di Paese + Anno) e' comune, se ineq si accorge che il pc rallenta e' un attimo aggiungere la colonna da riempire con la formula =B2&C2 e passare dalla formula "Anthony" a quella suggerita da Ricky.

Ciao a tutti.

[ineq]

Grazie mille!!!
Funziona!
Ho usato la formula di Anthony, anche perchè era spiegata in modo molto chiaro, e sono una principiante con excel.
Anche la descrizione del significato delle varie componenti della formula è stato utile: così ho potuto riproporre lo stesso meccanismo su un'altra colonna e ha funzionato anche in questo caso!

Grazie davvero a tutti!!