Condividi:        

Confronto di più celle

Vuoi potenziare i tuoi documenti Word? Non sai come si fa una macro in Excel? Devi creare una presentazione in PowerPoint?
Oppure sei passato a OpenOffice e non sei sicuro di come lavorare al meglio?

Moderatori: Anthony47, Flash30005

Confronto di più celle

Postdi Paolo67 » 24/10/23 18:59

Ciao a tutti,
avrei la necessita di fare diversi confronti con più celle.
Mi spiego meglio con un esempio:

La cella CH1 contine un numero.
Se questo numero è <=0 allora deve andare a leggere il valore nella cella B1.
Se questo è <=0 deve scrivere "SN" s
Se questo è >0 e <=1,7 deve scrivere "WSN"
Se questo è >1,7 deve andare a leggere il valore nella cella C1 e fare altri confronti.

Ho stilato un diagramma di flusso che servirebbe al mio scopo e che allego al msg
Se qualcuno riesce a darmi una dritta gliene sarei grato.

PS:Ho provato ad utilizzare la funzione SE ma con excel 2003 posso fare solo 7 reiterazioni

Immagine
OFFICE 2003 - OFFICE 2007
Paolo67
Utente Senior
 
Post: 121
Iscritto il: 20/04/21 20:35

Sponsor
 

Re: Confronto di più celle

Postdi Anthony47 » 24/10/23 21:04

Ad esempio:
Codice: Seleziona tutto
=SE(CH1<=0;"SN";"")&SE(E(CH1>0;CH1<=1,7);"WSN";"")&SE(E(CH1>1,7;C1<=0);"CasoX";"")

In pratica ogni "Condizione" se Vera crea la stringa risultato oppure "niente", e concateni questi esiti. Ovviamente devi fare in modo che solo 1 Condizione restituisca il suo valore
La formula si ferma a "deve andare a leggere il valore nella cella C1 e fare altri confronti"

Prova...
Avatar utente
Anthony47
Moderatore
 
Post: 19245
Iscritto il: 21/03/06 16:03
Località: Ivrea

Re: Confronto di più celle

Postdi Paolo67 » 24/10/23 21:43

Grazie Anthony,ho provato e funziona la tua formula però non sembra seguire il mio volere (se guardi il diagramma di flusso)
Mi spiego,
se nella cella CH1 il valore è <=0 allora devo andare a leggere la cella B1 e risolvere in questo modo:
Se nella cella B1 il valore è <=0 deve scrivere "SN"
Se nella cella B1 il valore è >0 e <=1,7 deve scrivere "WSN"
Se nella cella B1 il valore è >1,7 deve scrivere "RN"
e fin qui tutto ok però...
se nella cella CH1 il valore è >1,7 deve leggere il valore nella cellla B1 e a seconda scrivere "WSN" o "RN"
se nella CH1 il valore è >0 e <=1,7 deve andare a leggere sempre lacella B1 e se questa è
<=0 deve scrivermi "SN"
>=1,7 deve scrivermi "RN"
ma se è >0 e <=1,7 deve andare a leggere il valore in C e proseguire i confronti...
OFFICE 2003 - OFFICE 2007
Paolo67
Utente Senior
 
Post: 121
Iscritto il: 20/04/21 20:35

Re: Confronto di più celle

Postdi Anthony47 » 24/10/23 22:41

E' un gioco di pazienza...
Guardando lo schema, la parte che riguarda CH, B e C sara' (probabilmente):
Codice: Seleziona tutto
=SE(CH1<=0;SE(B1<=0;"SN";SE(B1>1,7;"RN";"WSN"));"^")
&SE(E(CH1>0;CH1<=1,7);SE(B1<=0;"SN";SE(B1>1,7;"RN";"^"));"^")
&SE(CH1>1,7;SE(B1<=1,7;"WSN";"RN");"^")
&SE(E(CH1>0;CH1<=1,7;B1>0;B1<=1,7);SE(C1<=0;"SN";SE(C1>1,7;"RN";"^")))

Ho suddiviso la formula su 4 righe, così e' piu' semplice vedere ogni riga quali casi considera; inoltre invece di "" ho usato " ^ " per rendere visibile il risultato di ogni singola riga della formula (dopo il collaudo ripristinerai "")
Ora devi aggiungere il caso in cui E(C1>0;C1<=1,7), col test di D1

Ri-prova..
Avatar utente
Anthony47
Moderatore
 
Post: 19245
Iscritto il: 21/03/06 16:03
Località: Ivrea

Re: Confronto di più celle

Postdi Paolo67 » 25/10/23 21:24

Ho provato ma sembra ci sia un errore.
Le prime 3 righe fungono,ma con la 4°mi restituisce,a seconda dei dati in input "WSNFALSO" o "SNFALSO" sia che usi "^" che ""
Ho provato anche a creare l'ultimo caso:
&SE(E(CH1>0;CH1<=1,7;B1>0;B1<=1,7;C1>0;C1<=1,7);SE(D1<=0;"SN";SE(D1>1,7;"RN";"WSN");"^"))))
ma restituisce un errore "Sono stati immessi troppi argomenti per questa funzione"
OFFICE 2003 - OFFICE 2007
Paolo67
Utente Senior
 
Post: 121
Iscritto il: 20/04/21 20:35

Re: Confronto di più celle

Postdi Anthony47 » 26/10/23 09:16

Probabilmente nel frattempo hai gia’ corretto...
Nello spezzone 4 manca la condizione Se-Falso, che va aggiunta; quindi:
Codice: Seleziona tutto
&SE(E(CH1>0;CH1<=1,7;B1>0;B1<=1,7);SE(C1<=0;"SN";SE(C1>1,7;"RN";"^"));"^")

Nello spezzone 5 che hai provato a inserire, hai fatto un po’ di confusione con la sequenza dei Se-Vero /Se-Falso vero. La sequenza giusta e’
Codice: Seleziona tutto
&SE(E(CH1>0;CH1<=1,7;B1>0;B1<=1,7;C1>0;C1<=1,7);SE(D1<=0;"SN";SE(D1>1,7;"RN";"WSN"));"^")
Avatar utente
Anthony47
Moderatore
 
Post: 19245
Iscritto il: 21/03/06 16:03
Località: Ivrea

Re: Confronto di più celle

Postdi Paolo67 » 27/10/23 20:07

Ciao Anthony,si effettivamente avevo fatto un pò di confusione.
I tuoi suggerimenti sono sempre preziosi e gli interventi sempre risolutivi.
Funge tutto
Grazie!!
;)
OFFICE 2003 - OFFICE 2007
Paolo67
Utente Senior
 
Post: 121
Iscritto il: 20/04/21 20:35


Torna a Applicazioni Office Windows


Topic correlati a "Confronto di più celle":


Chi c’è in linea

Visitano il forum: Nessuno e 38 ospiti