Conteggio colonne indipendenti excel o powerbi

[Blu_ice]

Ciao

Sono 2 giorni che proverei a tracciare il conteggio totale per ogni settimana ma non ho trovato alcuna idea per farlo. c'è correlazione con 2 colonne e non so come contare ogni colonna separatamente per ogni settimana e tracciarla

Traccerei un grafico con il conteggio settimanale dell'allenamento aperto totale e dell'allenamento completo totale

c'è modo di farlo in una sola pivot?, io lo faccio ovviamente con due pivot diverse avendo dipendenza tra i dati

Week Num wk Open training wk Complete training
28 28 28
28 28 29
28 28 30
29 29 29

eek numer count open training x week count complete training x week
28 3 1
29 1 2
30 0 3

[Anthony47]

Perdona, ma quali sono i dati di partenza? Almeno una immagine
E, descrivendo piu' generosamente, che cosa va calcolato?
Infine quale versione di Office usi

[Blu_ice]

I dati di inizio sono questi con office 365, ogni riga registra quando è stato aperto il training e chiuso

Es nella prima riga è stato aperto e chiuso nella stessa settimana, la riga successiva è stato chiuso nella settimana successiva e cosi via

Codice: Seleziona tutto

Num settimana   | Settimana apertura training |    Settimana chiusura training    
28      28            28   
28      28            29   
28      28            30   
29      29            29

Il risultato finale che mi piacerebbe avere in power bi o tabella pivt o quello sotto, essendo due colonne correlate tra loro apertura e la settimana non riesco a conteggiare in una sola tabella quel risultato, dovrei fare un conteggio indipendente tra apertura e chiusura

Codice: Seleziona tutto

Num sett.   | conteggio apertura train.   |conteggio chiusura traini.   
28      3            1   
29      1            2
30      0            3

[Blu_ice]

la tabella originale e quella di output

[Blu_ice]

la tabella originale e quella di output

https://postimg.cc/PNtD5kJ4

https://postimg.cc/PNtD5kJ4

[Anthony47]

La casistica data non e' esaustiva, ho rimediato con la mia fantasia.
I dati sono in colonna A-B-C, da riga 2
Inserisci in F2 (o dove vuoi i risultati) la formula

Codice: Seleziona tutto

=LET(iData;A2:C100;uWeek;SEQUENZA(MAX(iData)-MIN(iData)+1;;MIN(iData));Open;CONTA.SE(INDICE(iData;0;2);uWeek);Closed;CONTA.SE(INDICE(iData;0;3);uWeek);mayBe;STACK.ORIZ(uWeek;Open;Closed);mayBe)


I risultati saranno come da immagine:


Se aspettavi qualcosa di diverso allora devi descrivere con "ancora più dovizia di particolari"...

[Blu_ice]

Grazie molte è quello

si guardo se funziona sul excel 2013 ( pensavo di avere il 365)

Con la pivot non si può fare vero? si è costretti ad usare una formula distinta

[Anthony47]

Nel calcolo della colonna 3 non c'e' nessuna relazione con la colonna A, quindi non vedo come organizzare una unica pivot
Quella formula non lavorera' su XL2013, devi lavorae con altre formule.
Esempio:
-in F2 la formula

Codice: Seleziona tutto

=MIN(A2:C100)

-in F3 la formula

Codice: Seleziona tutto

=SE.ERRORE(SE(F2+1<=MAX($A$2:$C$100);F2+1;"");"")

Copia verso il basso per quante settimane pensi di dover elencare; se la settimana manca nell'elenco allora vedrai una cella vuota
-in G2 calcoli le "Aperte nella settimana" con la formula

Codice: Seleziona tutto

=SE($F2<>"";CONTA.SE(B$2:B$100;$F2);"")

Copia verso il basso per quante righe di formule hai inserito in colonna F
-copia le formule di colonna G in colonna H, per calcolare le "Chiuse nella settimana"

Prova e fai sapere...

[Blu_ice]

Grazie si si con le formule ho fatto un lavoro simile. ( uso office 2019)

si può fare la stessa cosa col power bi?

[Anthony47]

Non sono un esperto di Power BI, non so risponderti