Condividi:        

Confronto listini Utente e dealer

Vuoi potenziare i tuoi documenti Word? Non sai come si fa una macro in Excel? Devi creare una presentazione in PowerPoint?
Oppure sei passato a OpenOffice e non sei sicuro di come lavorare al meglio?

Moderatori: Anthony47, Flash30005

Confronto listini Utente e dealer

Postdi danibi60 » 11/02/22 15:08

VBuongiorno a Tutti, nel file che vi allego avevo costruito tempo fa una matrice che mi permettesse confrontare due listini,
Lato Dealer e Lato cliente

Tali listini sono stati inseriti alla dx del prospetto

Quel che vi chiedo è aiuto e supporto per quanto segue:

La formula , presente nelle colonne Q e S, che mi permette di valorizzare attraverso le fasce di peso mi sembra corretta, unico dubbio sul fatto che mi conteggi esattamente quanto richiesto nell'ultima fascia di entrambi (AG12 - AL12 - AQ12 - AV12 - BA12 - BF12)e cioè che dopo i 100 kg al valore di addebito abbinato alla fascia si incrementi tale valore ogni 1 kg dell'importo indicato appunto in tale cella.

Inoltre, giusto per non farsi mancare nulla, da quest'anno parte dell'Italia (Calabria e Isole) hanno una tariffazione diversa, indi per cui vorrei implementare la formula di cui sopra della possibilità - in relazione alla discriminante delle regioni poste in colonna che sono presenti in colonna G che, là dove riscontrasse appunto regioni del sud (Calabria, Sicilia o Sardegna) la formula tenga presente di tale condizione.... In tutta onestà non so come inserire quella parte nella formula già presente.

Spero d'essermi spiegato con la dovuta chiarezza...

Qui il file
https://www.dropbox.com/s/cim3a20g06064 ... .xlsx?dl=0
Grazie
Danibi60
"Sono le persone che nessuno immagina che possano fare certe cose, quelle che fanno cose che nessuno può immaginare."
Win 10 & Office365 Premium
danibi60
Utente Senior
 
Post: 489
Iscritto il: 11/07/13 09:21
Località: Bergamo

Sponsor
 

Re: Confronto listini Utente e dealer

Postdi Anthony47 » 12/02/22 13:37

La formula attuale calcola correttamente fino a 100 kg, usando il Cerca.Vert con "Intervallo" 1; avrei comunque usato <100.1 e non <101.
Per >100 il calcolo riparte da 14 + il costo a kg desunto da tabella.
Insomma, per fare un esempio, un collo da 99 kg paga 21.50 (tabella Cliente) e uno da 101 kg paga 15.00
Evidentemente andrebbe modificata la "base" di partenza a cui aggiungere il sovrapprezzo per peso.
Per le maggiorazioni, oggi le tabelle Calabria-Sicilia e Sardegna sono il 130% di quella "nazionale"; quindi volendo semplificare potremmo limitarci a moltiplicare per 1.3 il valore calcolato (1.26 la tariffa a kg).

Immagino pero' che queste tabelle possano variare con dinamiche piu' complesse, per cui credo sia meglio ignorare questa semplificazione e lavorare su tre tabelle diverse.

Per semplificarsi la vita in futuro, e' meglio prevedere che le tabelle possano crescere fino a 20 righe, e che comunque possano essere articolate diversamente per regione (es 10 fasce sul Nazionale e 5 fasce su Sardegna).

Come possiamo fare:
Per identificare l'ultima riga, in colonna 1 non usiamo la dizione "oltre xxx" ma 99999 (cioe' un peso oltre le peggiori aspettative)

Visto che hai Office 365, semplifichiamoci la vita usando la funzione LET.
Definiamo pertanto alcune "variabili":
Peso; il "peso convenzionale" da usare nel calcolo; in un caso sara' pari a MAX($O3:$P3), nell'altro a MAX($I3:$J3)
SDC; e' lo "scarto orizzontale" tra le tabelle Dealer e quella Cliente finale; nel caso Dealer sara' impostato a 0, nel caso Cliente finale sara' impostato a 15
Tabella; e' la tabella da cui estrarre i costi, e sara' calcolata tenendo presente la Regione e l'ambiente (Dealer /Cliente finale). Trattasi della definizione piu' complessa, e io l'ho calcolata con questa formula:
Codice: Seleziona tutto
SCARTO($AE$4;0;SDC+SE.ERRORE(AGGREGA(14;2;(RICERCA($G3;$AE$2:$AQ$2)>0)*(RIF.COLONNA($AE$2:$AQ$2)-RIF.COLONNA($AE$4));1);0);20;3)

$AE$4 rappresenta la "base" delle tabelle
$AE$2:$AQ$2 rappresenta l'intestazione in cui cercare la Regione
$G3 e' la Regione in questione
SDC e' lo scarto orizzontale aggiuntivo da utilizzare, a seconda che si tratti di Dealer o Cliente finale

Con queste impostazioni la formula finale SEMPLIFICATA e':
Codice: Seleziona tutto
=LET(Peso;DefinizionePeso;SDC;DefinizioneScartoAggiuntivo;Tabella;DefinizioneTabella;CERCA.VERT(Peso;Tabella;3;1)+CERCA.VERT(99999;Tabella;3;1)*(Peso>100)*(Peso-100))


L'ho scritta semplificata per mostrare la relativa semplicita' della formula e per renderla leggibile.

Nella forma reale, per la cella Q3, sara':
Codice: Seleziona tutto
=LET(Peso;MAX($O3:$P3);SDC;15;Tabella;SCARTO($AE$4;0;SDC+SE.ERRORE(AGGREGA(14;2;(RICERCA($G3;$AE$2:$AQ$2)>0)*(RIF.COLONNA($AE$2:$AQ$2)-RIF.COLONNA($AE$4));1);0);20;3);CERCA.VERT(Peso;Tabella;3;1)+CERCA.VERT(99999;Tabella;3;1)*(Peso>100)*(Peso-100))

La stessa formula puo' essere usata in S3, con le correzioni alle definizioni di Peso e di SDC; quindi
Codice: Seleziona tutto
=LET(Peso;MAX($I3:$J3);SDC;0;Tabella;SCARTO($AE$4;0;SDC+SE.ERRORE(AGGREGA(14;2;(RICERCA($G3;$AE$2:$AQ$2)>0)*(RIF.COLONNA($AE$2:$AQ$2)-RIF.COLONNA($AE$4));1);0);20;3);CERCA.VERT(Peso;Tabella;3;1)+CERCA.VERT(99999;Tabella;3;1)*(Peso>100)*(Peso-100))


Se in futuro cambia la posizione delle tabelle dovrai modificare quel $AE$4 (la base) e quei $AE$2:$AQ$2 (l'area delle intestazioni)
Se cambia la larghezza dovrai modificare quel $AE$4 (la base, probabilmente), quei $AE$2:$AQ$2 (l'area delle intestazioni) e anche i valori di SDC: rimarra' 0 per Dealer ma variera' l'offset delle tabelle Cliente)

Spero che sia tutto chiaro, a partire dall'uso della LET (se non conosci questa funzione guarda qui: viewtopic.php?f=26&t=111058#p658673 e nell'help di Excel)

Ciao
Avatar utente
Anthony47
Moderatore
 
Post: 19196
Iscritto il: 21/03/06 16:03
Località: Ivrea

Re: Confronto listini Utente e dealer

Postdi danibi60 » 12/02/22 15:08

Ciao Antony non conoscevo la funzione LET e devo dire che è di una complessità notevole...

La formula attuale calcola correttamente fino a 100 kg, usando il Cerca.Vert con "Intervallo" 1; avrei comunque usato <100.1 e non <101.
Hai ragione e ho variato il parametro come da te suggerito.

Per >100 il calcolo riparte da 14 + il costo a kg desunto da tabella. Era rimasto in memoria il vecchio valore ai 1000, ora ho inserito sia dal lato cliente sia dealer il valore 100 corretto...

Ho poi inserito le due LET nelle rispettive celle , ma in alcune righe (evidenziate in verde) "spara" un valore esorbitante, come mai?

Ti ho indicato giusto come esempio quale dovrebbe essere il valor e corretto in Q16

Allego file...

https://www.dropbox.com/s/cim3a20g06064 ... .xlsx?dl=0

Grazie
"Sono le persone che nessuno immagina che possano fare certe cose, quelle che fanno cose che nessuno può immaginare."
Win 10 & Office365 Premium
danibi60
Utente Senior
 
Post: 489
Iscritto il: 11/07/13 09:21
Località: Bergamo

Re: Confronto listini Utente e dealer

Postdi Anthony47 » 12/02/22 15:35

Ciao Antony non conoscevo la funzione LET e devo dire che è di una complessità notevole...
Beh, a me sembra abbastanza semplice; ma forse solo perche' la conosco e la uso già :lol:
Vedila un po' come tante celle di appoggio inserite all'interno della stessa formula.

I risultati esorbitanti...
Anthony ha scritto:Come possiamo fare:
Per identificare l'ultima riga, in colonna 1 non usiamo la dizione "oltre xxx" ma 99999 (cioe' un peso oltre le peggiori aspettative)

...nascono dal fatto che NON HAI utilizzato il valore 99999 per indicare l'ultima riga della tabella, di conseguenza non viene prelevato il costo al kg corretto.

Ciao
Avatar utente
Anthony47
Moderatore
 
Post: 19196
Iscritto il: 21/03/06 16:03
Località: Ivrea

Re: Confronto listini Utente e dealer

Postdi danibi60 » 12/02/22 16:12

Hai ragione, ma se inserisco comunque 99999 nelle ultime righe non funziona lo stesso...


https://www.dropbox.com/s/cim3a20g06064 ... .xlsx?dl=0
"Sono le persone che nessuno immagina che possano fare certe cose, quelle che fanno cose che nessuno può immaginare."
Win 10 & Office365 Premium
danibi60
Utente Senior
 
Post: 489
Iscritto il: 11/07/13 09:21
Località: Bergamo

Re: Confronto listini Utente e dealer

Postdi Anthony47 » 12/02/22 16:16

Non funziona perche' hai inserito 999999 ma la formula e' tarata su 99999; riprova!
Avatar utente
Anthony47
Moderatore
 
Post: 19196
Iscritto il: 21/03/06 16:03
Località: Ivrea

Re: Confronto listini Utente e dealer

Postdi danibi60 » 12/02/22 16:25

Che bischero! e si che li avevo contati due volte...
Sei un Grande Antony, ora funziona che è una bellezza...

Quindi se aumentassero i parametri dei vari listini sarà sufficiente modificare come da te indicato, giusto?

Se in futuro cambia la posizione delle tabelle dovrai modificare quel $AE$4 (la base) e quei $AE$2:$AQ$2 (l'area delle intestazioni)
Se cambia la larghezza dovrai modificare quel $AE$4 (la base, probabilmente), quei $AE$2:$AQ$2 (l'area delle intestazioni) e anche i valori di SDC: rimarra' 0 per Dealer ma variera' l'offset delle tabelle Cliente)



Grazie infinite!
Danibi60
"Sono le persone che nessuno immagina che possano fare certe cose, quelle che fanno cose che nessuno può immaginare."
Win 10 & Office365 Premium
danibi60
Utente Senior
 
Post: 489
Iscritto il: 11/07/13 09:21
Località: Bergamo

Re: Confronto listini Utente e dealer

Postdi Anthony47 » 12/02/22 16:35

Eh he, certe cose o vengono bene subito o diventano una serie di impapinamenti...

Se le tabelle si allungano (anche in modo difforme, es una si e due no) basta che la sequenza sia per peso crescente e l'ultima riga sia marcata 999999; oops... 99999
Se si creano piu' tabelle (es relative a regioni particolari) allora devi "allargare" l'area delle intestazioni e aumentare SDC (che e' la distanza tra le tabelle Dealer e quella Clienti); e' importante che Dealer e Clienti finali abbiano sempre lo stesso numero di tabelle e la stessa sequenza. Non l'ho detto, ma nelle intestazioni di tabella deve esserci scritta la regione a cui si riferisce (con lo stesso formato in cui si trova incolonna G)

Ciao
Avatar utente
Anthony47
Moderatore
 
Post: 19196
Iscritto il: 21/03/06 16:03
Località: Ivrea

Re: Confronto listini Utente e dealer

Postdi danibi60 » 13/02/22 10:40

Grazie Antony, anche per aver "limato" il complimento che m'ero fatto da me... :lol: :lol:

cosa intendi quando scrivi: "Se le tabelle si allungano (anche in modo difforme, es una si e due no) basta che la sequenza sia per peso crescente e l'ultima riga sia marcata 999999; oops... 99999"

e inoltre: "Se si creano piu' tabelle (es relative a regioni particolari) allora devi "allargare" l'area delle intestazioni e aumentare SDC (che e' la distanza tra le tabelle Dealer e quella Clienti)"

giusto per capire quale di queste situazioni avresti immaginato e che di certo potrebbero essermi utili...

Grazie e Buona Domenica

Danibi60
"Sono le persone che nessuno immagina che possano fare certe cose, quelle che fanno cose che nessuno può immaginare."
Win 10 & Office365 Premium
danibi60
Utente Senior
 
Post: 489
Iscritto il: 11/07/13 09:21
Località: Bergamo

Re: Confronto listini Utente e dealer

Postdi Anthony47 » 13/02/22 15:57

Dico che le tabelle si possono allungare (piu' delle righe al momento presenti, MA FINO a 20 righe) e non c'e' bisogno di nessun aggiustamento alle formule.
E puoi avere una tabella con mettiamo 7 fasce di prezzo e un'altra con 10, sempre senza bisogno di aggiustamenti.

Se le tabelle diventassero 4 per i dealer e 4 per i clienti finali (es perche' inserisci una tariffazione speciale per un'altra regione) allora dovrai usare, per i Clienti finali, un SDC che e' maggiore di 15 (vedi contare le colonne che ci sono tra la prima colonna Dealer e la prima colonna Clienti)

L'importante e' che le fasce di peso siano in ordine crescente e che l'ultima riga sia identificata come 99999

Volendo potrei semplificarti la vita con questa diversa formula per Q3:
Codice: Seleziona tutto
=LET(Peso;MAX($O3:$P3);SDC;15;BaseTab;$AE$4;Intestaz;$AE$2:$AQ$2;Tabella;SCARTO(BaseTab;0;SDC+SE.ERRORE(AGGREGA(14;2;(RICERCA($G3;Intestaz)>0)*(RIF.COLONNA(Intestaz)-RIF.COLONNA(BaseTab));1);0);20;3);CERCA.VERT(Peso;Tabella;3;1)+CERCA.VERT(99999;Tabella;3;1)*(Peso>100)*(Peso-100))


La parte da adattare e':
Codice: Seleziona tutto
Peso;MAX($O3:$P3);SDC;15;BaseTab;$AE$4;Intestaz;$AE$2:$AQ$2;

Poi gia' Tabella viene calcolata coi parametri BaseTab e Intestaz

Con questa soluzione, se sposti le tabelle modificherai BaseTab e Intestaz; se aggiungi una tabella modificherai Intestaz e SDC (che comunque e' sempre 0 per il listino Dealer)

Piu' semplice, vero :D :D :?:

Ciao
Avatar utente
Anthony47
Moderatore
 
Post: 19196
Iscritto il: 21/03/06 16:03
Località: Ivrea

Re: Confronto listini Utente e dealer

Postdi danibi60 » 13/02/22 17:01

Grazie Anthony, davvero fantastico tutto ciò!

Ma mi chiedo: come fa la formula a individuare la regione corretta? dico male se è attraverso l'intestazione dei listini giusto?
"Sono le persone che nessuno immagina che possano fare certe cose, quelle che fanno cose che nessuno può immaginare."
Win 10 & Office365 Premium
danibi60
Utente Senior
 
Post: 489
Iscritto il: 11/07/13 09:21
Località: Bergamo

Re: Confronto listini Utente e dealer

Postdi Anthony47 » 13/02/22 18:11

danibi oggi ha scritto:Ma mi chiedo: come fa la formula a individuare la regione corretta? dico male se è attraverso l'intestazione dei listini giusto?

Anthony ieri ha scritto: Non l'ho detto [non l'avevo ancora detto prima di ieri, eh], ma nelle intestazioni di tabella deve esserci scritta la regione a cui si riferisce (con lo stesso formato in cui si trova incolonna G)

Quindi No, non dici male

Mi accorgo che la formula ha un vulnus... Volendo fare una formula programmata per tutti i casi non si puo' considerare fisso che la soglia "a kg aggiuntivo" scatti a 100 kg.
Fortunatamente la possiamo calcolare sempre dalla tabella, con questa penultima variante della formula per Q3:
Codice: Seleziona tutto
=LET(Peso;MAX($O3:$P3);SDC;15;BaseTab;$AE$4;Intestaz;$AE$2:$AQ$2;Tabella;SCARTO(BaseTab;0;SDC+SE.ERRORE(AGGREGA(14;2;(RICERCA($G3;Intestaz)>0)*(RIF.COLONNA(Intestaz)-RIF.COLONNA(BaseTab));1);0);20;3);PesoMax;CERCA.VERT(99990;Tabella;2,1);CERCA.VERT(Peso;Tabella;3;1)+CERCA.VERT(99999;Tabella;3;1)*(Peso>PesoMax)*(Peso-PesoMax))


Come vedi, una volta definita Tabella vado a definire PesoMax=PesoMax;CERCA.VERT(99990;Tabella;2,1) e poi (invece di 100 come valore fisso) uso PesoMax nel calcolo finale:
CERCA.VERT(Peso;Tabella;3;1)+CERCA.VERT(99999;Tabella;3;1)*(Peso>PesoMax)*(Peso-PesoMax)

In questo modo potrai avere tabelle con il calcolo a scaglioni fino (esempio) a 100 kg, e altre fino a 200; e la formula si "aggiusta" da sola

Aahhh, il bello della LET....

PS: Consiglio di far partire tutte le tabelle da 0 kg, e non 0.1 come ora; non vorrei mai che ti trovassi a spedire 50 gr di oro, non riusciresti a calcolare il prezzo di spedizione
Avatar utente
Anthony47
Moderatore
 
Post: 19196
Iscritto il: 21/03/06 16:03
Località: Ivrea

Re: Confronto listini Utente e dealer

Postdi danibi60 » 16/02/22 09:56

Ciao Anthony,

ho simulato una spedizione per la Sicilia (che ti ho evidenziato) che però non mi quadra in termini di valorizzazione, infatto lato cliente mi tornerebbe un valore di €40,75, ma lato dealer €8,90, il ché non è corretto... Stiamo parlando di una tariffa che si interfaccia con la Sicilia...

https://www.dropbox.com/s/cim3a20g06064 ... .xlsx?dl=0
"Sono le persone che nessuno immagina che possano fare certe cose, quelle che fanno cose che nessuno può immaginare."
Win 10 & Office365 Premium
danibi60
Utente Senior
 
Post: 489
Iscritto il: 11/07/13 09:21
Località: Bergamo

Re: Confronto listini Utente e dealer

Postdi Anthony47 » 16/02/22 10:13

Se parli della riga 20, in Q20 calcoli una spedizione per peso=130 e in S20 per un peso=20; non mi meraviglia che i costi siano alquanto diversi...
Avatar utente
Anthony47
Moderatore
 
Post: 19196
Iscritto il: 21/03/06 16:03
Località: Ivrea

Re: Confronto listini Utente e dealer

Postdi danibi60 » 16/02/22 14:53

In S20 a dire io vedo solo la risultanza che è €8,29 e non il peso di 20 come da te indicato...
"Sono le persone che nessuno immagina che possano fare certe cose, quelle che fanno cose che nessuno può immaginare."
Win 10 & Office365 Premium
danibi60
Utente Senior
 
Post: 489
Iscritto il: 11/07/13 09:21
Località: Bergamo

Re: Confronto listini Utente e dealer

Postdi Anthony47 » 16/02/22 18:07

In S20 a dire io vedo solo la risultanza che è €8,29 e non il peso di 20 come da te indicato...


Nel tuo primo messaggio, il Nolo Cliente era calcolato con la formula
Codice: Seleziona tutto
=SE(MAX(O3;P3)<101;CERCA.VERT(MAX(O3;P3);$AT$4:$AW$12;3;1);14+(ARROTONDA.ECCESSO((MAX(O3;P3)-100)/1;1)*$AV$12))

Da cui avevo dedotto che il "peso convenzionale della spedizione" era calcolato guardando O3:P3

Il Nolo Dealer era invece calcolato con la formula
Codice: Seleziona tutto
=SE(I3<101;CERCA.VERT(MAX(I3;J3);$AE$4:$AH$12;3;1);21+(ARROTONDA.ECCESSO((I3-100)/1;1)*$AG$12))

Da cui avevo dedotto che il "peso convenzionale della spedizione" era calcolato guardando I3:J3

In tutte le mie formule ho continuato secondo queste convinzioni.
Ma se sono sballate allora non dovresti avere problema a correggere quanto ti ho proposto, in particolare basterà correggere la parte iniziale della formula, dove "definiamo" il valore del peso:
Codice: Seleziona tutto
=LET(Peso;MAX($O3:$P3);etc etc


Bastera' che invece delle definizioni che ho messo io (es, per Clienti finali, Max(O3:P3)) metti la definizione giusta per il tuo tracciato dati.

Ciao
Avatar utente
Anthony47
Moderatore
 
Post: 19196
Iscritto il: 21/03/06 16:03
Località: Ivrea

Re: Confronto listini Utente e dealer

Postdi danibi60 » 16/02/22 20:42

Ok, provo e Ti so dire
Grazie
"Sono le persone che nessuno immagina che possano fare certe cose, quelle che fanno cose che nessuno può immaginare."
Win 10 & Office365 Premium
danibi60
Utente Senior
 
Post: 489
Iscritto il: 11/07/13 09:21
Località: Bergamo

Re: Confronto listini Utente e dealer

Postdi danibi60 » 17/02/22 07:22

Si è vero, avevo scordato d'aver inserito una variabile anche in ($O3:$P3), indi per cui la formula teneva conto anche di quel parametro... perdona se ti ho fatto perdere tempo.
Grazie infinite

Danilo
"Sono le persone che nessuno immagina che possano fare certe cose, quelle che fanno cose che nessuno può immaginare."
Win 10 & Office365 Premium
danibi60
Utente Senior
 
Post: 489
Iscritto il: 11/07/13 09:21
Località: Bergamo

Re: Confronto listini Utente e dealer

Postdi danibi60 » 19/02/22 16:49

Ciao Anthony,

con i fornitori davvero è un'impresa folle cercare di capire tutti i vari meccanismi e spesso sono così macchiavellici nelle loro applicazioni che mi fanno impazzire.

Morale dai 100 kg in su non funziona come avevo compreso inizialmente e di conseguenza programmato la formula iniziale

Ti spiego:

Facciamo un esempio che vale per la tariffa sia Italia sia per il Sud (che per suddivisione geografica è rimasta invariata) cambiano solo gli importi ma il meccanismo di calcolo è lo stesso.

Spedizione da 130 kg

La spedizione in oggetto parte da Torino per cui il pricing di riferimento è quello Fino a 100 kg: € 20,97.

I 30kg successivi rientrano nella fascia “Oltre fino a kg1000 ogni 50 kg eccedenti” Indi per cui 11,89€ vengono quindi addebitati quando si superano i 100kg a scaglioni di 50kg.

Nel nostro caso, 130kg i 30kg eccedenti rientrano nel primo scaglione da 50.
Il peso superiore a 100, da 101 a 150 prevede l’addebito dei 11,89€; da 151kg a 200Kg scatta il secondo scaglione da 11,89€.

Indi per cui il costo totale dev'essere:€32,86

Ho tentato i modificare l'ultima scala ma con Let che non conosco credo di generare solo disastri...

Ti chiedo scusa ma ho ricevuto la tariffa (che ti ho incollato sotto le tariffe nel file allagato, con questa modifica in chiaro solo venerdì...

Danibi60

https://www.dropbox.com/s/cim3a20g06064 ... .xlsx?dl=0
"Sono le persone che nessuno immagina che possano fare certe cose, quelle che fanno cose che nessuno può immaginare."
Win 10 & Office365 Premium
danibi60
Utente Senior
 
Post: 489
Iscritto il: 11/07/13 09:21
Località: Bergamo

Re: Confronto listini Utente e dealer

Postdi Anthony47 » 19/02/22 18:52

Quindi non si procede a tanto al kg ma tanto a ogni blocco di +50 kg?
Se e' così allora bisogna modificare l'ultima parte della formula:

Non CERCA.VERT(99999;Tabella;3;1)*(Peso>100)*(Peso-100))
Ma:
Codice: Seleziona tutto
CERCA.VERT(99999;Tabella;3;1)*(Peso>100)*(INT((Peso-100)/50)+1))


Ovviamente se un'area lavora in un modo (es tanto a kg) e un'altra lavora in altro modo (es tanto a bloccki di N kg) le formule andrebbero riviste.

Ciao
Avatar utente
Anthony47
Moderatore
 
Post: 19196
Iscritto il: 21/03/06 16:03
Località: Ivrea

Prossimo

Torna a Applicazioni Office Windows


Topic correlati a "Confronto listini Utente e dealer":


Chi c’è in linea

Visitano il forum: Nessuno e 52 ospiti