EXCEL--MACRO PER SCARICO AUTOMATICO DI DETERMINATE QUANTITA'

[FLAVIOZ]

Buongiorno a tutti, avrei bisogno di aiuto per sistemare il mio file di inventario magazzino.
Per ora ho una serie di colonne quali ARTICOLO, QUANTITA' PER MACCHINA, QUANTITA' A MAGAZZINO.
Tutti gli articoli sono parti per assemblare delle macchine, ed io volevo tenere conto della giacenza a magazzino senza andarli a scaricare uno per uno ogni volta che viene assemblata una macchina.
La mia idea era appunto di creare dei pulsanti, ognuno con un nome di una macchina, e ogni volta che si preme sopra ad uno di essi che vada a sottrarre per un determinato numero di articoli (quelli necessari per costruirla) la quantità per macchina alla quantità a magazzino.
esempio:
10 articoli, 2 tipi di macchine da assemblare, per la macchina A ho bisogno di 10 pezzi, per la macchina B di 4 pezzi
una volta montata una macchina, tramite apposito pulsante, vado a scalare la quantità degli articoli che mi son serviti per costruirla dalla giacenza dei miei articoli. in questo modo la giacenza rimane sempre aggiornata ad ogni macchina assemblata.

Grazie per l'attenzione e confido in voi

[Anthony47]

Intanto "Benvenuto nel forum"

Ti propongo questo approccio:
-nel tuo foglio di lavoro, utilizza delle colonne libere per creare gli Elenchi dei materiali necessari per assemblare le varie apparecchiature. Se hai un elenco di 1000 codici, in queste colonne scriverai le quantita' da scalare per ognuna delle 1000 voci di anagrafica; basta scrivere le qt <> 0, cioe' i soli componenti necessari
-in un Modulo standard del tuo vba, inserisci questo codice:

Codice: Seleziona tutto

Sub SubtrBoM()
Dim Rispo0 As Variant, Rispo1 As Long, cPos As String, I As Long, ICol As String
'
ICol = "R"                          '<<< La colonna del tuo foglio contenente le giacenze
On Error Resume Next
cPos = Selection.Address
On Error GoTo 0
Rispo0 = Application.InputBox(prompt:="Quale Lista?", Type:=2)      'Quale lista
If Rispo0 <> False Then                                             'Se risposta valida
    Application.EnableEvents = False
    Range(Rispo0 & 1).Resize(2000, 1).Select                        'Mostra la colonna scelta
    Rispo1 = Application.InputBox(prompt:="Quante volte?", Type:=1) 'Quante sottrazioni
    Cells(1, Rispo0).Resize(2000, 1).Copy                           'Copia la lista
    For I = 1 To Rispo1                                             'Sottrai N volte
        Range(ICol & 1).PasteSpecial Paste:=xlPasteValues, Operation:=xlSubtract, _
            SkipBlanks:=False, Transpose:=False
    Next I
    Application.CutCopyMode = False
    If Len(cPos) > 0 Then Range(cPos).Select
    Application.EnableEvents = True
End If
End Sub

Per come fare, vedi viewtopic.php?f=26&t=103893&p=647675#p647675

Nel codice la riga marcata <<< e' da personalizzare con la colonna del tuo foglio contenente le quantita' in giacenza; io per prova ho usato la R, il tuo layout sara' certamente diverso.

A questo punto, se mandi in esecuzione la Sub SubtrBoM, ti verra' chiesto tramite un Inputbox di indicare quale lista vuoi "scaricare"; indicherai la colonna che contiene la lista.
In sequenza verra' selezionata quella lista e ti verra' chiesto quante volte vuoi scaricare quelle voci; risponderai con un numero (va bene anche 0, che significa Non scaricare niente).

Per le modalita' con cui si puo' avviare una macro, vedi viewtopic.php?f=26&t=103893&p=647678#p647678

Fai sapere...