Condividi:        

[Excel 2019]: somma.più.se insieme ad E

Vuoi potenziare i tuoi documenti Word? Non sai come si fa una macro in Excel? Devi creare una presentazione in PowerPoint?
Oppure sei passato a OpenOffice e non sei sicuro di come lavorare al meglio?

Moderatori: Anthony47, Flash30005

[Excel 2019]: somma.più.se insieme ad E

Postdi karug64 » 23/05/19 22:46

Salve a tutti.

Vorrei sapere se è possibile unire un somma.più.se con all'interno la "E".

Questa funziona:

Codice: Seleziona tutto
=SOMMA.PIÙ.SE(Master!$BZ$2:$BZ$300;Master!$B$2:$B$300;"=Si";Master!$P$2:$P$300;"=Si")/CONTA.PIÙ.SE(Master!$B$2:$B$300;"=Si";Master!$P$2:$P$300;"=Si")


Poichè in colonna B oltre che "Si" c'è anche "No" e "Forse" all'interno della formula dovrei dire "sia "si" che "Forse".

Ovviamente se provo qualcosa del genere :

Codice: Seleziona tutto
=SOMMA.PIÙ.SE(Master!$BZ$2:$BZ$300;E(Master!$B$2:$B$300;"=Si";Master!$B$2:$B$300;"=Dubbia");Master!$P$2:$P$300;"=Si")/CONTA.PIÙ.SE(Master!$B$2:$B$300;"=Si";Master!$P$2:$P$300;"=Si")


non va.

C'è qualche soluzione per questo ?

Grazie
Office 2010
karug64
Utente Senior
 
Post: 746
Iscritto il: 20/11/11 21:22

Sponsor
 

Re: [Excel 2019]: somma.più.se insieme ad E

Postdi klingklang » 24/05/19 06:14

Ciao, prova a cambiare E con O (l'espressione deve restituire VERO e se usi E non lo farà mai, visto che una cella non può avere valore "Sì" *E* valore "Dubbia" allo stesso tempo). Inoltre devi togliere il segno =
Insomma verrebbe:

=SOMMA.PIÙ.SE(Master!$BZ$2:$BZ$300;O(Master!$B$2:$B$300;"Si";Master!$B$2:$B$300;"Dubbia");Master!$P$2:$P$300;"Si")/CONTA.PIÙ.SE(Master!$B$2:$B$300;"Si";Master!$P$2:$P$300;"Si")
Avatar utente
klingklang
Utente Junior
 
Post: 97
Iscritto il: 23/11/18 15:01
Località: San Giovanni in Persiceto

Re: [Excel 2019]: somma.più.se insieme ad E

Postdi karug64 » 25/05/19 00:11

klingklang ha scritto:Ciao, prova a cambiare E con O (l'espressione deve restituire VERO e se usi E non lo farà mai, visto che una cella non può avere valore "Sì" *E* valore "Dubbia" allo stesso tempo). Inoltre devi togliere il segno =
Insomma verrebbe:

=SOMMA.PIÙ.SE(Master!$BZ$2:$BZ$300;O(Master!$B$2:$B$300;"Si";Master!$B$2:$B$300;"Dubbia");Master!$P$2:$P$300;"Si")/CONTA.PIÙ.SE(Master!$B$2:$B$300;"Si";Master!$P$2:$P$300;"Si")


Grazie per la risposta, ma la formula da un errore alla conferma nella cella:
"Per la funzione sono stati immessi insufficienti argomenti"

Grazie
Office 2010
karug64
Utente Senior
 
Post: 746
Iscritto il: 20/11/11 21:22

Re: [Excel 2019]: somma.più.se insieme ad E

Postdi Anthony47 » 25/05/19 00:50

La funzione Somma.Più.Se consente di inserire tanti criteri che devono essere tutti rispettati affinche' quel record sia Sommato.
Quindi puoi fare la funzione E (come avevi scritto) semplicemente mettendo due criteri; tipo:
Codice: Seleziona tutto
=SOMMA.PIÙ.SE(A1:A100;B1:B100;"Si";C1:C100;"Luca")

Sommi solo se in colonna B c'e' "Si" E in col C c'e' "Luca"

Se invece vuoi ad esempio sommare con B=Si e C=Luca oppure Giulia allora devi usare qualcosa tipo
Codice: Seleziona tutto
=SOMMA.PIÙ.SE(A:A1100;B1:B100;"Si";C1:C100;"Luca")+SOMMA.PIÙ.SE(A1:A100;B1:B100;"Si";C1:C100;"Giulia")


Oppure vai su (ad esempio) Matr.Somma.Prodotto; tipo:
Codice: Seleziona tutto
=MATR.SOMMA.PRODOTTO(A1:A100;--(B1:B100="Si");--((C1:C100="Luca")+(C1:C100="Giulia")))


Formule dimostrative, da adattare alla tua applicazione.

Ciao
Avatar utente
Anthony47
Moderatore
 
Post: 19196
Iscritto il: 21/03/06 16:03
Località: Ivrea

Re: [Excel 2019]: somma.più.se insieme ad E

Postdi klingklang » 25/05/19 00:56

karug64 ha scritto:
klingklang ha scritto:Ciao, prova a cambiare E con O (l'espressione deve restituire VERO e se usi E non lo farà mai, visto che una cella non può avere valore "Sì" *E* valore "Dubbia" allo stesso tempo). Inoltre devi togliere il segno =
Insomma verrebbe:

=SOMMA.PIÙ.SE(Master!$BZ$2:$BZ$300;O(Master!$B$2:$B$300;"Si";Master!$B$2:$B$300;"Dubbia");Master!$P$2:$P$300;"Si")/CONTA.PIÙ.SE(Master!$B$2:$B$300;"Si";Master!$P$2:$P$300;"Si")


Grazie per la risposta, ma la formula da un errore alla conferma nella cella:
"Per la funzione sono stati immessi insufficienti argomenti"

Grazie

Ti chiedo scusa, l'ho scritta da smartphone e anche senza rifletterci su, a quanto pare. Segui i consigli di Anthony. Ciao
Avatar utente
klingklang
Utente Junior
 
Post: 97
Iscritto il: 23/11/18 15:01
Località: San Giovanni in Persiceto

Re: [Excel 2019]: somma.più.se insieme ad E

Postdi karug64 » 25/05/19 08:09

Anthony47 ha scritto:La funzione Somma.Più.Se consente di inserire tanti criteri che devono essere tutti rispettati affinche' quel record sia Sommato.
Quindi puoi fare la funzione E (come avevi scritto) semplicemente mettendo due criteri; tipo:
Codice: Seleziona tutto
=SOMMA.PIÙ.SE(A1:A100;B1:B100;"Si";C1:C100;"Luca")

Sommi solo se in colonna B c'e' "Si" E in col C c'e' "Luca"

Se invece vuoi ad esempio sommare con B=Si e C=Luca oppure Giulia allora devi usare qualcosa tipo
Codice: Seleziona tutto
=SOMMA.PIÙ.SE(A:A1100;B1:B100;"Si";C1:C100;"Luca")+SOMMA.PIÙ.SE(A1:A100;B1:B100;"Si";C1:C100;"Giulia")


Oppure vai su (ad esempio) Matr.Somma.Prodotto; tipo:
Codice: Seleziona tutto
=MATR.SOMMA.PRODOTTO(A1:A100;--(B1:B100="Si");--((C1:C100="Luca")+(C1:C100="Giulia")))


Formule dimostrative, da adattare alla tua applicazione.

Ciao


Ciao Anthony.
Intanto grazie per la spiegazione.

Il problema che ho io è che nella colonna "C" (per esempio) ho 5 valori (A,B,C,D,E). Avrei necessità di adattare le formule del somma-più.se al fatto che nella "C" ci sia il valore "A" O "D".
Immagino, quindi, secondo la tua spiegazione, che questo la somma.più.se non lo faccia.

Unica soluzione, quindi, è creare due totali (uno per i valori "A" e uno per i valori "D") e poi sommarli .....

Grazie ancora.
Office 2010
karug64
Utente Senior
 
Post: 746
Iscritto il: 20/11/11 21:22

Re: [Excel 2019]: somma.più.se insieme ad E

Postdi Anthony47 » 25/05/19 13:48

Unica soluzione, quindi, è creare due totali (uno per i valori "A" e uno per i valori "D") e poi sommarli .....
Forse non "l'unica", ma secondo me la piu' semplice da realizzare.

Una possibile alternativa e' l'uso di una matrice di costanti; tipo (invece che =SOMMA.PIÙ.SE(A:A1100;B1:B100;"Si";C1:C100;"Luca")+SOMMA.PIÙ.SE(A1:A100;B1:B100;"Si";C1:C100;"Giulia"):
Codice: Seleziona tutto
=SOMMA(SOMMA.PIÙ.SE(A1:A100;B1:B100;"Si";C1:C100;{"Luca"."Giulia"}))

Ciao
Avatar utente
Anthony47
Moderatore
 
Post: 19196
Iscritto il: 21/03/06 16:03
Località: Ivrea

Re: [Excel 2019]: somma.più.se insieme ad E

Postdi karug64 » 25/05/19 21:05

Matrice di costanti ....

:eeh: :eeh: :eeh: :eeh: :eeh: :eeh: :eeh: :eeh:

Non si finisce mai di imparare . Grazie
Office 2010
karug64
Utente Senior
 
Post: 746
Iscritto il: 20/11/11 21:22

Re: [Excel 2019]: somma.più.se insieme ad E

Postdi Anthony47 » 26/05/19 16:53

Matrice di costanti ....
Non si finisce mai di imparare


Forse siamo abituati a vederla nella formulazione classica
Codice: Seleziona tutto
=SOMMA(SOMMA.PIÙ.SE(A1:A100;B1:B100;"Si";C1:C100;D1:D5))
(con in D1:D5 l'elenco dei nominativi)

Anzi, rispetto alla formulazione {"Luca"."Giulia"}, la "classica" e' piu' semplice perche' (a) in alcune tastiere non si riesce a trovare al volo le parentesi graffe, (b) perche' il separatore di costanti in alcune versioni e' "punto", in altre e' "\" in altre e' "virgola" quindi spesso non ci si capisce con l'utente, e (c) perche' e' piu' facile aggiungere /togliere /modificare i valori.
Piccola facilitazione e' che l'uso di {"Luca"."Giulia"} evita il Contr-Maiusc-Enter, perche' la formula e' implicitamente a matrice.

Insomma, "nuovo ma non troppo"...
Avatar utente
Anthony47
Moderatore
 
Post: 19196
Iscritto il: 21/03/06 16:03
Località: Ivrea

Re: [Excel 2019]: somma.più.se insieme ad E

Postdi karug64 » 26/05/19 17:24

Grazie per la spiegazione. Alla prossima
Office 2010
karug64
Utente Senior
 
Post: 746
Iscritto il: 20/11/11 21:22


Torna a Applicazioni Office Windows


Topic correlati a "[Excel 2019]: somma.più.se insieme ad E":


Chi c’è in linea

Visitano il forum: Nessuno e 28 ospiti