Condividi:        

scadenzario excel

Vuoi potenziare i tuoi documenti Word? Non sai come si fa una macro in Excel? Devi creare una presentazione in PowerPoint?
Oppure sei passato a OpenOffice e non sei sicuro di come lavorare al meglio?

Moderatori: Anthony47, Flash30005

scadenzario excel

Postdi luigi58 » 15/11/18 23:58

Buongiorno a tutti. mi chiamo luigi e sono nuovo del forum, non so se è la sezione giusta ma spero di si.
Innanzi tutto comincio con il ringraziare tutti coloro che vorranno aiutarmi e dedicarmi il loro tempo, Grazie.!
Premetto che ho cercato ovunque nel web, molti si avvicinano ma nessuno, che io abbia trovato, risolve il mio problema.

Vengo subito al mio problema,
ho creato una semplice lista clienti in OFFICE EXCEL così composta:

Nome - Cognome - tel - e-mail - data contratto - scadenza contratto - data odierna - giorni mancanti alla scadenza

e fino a quì nessun problema, ecco io vorrei fare in modo che quando la cella del conto alla rovescia "giorni mancanti" di ogni cliente segna il n° 15 (15 gg. alla scadenza) gli venisse inviata una e-mail di notifica in automatico.
Oppure, in alternativa, per ogni cliente che, come sopra, mancano 15 gg alla scadenza viene inviata in automatico una e-mail di notifica al mio indirizzo di posta elettronica o un sms o anche una notifica sul cellulare.
Qualsiasi modo possa avvertire il cliente oppure me o entrambi (meglio) che mancano 15 gg. alla scadenza del contratto.

Spero possiate aiutarmi, complimenti per il forum e tutti quelli che lo sostengono veramente bravi Grazie.!
luigi58
Windows 7 Ultimate, Office Professional plus 2016.
luigi58
Newbie
 
Post: 4
Iscritto il: 15/11/18 22:29

Sponsor
 

Re: scadenzario excel

Postdi Anthony47 » 16/11/18 20:53

Ciao Luigi, benvenuto nel forum.

Supponendo che tu utilizzi Outlook come client di posta elettronica, ho elaborato una delle tante macro di Invio Email ti propongo questa versione:
Codice: Seleziona tutto
Sub InvioemailB811()
'Vedi http://www.pc-facile.com/forum/viewtopic.php?f=26&t=110177
''Vedi http://www.pc-facile.com/forum/viewtopic.php?f=26&t=105944
''Vedi http://www.pc-facile.com/forum/viewtopic.php?f=26&t=104487
'
Dim OutApp As Object, OutMail As Object
Dim EmailAddr As String, Subj As String, myShips, Ship
Dim CScad As String, cFree As String, wDays As Long
Dim BDT As String, I As Long, myCnt As Long                      'FIN QUI SONO "DICHIARAZIONI"
'  (a)
'Parametri
CScad = "M"                                 '<<< La colonna con le date di Scadenza
cFree = "Z"                                 '<<< Una colonna LIBERA
wDays = 15                                  '<<< I giorni di preavviso desiderati
myShips = Array("Foglio1", "Foglio2")       '<<< Elenco dei fogli da esaminare
'
BDT = "Alert per Contratto in scadenza al " & Format(Date, "yyyy-mmm-dd") & vbCrLf
'Si crea una sessione Outlook
Set OutApp = CreateObject("Outlook.Application")
For Each Ship In myShips
    Sheets(Ship).Select
    For I = 2 To Cells(Rows.Count, CScad).End(xlUp).Row
        If Cells(I, CScad) < (Date + wDays) Then
            If Cells(I, cFree) + 7 < Date Then
                Cells(I, cFree).Value = Date
                'Si compila il testo della mail
                BDT = BDT & Cells(I, "A").Value & " " & Cells(I, "B").Value & _
                    " - Scadenza: " & Format(Cells(I, CScad).Value, "dd-mmm-yyyy") & vbCrLf
                myCnt = myCnt + 1
                BDT = BDT & "La tua macro"
                '
                'DA QUI SI CREA E INVIA LA MAIL:
                EmailAddr = "TuaEmail@Dominio.ppp"                      '<<< TUO INDIRIZZO EMAIL
                Subj = "Prossime Scadenze al " & Format(Date, "yyyy-mmm-dd") & " - " & myCnt    '<<< OGGETTO DELLA MAIL
                Set OutMail = OutApp.CreateItem(0)
                With OutMail
                    .To = EmailAddr
'                    .CC = Cells(I, "D")                                 '<<< In Copia al Cliente?? Colonna D???
'                    .BCC = ""
                    .Subject = Subj
                    .Body = BDT
                    '.Display 'or use .send
                    .send
                End With
                '  (c)
                Application.Wait (Now + TimeValue("0:00:01"))
                Set OutMail = Nothing
            End If
        End If
    Next I
Next Ship
'  (d)  Chiudi Outlook
Set OutApp = Nothing
If myCnt > 0 Then
    MsgBox ("Prossime scadenze: " & myCnt)
Else
    MsgBox ("Nessuna prossima scadenza rilevata...")
End If
'
End Sub


Il codice va inserito in un "Modulo standard" del vba:
-dal tuo foglio excel, premi Alt-F11 per aprire l' editor delle macro
-Menu /Inserisci /Modulo
-copia il codice e inseriscilo nel frame di dx
Le istruzioni marcate <<< vanno personalizzate come da commento sulla linea.

Non conoscendo il layout dei tuoi dati ho inventato io quali vanno prese in considerazione; le eventuali variazioni sono da fare nelle righe marcate <<<

La macro prevede che si possa lavorare anche su piu' Fogli (ad esempio per un Agente che gestisce piu' Compagnie), e richiede l'uso di una colonna LIBERA che sara' utilizzata per marcare la data di prima segnalazione, cioe' invio della prima email; se dopo 7 giorni la scadenza non e' stata ancora aggiornata allora sara' inviata una ulteriore email, e cosi' ogni 7 giorni.

La macro prevede l'invio al tuo indirizzo email, ma e' gia' predisposta per l'invio in copia al Cliente; basterebbe eliminare l' Apostrofo in tesa alla riga .CC = Cells(I, "D").
Ma mi permetto di suggerire che l'email al cliente la inoltri tu dopo aver verificato la correttezza di quanto segnalato. Vedi tu.

Se non usi Outlook allora si puo' cercare qualche altro metodo, ma meno automatizzato.

Prova e fai sapere
Avatar utente
Anthony47
Moderatore
 
Post: 19196
Iscritto il: 21/03/06 16:03
Località: Ivrea

Re: scadenzario excel

Postdi luigi58 » 17/11/18 21:35

Ciao Antony, Grazie per la tua disponibilità, provo ad eleborare il tuo codice e ti faccio sapere. A prima vista mi sembra (finalmente) quello giusto.
Per completezza, ti confermo che uso Outlook.
luigi58
Windows 7 Ultimate, Office Professional plus 2016.
luigi58
Newbie
 
Post: 4
Iscritto il: 15/11/18 22:29

Re: scadenzario excel

Postdi luigi58 » 24/11/18 19:55

Ciao Antony, scusate il ritardo ma ero fuori a lavorare.
Ho provato il tuo suggerimento ma purtroppo mi sono dovuto fermare subito
perchè quando devo aggiungere il riferimento ad outlook (Strumenti-Riferimenti-spunta Microsoft Outlook)
appena clikko su Strumenti-Riferimenti mi da questo messaggio di errore: "Errore di accesso al registro di configurazione di sistema". E sono praticamente fermo li. Se avete suggerimenti vi ringrazio.
luigi58
Windows 7 Ultimate, Office Professional plus 2016.
luigi58
Newbie
 
Post: 4
Iscritto il: 15/11/18 22:29

Re: scadenzario excel

Postdi Anthony47 » 24/11/18 21:14

La macro non richiede il riferimento alla libreria Outlook.
Ovviamente devi avere Outlook come software per la gestione delle email, ma questo l'avevi gia' confermato.
Non conosco il significato di quell'errore...
Avatar utente
Anthony47
Moderatore
 
Post: 19196
Iscritto il: 21/03/06 16:03
Località: Ivrea

Re: scadenzario excel

Postdi luigi58 » 24/11/18 21:34

Ciao Antony, Ho appena testato il programmino e funziona, Grazie per l' aiuto.
Volevo solo un chiarimento, devo sempre eseguire il modulo ogni volta che apro excel per farlo funzionare oppure avviando excel va in autoesecuzione? Grazie ancora e complimenti siete veramente bravi. ;)
luigi58
Windows 7 Ultimate, Office Professional plus 2016.
luigi58
Newbie
 
Post: 4
Iscritto il: 15/11/18 22:29

Re: scadenzario excel

Postdi Anthony47 » 25/11/18 12:37

La macro "spara" un tot di email, preferisco che sia tu a decidere quando farlo.
Puoi avviarla partendo da Alt-F8 (poi scegli InvioemailB811 dall'elenco di macro disponibili e premi Esegui); oppure tramite un Pulsante a cui associ la macro InvioemailB811.

Comunque se vuoi attivare il processo tutte le volte che apri il file devi inserire una macro di Workbook_Open nel modulo QuestaCartellaDiLavoro e inserirvi l'istruzione Call InvioemailB811

Se lo sai fare allora saprai anche garantire che non partano mail a caso.

Ciao
Avatar utente
Anthony47
Moderatore
 
Post: 19196
Iscritto il: 21/03/06 16:03
Località: Ivrea


Torna a Applicazioni Office Windows


Topic correlati a "scadenzario excel":


Chi c’è in linea

Visitano il forum: Nessuno e 91 ospiti