[excel] subtotale con condizioni

[marcoc]

buongiorno a tutti,
avrei bisogno di una formula che combini il subtotale con il somma.se, da inserire nelle celle in giallo del file in
http://www.filedropper.com/subtotaleconcondizioni
e che mi dia i valori di quanto mostrato filtrando ad esempio "0" in colonna D.
Sapete aiutarmi?

[Anthony47]

Perdona, non ho capito quali dati andrebbero presi in considerazione e quale somma calcolare; puoi descrivere nuovamente, sia per le celle gialle di colonna C che di colonna D?

[marcoc]

ok.
nella riga 2 ho delle formule che mi sommano i valori delle colonne C e D se nella colonna A è presente "#N/D".
nella riga 3, stessa cosa se non è presente "#N/D", ovvero se è presente una lettera (nel mio caso specifico il nome di un venditore).
Se io filtro lo zero nella colonna D (ovvero dove nel mio caso non c'é fatturato after sales) vorrei vedere nelle celle in giallo, ciò che mi mostrerebbe un generico subtotale, ovvero per 1.001.897 (C2), 4.048.135 (C3) e zero (D2 e D3).
Poichè ci sono le condizioni uguale/diverso da "#N/D", non so come impostare la formula che mi serve, che appunto dovrebbe combinare il somma.se con il subtotale.

[Anthony47]

Capito, parli della Funzione Subtotale non del comando Subtotale...
Purtroppo la funzione Subtotale non puo' essere usata in forma di matrice, quindi bisogna usare un qualche trucco per individuare se una riga e' filtrata o no.
Ad esempio potresti usare, in C2

Codice: Seleziona tutto

=SOMMA((C$6:C$25)*(SUBTOTALE(2;SCARTO($C$5;1;0;RIF.RIGA(INDIRETTO("1:"&RIGHE($C$6:$C$25)));1))>SUBTOTALE(2;SCARTO($C$5;0;0;RIF.RIGA(INDIRETTO("1:"&RIGHE($C$6:$C$25)));1)))*(SE.ERRORE(($A$6:$A$25="#N/D");1)))


Da confermare con Contr-Maiusc-Enter, non il solo Enter
Poi copia C2 in D2
La formula per C3 e' la stessa a parte la componente ="#N/D" che deve diventare <>"#N/D"

Per agevolarti ad adattare la formula ai tuoi dati, ecco il significato dei vari spezzoni di formula

Codice: Seleziona tutto

=SOMMA(       'Fa la somma degli addendi successivi
(C$6:C$25)    'Sono i valori della colonna C
(SUBTOTALE(2;SCARTO($C$5;1;0;RIF.RIGA(INDIRETTO("1:"&RIGHE($C$6:$C$25)));1))>SUBTOTALE(2;SCARTO($C$5;0;0;RIF.RIGA(INDIRETTO("1:"&RIGHE($C$6:$C$25)));1)))                             'Questa parte serve per identificare se una riga e' nascosta (dal filtro) o no
(SE.ERRORE(($A$6:$A$25="#N/D");1)))        'Questa parte controlla il contenuto di colonna A

Ciao, fai sapere...

[marcoc]

Non mi torna la riga 3; mettendo il "<>#N/D" mi riporta il subtotale "classico".
Poco male comunque poiché avendo già il subtotale "classico" in C1, posso utilizzare la formula che mi hai detto nella C2, e mettere la differenza tra i due in C3 (e idem poer la colonna D).

grazie mille come sempre

[marcoc]

se invece della somma volessi mettere il conta valori, come diventerebbe la formula?
ho visto che non basta sostituire "somma" con "conta"...

[marcoc]

ho applicato la formula al mio file che contiene più colonne della versione semplificata che ho caricato.
vedo che la formula comprende spesso "$C$", ma se io la estendo ad esempio fino alla colonna Z, mi fa correttamente "il subtotale con condizione" di ogni colonna, qualsiasi colonna filtri.
Mi confermi che rimane solamente la col.A quella "discriminante" per la condizione?

[Anthony47]

Non mi torna la riga 3; mettendo il "<>#N/D" mi riporta il subtotale "classico".

Infatti non bisogna fare solo quella modifica:
invece di ="#N/D");1
mettere <>"#N/D");0

Per l'eventuale Conta, va semplicemente eliminato dalle formule la componente (C$6:C$25)*

Ciao

[marcoc]

perfetto, ho modificato e funziona.
mi confermi il post delle 15:17?

[Anthony47]

vedo che la formula comprende spesso "$C$", ma se io la estendo ad esempio fino alla colonna Z, mi fa correttamente "il subtotale con condizione" di ogni colonna, qualsiasi colonna filtri.
Mi confermi che rimane solamente la col.A quella "discriminante" per la condizione?

Nella formula la parte RIGHE($C$6:$C$25) serve solo a contare quante righe devono essere esaminate, le colonne sono indifferenti.
La colonna con la condizione e' la A; i dati da sommare sono rappresentati da (C$6:C$25), che si adattano in quanto a colonna se copi la formula nelle colonne adiacenti

Ciao

[marcoc]

ok, grazie mille.