MACRO duplica righe

[centaine]

Ciao a tutti,
ho un foglio xls con una serie di colonne e righe ( il numero delle colonne è fisso ma quello delle righe è sempre diverso) e avrei bisogno di duplicare ogni riga copiando esattamente la precedente tranne che nella colonna C dove va inserita una parola specifica.
Ho provato a cercare tra le soluzioni già esistenti ma purtroppo per me è incomprensibile!
Grazie a chi mi aiuterà!

[Anthony47]

Per capire cosa suggerire:
-parliamo di 100 o di 10mila righe?
-visto che le colonne sono fisse, quali sono?
-la parola specifica per colonna C e' fissa e nota (quale?); fissa ma da indicare quando si duplicano le righe; variabile riga per riga con una regola nota (quale) / senza regola?
-le righe contengono solo valori, o anche formule?
-vanno duplicati i contenuti delle celle o anche le formattazioni?

Ciao

[centaine]

Le righe non saranno sempre lo stesso numero ma decisamente intorno alle 100 e non 10mila.
Le colonne sono fisse da A a H, la prima riga contiene intestazioni di colonna.
La parola da variare è fissa e nota: la colonna C contiene sempre in tutte le righe la parola GEN e nelle altre colonne valori variabili, la riga da duplicare sarà identica nelle altre colonne ma al posto di GEN deve contenere PAR.
Le righe contengono solo valori digitati, nessuna formula, nessuna formattazione particolare.
Praticamente a mano dovrei fare seleziona riga, copia, inserisci celle copiate, e digitare PAR in colonna C al posto di GEN, e ripetere questo per ogni riga presente nel file...
grazie mille!

[Anthony47]

Sulla base di quel che ho capito prova questa macro:

Codice: Seleziona tutto

Sub ReplicaR()
Dim oArr(), I As Long, J As Long, lastC As Long
Dim myC As String, K As Long
'
myC = "A:H"     '<<< Le colonne da duplicare (deve partire a A)
'
lastC = Cells(Rows.Count, "C").End(xlUp).Row
ReDim oArr(1 To (lastC - 1) * 2, 1 To Range(myC).Columns.Count)
For I = 2 To lastC
    K = (I - 2) * 2 + 1
    For J = 1 To Range(myC).Columns.Count
        oArr(K, J) = Cells(I, J)
        oArr(K + 1, J) = oArr(K, J)
    Next J
    oArr(K + 1, 3) = "PAR"
Next I
Range("A2").Resize(UBound(oArr), UBound(oArr, 2)).Value = oArr
End Sub


Va messa in un "modulo standard" dell'editor delle macro; per questo, partendo da Excel:
-premi Alt-F11 per aprire l'editor delle macro
-Menu /Inserisci /Modulo
-Copia il codice e incollalo nel frame dx del modulo appena creato
Personalizza eventualmente la riga marcata <<< come da commento.

Poi torna su Excel e quando hai i dati iniziali pronti lancia la macro ReplicaR:
-premi Alt-F8
-seleziona ReplicaR dall'elenco di macro disponibili
-premi Esegui

Fai sapere...

[centaine]

Funziona perfettamente!
Non so davvero come ringraziarti, mi è di enorme utilità!
Grazie grazie grazie infinite!!!