ritardo di 6 numeri

[raimea]

ciao
ho una serie di numeri da 1 al 6
sono scritti in una tabella da E6 a G100
il piu recente e' scritto in basso nella riga piu alta

vorrei calcolare il ritardo attuale di ogni numero
e riportarlo in colonna L6
mentre in colonna N6 mettere dal piu in ritado al piu recente

vi allego il file
https://www.dropbox.com/s/bxpb0vjq6veb08n/6_numeri.rar?dl=0

ciao

[Anthony47]

A) Per il calcolo dei ritardi, in L6

Codice: Seleziona tutto

=SE.ERRORE(GRANDE(SE($E$6:$G$100=K6;RIF.RIGA($E$6:$E$100);"");1)-GRANDE(SE($E$6:$G$100=K6;RIF.RIGA($E$6:$E$100);"");2);"")

da confermare con Contr-Maiusc-Enter, non il solo Enter
Poi copia verso il basso

B) Per il calcolo in ordine di ritardo decrescente
1) in P6 calcoliamo il ritardo con

Codice: Seleziona tutto

=GRANDE($L$6:$L$11-$K$6:$K$11/100;RIF.RIGA(A1))

Sempre Contr-Maiusc-Enter; formatta come "numero senza decimali" e poi copia verso il basso
2) in Q6 calcoliamo il Numero con

Codice: Seleziona tutto

=(1-RESTO(P6;1))*100

Copia verso il basso

Ciao

[raimea]

ciao




non corriapondono i calcoli

il numero 1 ha un ritardo di 0
perche ' c'e' nell'ultima riga (R13)

idem per il num 6 e 5

il num 2,3,4 hanno un ritardo di 1

il controllo non deve essere solo sulla stessa colonna
ma nel range E6:G100

allego il file con le formule inserite
https://www.dropbox.com/s/5ddm5x9znsd7nvp/6_numeri.rar?dl=0

[Anthony47]

Eh eh, e' che proprio non avevo afferrato il concetto di "ritardo attuale"...
La formula in L6:

Codice: Seleziona tutto

=SE.ERRORE(GRANDE(SE($E$6:$G$100<>"";RIF.RIGA($E$6:$E$100);"");1)-GRANDE(SE($E$6:$G$100=K6;RIF.RIGA($E$6:$E$100);"");1);"")

Tutto il resto come prima.

Ciao

[raimea]

ciao

ora tutto ok
faccio altri test

grazie

[raimea]

ciao
un piccolo bug:



le formule in col da Q6 e R6

Q6

Codice: Seleziona tutto

=(1-RESTO(R6;1))*100

R6

Codice: Seleziona tutto

=GRANDE($L$6:$L$11-$K$6:$K$11/100;RIF.RIGA(A1))

non danno dei risultati fino a quando non sono stati scritti
almeno 1na volta tutti i 6 numeri

e' possibile avere numeri gia' dopo aver inserito
una solo serie di 3 numeri ?
( cioe' dopo aver compilato riga6 )

ciao

[raimea]

.

[Anthony47]

Se vuoi ignorare i numeri mai presenti, prova in P6 e Q6 rispettivamente

Codice: Seleziona tutto

=SE(GRANDE(SE($L$6:$L$11<>"";$L$6:$L$11;-1)-$K$6:$K$11/100;RIF.RIGA(A1))>-1;GRANDE(SE($L$6:$L$11<>"";$L$6:$L$11;-1)-$K$6:$K$11/100;RIF.RIGA(A1));"")

=SE.ERRORE((1-RESTO(P6;1))*100;"")

La prima e' "a matrice"

Se invece vuoi assegnare ai numeri non ancora presenti il ritardo max (pari al numero di righe popolate nell'elenco) allora modifica in L6 e sottostanti:

Codice: Seleziona tutto

=SE.ERRORE(GRANDE(SE($E$6:$G$100<>"";RIF.RIGA($E$6:$E$100);"");1)-GRANDE(SE($E$6:$G$100=K6;RIF.RIGA($E$6:$E$100);"");1);CONTA.NUMERI($E$6:$E$100))

Ciao

[raimea]

bene
ho optato per questa

Codice: Seleziona tutto

=SE.ERRORE(GRANDE(SE($E$6:$G$100<>"";RIF.RIGA($E$6:$E$100);"");1)-GRANDE(SE($E$6:$G$100=K6;RIF.RIGA($E$6:$E$100);"");1);CONTA.NUMERI($E$6:$E$100))

faccio altri test

grazie