Matrice da trasformare in 2 colonne - Excel 2013

[femon]

Salve, ho una matrice fatta in questo modo:
A 1 2 3 4 5 6 ....
B 7 8 9 10 11 12 ....
C 13 14 15 16 17 18 ...
ecc...
vorrei che il tutto diventasse su 2 colonne:
A 1
A 2
A 3
A 4
A 5
A 6
B 7
B 8
B 9
B 10
B 11
B 12
C 13
C 14
......ecc.
C'è un modo per farlo velocemente?
Grazie.
Federico.
P.S. la matrice avrà circa 20 colonne x 100 righe

[Anthony47]

Dalla descrizione non ho capito se ti basta un "Trasponi":
-seleziona i dati di partenza e copiali
-seleziona la prima cella di destinazione
-Incolla speciale /Valori, e come operazione spunti Trasponi; Ok

Se non e' cosi' allora spiega meglio allegando delle immagini dei dati di partenza e di arrivo, o anche un file dimostrativo; per le istruzioni su come allegare un file o una immagine1:
viewtopic.php?f=26&t=103893

Ciao

[femon]

Ciao Anthony47, grazie per la risposta,
la funzione trasponi però non mi va bene, in quanto mi "gira" la matrice, ma in realtà la prima colonna della tabella originale che contiene la lettera "A" poi "B" poi "C" ecc. dovrà ripetersi più volte (e dunque in più righe nella prima colonna) ed associarsi in una seconda colonna per tutti i valori che aveva alla sua dx in origine.

Per esempio la lettera "A" verrà ricopiata nella prima colonna per ben 6 volte (dunque per 6 righe) e nella seconda colonna avrà per ogni riga il valore 1 poi il valore 2 poi il 3 ecc. fino alla sesta riga che avrà il valore 6.
Poi inizierà la lettera B nella prima colonna anche questa per 6 volte con associati i valori dal 7 al 12 (ma potrebbero essere anche altri valori) ecc. fino al termine della tabella.

Fammi sapere se sono stato un pò confuso che proverò ad allegarti un file di prova.

Grazie.
Federico.

[CANAPONE]

Ciao,

con le formule avrei bisogno di una colonna di servizio: uso il range A2:A100

Le lettere sono in b2:b100, i numeri in c2:z100

In A2

Codice: Seleziona tutto

=CONTA.VALORI(C$2:Z2)

e copio la formula accanto alle lettere

Questa colonna di servizio la puoi anche sviluppare a sinistra del tuo database: nel caso poi adatta le formule.


In AB2 copio in basso

Codice: Seleziona tutto

=SE.ERRORE(INDICE(B$2:B$100;CONFRONTA(AGGREGA(15;6;A$2:A$100/(A$2:A$100>=RIGHE(A$1:A1));1);A$2:A$100;0));"")

In AC2 per ottenere i numeri

Codice: Seleziona tutto

=SE.ERRORE(INDICE(C$2:Z$100;CONFRONTA(AB2;B$2:B$100;0);CONTA.SE(AB$2:AB2;AB2));"")

Saluti

[CANAPONE]

Ciao,

una piccola precisazione: se la tabella contenesse lo stesso numero di numeri (scusa la quasi alliterazione) per riga, la colonna d'appoggio non serve, basta usare delle combinazioni ricorsive di rif.riga().

Non credo sia il tuo caso.


Saluti

[femon]

Perfetto!!!!!! Canapone,
ho provato il tutto e funziona perfettamente.
Mi hai risparmiato un bel po' di tempo.
Grazie mille!!!!
Federico.

[CANAPONE]

Ciao,

grazie del riscontro.

Si può fare anche senza colonna di servizio. Se servisse

Avrei solo bisogno di sapere il range occupato dai dati: esempio A2:Z1000, nella colonna A le lettere.

Ripeto, solo se ti fosse di qualche utilità.

[femon]

Ma guarda,
la tabella non è proprio precisa, ci sono righe con un numero di dati diverso dalle altre righe e dunque la soluzione che mi hai proposto con la colonna di appoggio mi sembra comunque comoda e funzionale.
Ora proverò a "studiarmi" le formule che mi hai dato.... ma non so quanto ne capirò..
Comunque GRAZIE ancora.
Federico.

[CANAPONE]

Ciao,


condivido anche la formula che avevo fatto una settimana fa.

Non ha bisogno della colonna di servizio, legge le righe di ampiezza irregolare sino a 10 numeri (basta modificare colonne(B:K) e scrivere - esempio- 15 se dovremo leggere da 1 a 15 numeri

Codice: Seleziona tutto

=SE.ERRORE(INDICE($A$2:$A$1000;CONFRONTA(AGGREGA(15;6;SUBTOTALE(2;SCARTO($B$2;;;RIF.RIGA($A$2:$A$1000)-1;COLONNE($B:$K)))/(SUBTOTALE(2;SCARTO($B$2;;;RIF.RIGA($A$2:$A$1000)-1;COLONNE($B:$K)))>=RIGHE(A$1:A1));1);INDICE(SUBTOTALE(2;SCARTO($B$2;;;RIF.RIGA($A$2:$A$1000)-1;COLONNE(B:K))););0));"")

Se servisse