somma se e giorno.settimana

[ramset1978]

E' possibile sommare dei risultati in base la giorno della settimana utilizzando la funziona somma.se?

es. somma.se(giorno.settimana(data);risultato) dove data è la colonna delle date e risultato è il numero associato a quella data.

Vorrei evitare la funzione MATR.SOMMA.PRODOTTO perchè rallenta molto il file.

[CANAPONE]

Ciao,

credo tu debba usare matr.somma.prodotto specificando gli intervalli che vuoi elaborare

=MATR.SOMMA.PRODOTTO((GIORNO.SETTIMANA(A2:A100)=7)*(A2:A100<>"")*B2:B100)

Lasciando la formula così - esempio- rallenti parecchio la velocità di calcolo

=MATR.SOMMA.PRODOTTO((GIORNO.SETTIMANA(A:A)=7)*(A:A<>"")*B:B)

Saluti

[ramset1978]

Rallenta comunque i calcoli... quindi mi pare di capire che le funzione SOMMA.SE e GIORNO.SETTIMANA non siano utilizzabili insieme, è corretto?

[CANAPONE]

Ciao,

se vuoi usare giorno.settimana non lo puoi fare con il somma.se.Il somma.se non accetta matrici di risultati da elaborare.

matr.somma prodotto sì.


Forse non ho capito bene.

[ramset1978]

Ciao,

se vuoi usare giorno.settimana non lo puoi fare con il somma.se.

Forse non ho capito bene.

Hai capito bene e dalla tua risposta si evince che le due funzioni non sono utilizzabili insieme. Grazie.

[CANAPONE]

Ciao,

stavo cercando un articolo che confrontava la velocità di somma.se (o somma.più.se) e matr.somma.prodotto

L'argomento è diventato interessante quando matr.somma.prodotto ha accettato di elaborare anche intere colonne

=matr.somma.prodotto(--(a:a="pippo");(b:b))

Matr.somma.prodotto non restituisce più errore usando Excel 2007 ( o 2010 non ricordo ) , però elabora tutte le 2^20 righe, anche se i dati da elaborare sono solo nelle prime 50 righe.


Se ritrovo il link dove vengono paragonate le velocità di elaborazione lo metto in condivisione: credo di averlo nel pc in ufficio.

Saluti

[ramset1978]

Ok grazie, ciao.

[Anthony47]

Ho testato formule del tipo

Codice: Seleziona tutto

1:  =SOMMA(SE(GIORNO.SETTIMANA(A2:A100;2)=1;B2:B100;""))
2: =MATR.SOMMA.PRODOTTO(--(GIORNO.SETTIMANA(A2:A100;2)=1);B2:B100)
3: =MATR.SOMMA.PRODOTTO(--(GIORNO.SETTIMANA(A1:A100;2)=1);B1:B100)
4: =SOMMA((GIORNO.SETTIMANA(A2:A100;2)=1)*(B2:B100))

Le formule hanno tempi di esecuzione confrontabile (+/-1%)
Ho allungato l'intervallo fino a 1000; il tempo unitario aumenta di circa 10%, tempi di esecuzione confrontabile (+/-1%)
Ho allungato fino a 10mila: tempo unitario raddoppia, leggera prevalenza della formula 3 (-5%).
Ho allungato fino a 100mila: tempo unitario quintuplica, leggera prevalenza delle formule 2 e 3 (-5%)
Ho allungato fino a inserire l'intera colonna: tempo unitario decuplica, leggera prevalenza della formula 3 (-10%)
Insomma, in tutte le situazioni un riferimento all'intera colonna e' penalizzante, e i tempi di esecuzione sono dipendenti dall'intervallo specificato.

La 1 e la 4 sono "a matrice" (Contr-Maiusc-Enter)

I tempi unitari sono confrontati con la condizione precedente (non quella iniziale).

Per finire dico che la formula che ha performato meglio (con righe da 10mila in su) e' quella che non ho ancora scritto:

Codice: Seleziona tutto

=SOMMA.SE(C2:C100;1;B2:B100)

Questa considera che in colonna C ci sia il calcolo GIORNO.SETTIMANA.

Ciao a tutti.

[CANAPONE]

Ciao,

saluto subito Anthony47.

Mi riferivo a questo articolo:

https://fastexcel.wordpress.com/2015/12 ... -bad-idea/

Se non lo conosci, segnalo anche:

http://www.decisionmodels.com/index.htm

Saluti

[ramset1978]

Per finire dico che la formula che ha performato meglio (con righe da 10mila in su) e' quella che non ho ancora scritto:

Codice: Seleziona tutto

=SOMMA.SE(C2:C100;1;B2:B100)

Questa considera che in colonna C ci sia il calcolo GIORNO.SETTIMANA.

Ciao a tutti.

Grazie Anthony, preciso ed infallibile come sempre. E' esattamente quello che ho fatto.