Condividi:        

Segno predominante e confronto stringa

Vuoi potenziare i tuoi documenti Word? Non sai come si fa una macro in Excel? Devi creare una presentazione in PowerPoint?
Oppure sei passato a OpenOffice e non sei sicuro di come lavorare al meglio?

Moderatori: Anthony47, Flash30005

Segno predominante e confronto stringa

Postdi bibbaste » 02/11/15 19:44

Ben ritrovati a tutti.

A distanza di tempo ricorro nuovamente al vostro prezioso aiuto.

Avrei necessità di una formula che mi permetta di ottenere il seguente risultato:

ho 3 stringhe di 10 numeri (composta solo di numeri 1 oppure 2)

es.
H6 1211122121
H7 1211222111
H8 2122112211

in un'altra cella (es. F7) dovrei ottenere una sola stringa "riassuntiva" con il segno prevalente (confronto verticale delle streghe precedenti per ogni posizione) . In questo caso il risultato sarebbe:

F7 1211122111


Ottenuto questo risultato devo confrontare questa stringa con una inserita da me nella cella F8 (es. 2112221111) e sapere quanti punti ho totalizzato, quindi:

1211122111 (stringa precedentemente trovata)
2112221111 (stringa da me inserita)
xxyxxyxyyy x=errore y= esatta corrispondenza

in questo esempio nella cella F9 dovrei trovarmi il risultato: il numero 5 (5 corrispondenze)

Spero di essere stato chiaro, in caso non lo sia stato, vedo di spiegarmi meglio. :oops:

Ancora un grazie.

Un saluto a tutti
bibbaste
Utente Junior
 
Post: 32
Iscritto il: 03/06/15 15:39

Sponsor
 

Re: Segno predominante e confronto stringa

Postdi bibbaste » 02/11/15 20:33

Mi scuso per la dimenticanza.... forse il dato è necessario. Utilizzo Excel 2010
bibbaste
Utente Junior
 
Post: 32
Iscritto il: 03/06/15 15:39

Re: Segno predominante e confronto stringa

Postdi bibbaste » 03/11/15 09:27

Buongiorno a tutti, volevo aggiornare il post con la soluzione che ho adottato.

Per la prima parte, sono riuscito ad avere un risultato attraverso "testo in colonne" e poi facendo dei confronti matematici tra le varie celle.... :P --- poco ortodosso, ma funziona :lol: (nel caso ci sia qualcosa di meglio.... mi farebbe piacere)

per la seconda parte sono riuscito ad adattare una formula che questa estate Anthony mi ha gentilmente costruito ed il risultato è perfetto.

Vi riporto la formula:
Codice: Seleziona tutto
=MATR.SOMMA.PRODOTTO(--(STRINGA.ESTRAI(Consuntivo!F7;RIF.RIGA(INDIRETTO("1:"&LUNGHEZZA(Consuntivo!F7)));1)="1");--(STRINGA.ESTRAI(Consuntivo!F8;RIF.RIGA(INDIRETTO("1:"&LUNGHEZZA(Consuntivo!F7)));1)="1"))+MATR.SOMMA.PRODOTTO(--(STRINGA.ESTRAI(Consuntivo!F7;RIF.RIGA(INDIRETTO("1:"&LUNGHEZZA(Consuntivo!F7)));1)="2");--(STRINGA.ESTRAI(Consuntivo!F8;RIF.RIGA(INDIRETTO("1:"&LUNGHEZZA(Consuntivo!F7)));1)="2"))


Ancora grazie

Un saluto a tutti
bibbaste
Utente Junior
 
Post: 32
Iscritto il: 03/06/15 15:39

Re: Segno predominante e confronto stringa

Postdi ninai » 03/11/15 09:31

ciao
con l'ausilio di celle di appoggio si può fare con formule abbastanza semplici:
in I6:
=STRINGA.ESTRAI($H6;RIF.COLONNA(A1);1)*1
e trascini fino a R8

in I9:
=MODA(I6:I8)
trascini fino ad R9

in F7:
=CONCATENA(I9;J9;K9;L9;M9;N9;O9;P9;Q9;R9)

in F9
=CONCATENA(I10;J10;K10;L10;M10;N10;O10;P10;Q10;R10)

Si potrà fare anche senza appoggio ma bisogna intervenire con delle matriciali, vedrò di studiarle appena potrò e se saprò
w8 + Office 2010 Ita
ninai
Utente Senior
 
Post: 271
Iscritto il: 12/06/13 05:23
Località: prov. Messina

Re: Segno predominante e confronto stringa

Postdi Anthony47 » 04/11/15 02:53

Un paio di piccole semplificazioni rispetto a quanto avete gia' fatto:
-avendo i dati di partenza in H6, H7 e H8 si possono calcolare i componenti del "segno predominate" inserendo in I9 la formula
Codice: Seleziona tutto
=MODA(--STRINGA.ESTRAI($H$6:$H$8;RIF.COLONNA(A1);1))
Da copiare poi fino a R9

In F7 confermo la formula di ninai
Codice: Seleziona tutto
=CONCATENA(I9;J9;K9;L9;M9;N9;O9;P9;Q9;R9)

In F8 il valore scritto a mano
In F9 le corrispondenze trovate con la formula
Codice: Seleziona tutto
=SOMMA(--(STRINGA.ESTRAI(F7;RIF.COLONNA(A1:J1);1)=STRINGA.ESTRAI(F8;RIF.COLONNA(A1:J1);1)))
Questa e' da confermare con Contr-Maiusc-Enter, non il solo Enter

Non ho capito invece la formula suggerita da ninai per F9

Ciao a tutti.
Avatar utente
Anthony47
Moderatore
 
Post: 19196
Iscritto il: 21/03/06 16:03
Località: Ivrea

Re: Segno predominante e confronto stringa

Postdi Anthony47 » 04/11/15 13:43

A scopo puramente ludico, il valore cercato potrebbe essere calcolato direttamente in F7, senza le celle di appoggio, con la formula
Codice: Seleziona tutto
=SOSTITUISCI(SOSTITUISCI(SOSTITUISCI(SOSTITUISCI(H6+H7+H8;"3";"1");"4";"1");"5";"2");"6";"2")

Tuttavia questa e' difficilmente riciclabile se ci fossero piu' di 2 possibili valori per ogni digit o se il numero di elementi fosse superiore a 3-4

Ciao
Avatar utente
Anthony47
Moderatore
 
Post: 19196
Iscritto il: 21/03/06 16:03
Località: Ivrea

Re: Segno predominante e confronto stringa

Postdi ninai » 04/11/15 20:26

Anthony47 ha scritto:Non ho capito invece la formula suggerita da ninai per F9
Ciao a tutti.

sono cose difficili per te ,
:D :D :lol:


avendo io, alla fine di tutta la lungaggine, dimenticato di pubblicare la formula in I10:
=SE(I9=STRINGA.ESTRAI($F$8;RIF.COLONNA(A1);1)+0;"y";"x")
da trascinare a destra
w8 + Office 2010 Ita
ninai
Utente Senior
 
Post: 271
Iscritto il: 12/06/13 05:23
Località: prov. Messina


Torna a Applicazioni Office Windows


Topic correlati a "Segno predominante e confronto stringa":


Chi c’è in linea

Visitano il forum: Nessuno e 47 ospiti