Valore da massimo da utilizzare nel file di calcolo excel

[danibi60]

Buonasera a tutti,

ho la necessità di ottenere questo risultato:

nella tabella excel allegata, in cella D21, deve comparire, per il calcolo di arrotodamento, il valore massimo tra la cella E14 o E16 (nell'esempio allegato il valore massimo è E16) quindi il valore da utilizzare è 720 che con la formula di arrotondamento diventerà 800, Se il valore più alto fosse stato in E14 idem con patate, in cella D21 dovrà finire il valore di quella cella escludendo il valore di E16.

https://www.dropbox.com/s/a8320k5xv2v55 ... a.xls?dl=0

Spero di esser stato abbastanza chiaro.

Un grazie di cuore per l'aiuto,

danibi60

[ricky53]

Ciao,
Non posso scaricare il tuo file per problemi sul mio PC.

Prova in questo modo
in "D21" scrivi la seguente formula

Codice: Seleziona tutto

=SE(E14>E16; E14; E16)

L'arrotondamento lo hai già fatto?

In caso utilizza la seguente soluzione

Codice: Seleziona tutto

=ARROTONDA.ECCESSO(SE(E14>E16; E14; E16);100)

[Flash30005]

Leggi il post di Ricky
Penso che con questa formula in D21 tu possa risolvere

Codice: Seleziona tutto

=(INT(ARROTONDA(MAX(E14:E16);3)/10^(LUNGHEZZA(ARROTONDA(MAX(E14:E16);3))-1))+1)*10^(LUNGHEZZA(ARROTONDA(MAX(E14:E16);3))-1)

ciao

[Anthony47]

Codice: Seleziona tutto

=ARROTONDA.ECCESSO(SE(E14>E16; E14; E16);100)

Codice: Seleziona tutto

=(INT(ARROTONDA(MAX(E14:E16);3)/10^(LUNGHEZZA(ARROTONDA(MAX(E14:E16);3))-1))+1)*10^(LUNGHEZZA(ARROTONDA(MAX(E14:E16);3))-1)

Io userei la formula piu' semplice, eventualmente semplificandola in

Codice: Seleziona tutto

=ARROTONDA.ECCESSO(MAX(E14;E16);100)

Versioni piu' complesse solo a pagamento; supplemento per formule funzionanti.

Ciao a tutti.

[danibi60]

Anthony, Flash, formula perfette e idonee al mio caso, davvero molto gentili.
Stavo inoltre pensando: se desiderassi, in cella E18, anziché inserire a mano il valore, lo selezionassi attraverso una tendina in funzione della regione, sarebbe possibile?
Naturalmente il valore da scliegliere sarebbe: o solo l'importo della regione oppure regione più provincia insieme. Es.

Tariffa consegna a Milano: valore da selezione €9,80 (vedi lombardia)
Tariffa consegna a Rozzano (provincia di Milano) valora da selezionare €9,80+1,80= €11,60

Spero di esser stato sufficientemente chiaro

Intenderei utilizzare come tabella degli importi questa che vi allego....

https://www.dropbox.com/s/a7w5ma56t3cwx ... i.xls?dl=0

Grazie
Danibi60

[Anthony47]

Allora creati due celle con convalida da elenco; il primo contiene le localita' elencate in colonna A di MATRICE, il secondo Capoluogo /Provincia. Supponiamo che siano in C18 e D18.
Calcolerai la tariffa per localita' con la formula

Codice: Seleziona tutto

=INDICE(MATRICE!A:C;CONFRONTA(C18;MATRICE!A:A;0);3)+INDICE(MATRICE!A:C;CONFRONTA(C18;MATRICE!A:A;0)+1;3)*(D18<>"Capoluogo")

Ciao

[danibi60]

Grazie Antony,
ma perdona la mia abominevole ignoranza,ma cosa significa:" Allora creati due celle con convalida da elenco; il primo contiene le localita' elencate in colonna A di MATRICE, il secondo Capoluogo /Provincia."?
Grazie,

Danibi60

[danibi60]

Dopo vani tentativi, onestamente non riesco a fare nulla...mi spiace ma devo comprendere al meglio cosa intendi Antony.
Grazie per il supporto

[Anthony47]

Ecco come l'ho abbozzato io:

hostare immagini
La cella C18 ha una convalida con l' Elenco Regioni; D18 ha la convalida con la seconda scelta; la formula l'ho messa in E18.

Ciao

[danibi60]

Antony, Grandioso!!!
Grazie,
Danilo

[danibi60]

Ragazzi buonasera e, spero, ben rientrati dalle vacanze.
In merito alla richiesta per la quale mi avete fornito l'ottima soluzione di cui sopra, Vi sottoponmgo quest'altra necessita:

La "tabella fasce di peso" (ex matrice) potrebbe avere più colonne in quanto i pesi della merce e quindi il valore da applicare al nolo potrebbero variare in funzione appunto della fascia di appartenenza

Vedi qui allegato: https://www.dropbox.com/s/yoj4v1kqqs676 ... o.xls?dl=0

Es. il peso sul quale si deve effettuare il calcolo è quello espresso dalla formula in D22 del file "File x calcolo tariffa"( https://www.dropbox.com/s/9eas9j7c99v6t ... .xls?dl=0) in questo caso dovrebbe il valore del nolo sarebbe quello in colonna K del file "tabella per fasce di peso" in funzione poi della regione che imputerei manualmente.

Inoltre, le fasce di peso inserite nel file "tabella fasce di peso" dovranno necessariamente peter essere variate in funzione delle richieste del cliente indi per cui potrei avere fasce di peso diverse es. fino a 300 kg, sino a 1000, sino a 2000 ecc....e in funzione di queste veicolare il risultato che esce dalla cella D22 con la colonna spettante nel "File per calcolo Tariffa"

Spero di essere stato abbastanza chiaro,
grazie come sempre.

Danibi60

[Anthony47]

Devi innanzitutto fare una revisione delle tabelle, che non devono avere in intestazione "Fino a XX Kg" ma "A partire da xx Kg"; di conseguenza la prima colonna sara' " A partire da 0 Kg", la seconda " A partire da 251 Kg", e cosi' via fino all'ultima colonna.

image hosting

A questo punto la formula diventera':

Codice: Seleziona tutto

=INDICE('[Tabella fasce di peso.xls]MATRICE'!A:T;CONFRONTA(C19;'[Tabella fasce di peso.xls]MATRICE'!A:A;0);CONFRONTA(D22;'[Tabella fasce di peso.xls]MATRICE'!$A$5:$T$5;1))+INDICE('[Tabella fasce di peso.xls]MATRICE'!A:T;CONFRONTA(C19;'[Tabella fasce di peso.xls]MATRICE'!A:A;0)+1;CONFRONTA(D22;'[Tabella fasce di peso.xls]MATRICE'!$A$5:$T$5;1))*(D19<>"Capoluogo")

Questa accetta una tabella di fasce di prezzo fino a colonna T, potendo compilare quindi fino a 18 fasce di prezzo.

Il file con la tabella dei prezzi si chiama "Tabella fasce di peso.xls", il foglio "MATRICE"

Rispetto alla formula precedente e' stato sostituita la colonna fissa "3" con la componente CONFRONTA(D22;'[Tabella fasce di peso.xls]MATRICE'!$A$5:$T$5;1)

Ciao

[danibi60]

Grandissimo Anthony! Sono stato fuori per lavoro e solo ora ho trovato il tuo splendido lavoro.
Grazie ancora.
Danibi