Condividi:        

importare dati dal web con excel con un certo criterio

Vuoi potenziare i tuoi documenti Word? Non sai come si fa una macro in Excel? Devi creare una presentazione in PowerPoint?
Oppure sei passato a OpenOffice e non sei sicuro di come lavorare al meglio?

Moderatori: Anthony47, Flash30005

importare dati dal web con excel con un certo criterio

Postdi vittotto » 14/04/15 21:50

Salve a tutti vorrei un aiuto in excel devo fare una macro per importare dati da un sito il sito in questione e' http://it.zulubet.com/
ogni volta che usa la macro mi deve cancellare i vecchi dati e aggiornare con i nuovi ed una macro che mi copi dalla pagina importata quelli che mi soddisfono il mio criterio che imposto per esempio tutti idati con i pronostici 1 e li copia in un altro foglio
Vi ringrazio anticipatamente
vittotto
Utente Junior
 
Post: 24
Iscritto il: 22/01/11 20:54

Sponsor
 

Re: importare dati dal web con excel con un certo criterio

Postdi Flash30005 » 14/04/15 23:10

Copia l'intero codice e inseriscilo in un modulo

Codice: Seleziona tutto
Public WAQ1 As Worksheet, WAQ2 As Worksheet
Sub AggiornaWeb()
Application.ScreenUpdating = False
Application.Calculation = xlManual

Set WAQ1 = ThisWorkbook.Sheets("Foglio1")  '<<<<< assegna il nome effettivo del foglio con la queryweb
Set WAQ2 = ThisWorkbook.Sheets("Foglio2")  '<<<<< assegna il nome effettivo del foglio dati finale
WAQ1.Select
WAQ1.Cells.Clear
    Range("A1").Select
    With ActiveSheet.QueryTables.Add(Connection:="URL;http://it.zulubet.com", _
        Destination:=Range("$A$1"))
        .Name = "it.zulubet"
        .FieldNames = True
        .RowNumbers = False
        .FillAdjacentFormulas = False
        .PreserveFormatting = True
        .RefreshOnFileOpen = False
        .BackgroundQuery = True
        .RefreshStyle = xlInsertDeleteCells
        .SavePassword = False
        .SaveData = True
        .AdjustColumnWidth = True
        .RefreshPeriod = 0
        .WebSelectionType = xlSpecifiedTables
        .WebFormatting = xlWebFormattingNone
        .WebTables = "3"
        .WebPreFormattedTextToColumns = True
        .WebConsecutiveDelimitersAsOne = True
        .WebSingleBlockTextImport = False
        .WebDisableDateRecognition = False
        .WebDisableRedirections = False
        .Refresh BackgroundQuery:=False
    End With
    RiportaProno
    Application.Calculation = xlCalculationAutomatic
    Application.ScreenUpdating = True
End Sub
Private Sub RiportaProno()

WAQ2.Cells.Clear
WAQ1.Rows("1:2").Copy Destination:=WAQ2.Range("A1")
UR1 = WAQ1.Range("A" & Rows.Count).End(xlUp).Row
For RR1 = 3 To UR1
    If WAQ1.Range("F" & RR1).Value = 1 Then  '<<<<< condizione che copia se il pronostico corrisponde a "1"
    UR2 = WAQ2.Range("F" & Rows.Count).End(xlUp).Row + 1
    WAQ1.Rows(RR1).Copy Destination:=WAQ2.Range("A" & UR2)
    End If
Next RR1
WAQ2.Select
WAQ2.Columns("A:K").EntireColumn.AutoFit
End Sub


I fogli considerati sono "Foglio1" e "Foglio2"
se non sono questi i nomi modifica questi nomi nella macro di avvio dove indicato con <<<<

Dopodiché avvia "AggiornaWeb"

ciao
Flash
Win10 + Office 2010 Ita
"Fotografica" al servizio dell'immagine
Avatar utente
Flash30005
Moderatore
 
Post: 8517
Iscritto il: 27/09/07 11:44
Località: Roma +o-

Re: importare dati dal web con excel con un certo criterio

Postdi vittotto » 16/04/15 23:53

Grazie mille e' quello che volevo
vittotto
Utente Junior
 
Post: 24
Iscritto il: 22/01/11 20:54

Re: importare dati dal web con excel con un certo criterio

Postdi vittotto » 17/04/15 13:28

mi va bene la macro vorrei solo un altro favore se e' possibile se voglio cambiare il criterio di ricerca per esempio invece di 1 voglio la x che riga devo modificare e se si puo fare una maschera di input dove posso stabilire io il criterio
lo so' vi chiedo molto ma voi siete molto bravi in programmazione vi ringrazio anche se non e' possibile
vittotto
Utente Junior
 
Post: 24
Iscritto il: 22/01/11 20:54

Re: importare dati dal web con excel con un certo criterio

Postdi Flash30005 » 18/04/15 23:43

Sostituisci solo la seconda macro con questa
Codice: Seleziona tutto
Private Sub RiportaProno()
WAQ2.Cells.Clear
Dim Message, Title, Default, MyValue
Message = "Quale pronostico deisderi filtare?"
Title = "Cerca Pronostico    ' Imposta il titolo."
Default = ""
MyValue = InputBox(Message, Title, Default)
If MyValue = "" Then Exit Sub
WAQ1.Rows("1:2").Copy Destination:=WAQ2.Range("A1")
UR1 = WAQ1.Range("A" & Rows.Count).End(xlUp).Row
For RR1 = 3 To UR1
    If UCase(WAQ1.Range("F" & RR1).Text) = UCase(MyValue) Then
    UR2 = WAQ2.Range("F" & Rows.Count).End(xlUp).Row + 1
    WAQ1.Rows(RR1).Copy Destination:=WAQ2.Range("A" & UR2)
    End If
Next RR1
WAQ2.Select
WAQ2.Columns("A:K").EntireColumn.AutoFit
End Sub


Ciao
Flash
Win10 + Office 2010 Ita
"Fotografica" al servizio dell'immagine
Avatar utente
Flash30005
Moderatore
 
Post: 8517
Iscritto il: 27/09/07 11:44
Località: Roma +o-

Re: importare dati dal web con excel con un certo criterio

Postdi vittotto » 19/04/15 23:52

Grazie mille
vittotto
Utente Junior
 
Post: 24
Iscritto il: 22/01/11 20:54


Torna a Applicazioni Office Windows


Topic correlati a "importare dati dal web con excel con un certo criterio":


Chi c’è in linea

Visitano il forum: Anthony47 e 25 ospiti