Condividi:        

Cerca valore minimo

Vuoi potenziare i tuoi documenti Word? Non sai come si fa una macro in Excel? Devi creare una presentazione in PowerPoint?
Oppure sei passato a OpenOffice e non sei sicuro di come lavorare al meglio?

Moderatori: Anthony47, Flash30005

Cerca valore minimo

Postdi apocrimata75 » 29/03/14 17:49

Ragazzi scusate ma con l'età mi rincretinisco

vorrei trovare il primo valore della colonna j (da j2 a j5000) maggiore di zero e che rispetti la condizione BACKUP!$C$2:$P$5000=Pronostici!C18)

formula per ultimo valore
Codice: Seleziona tutto
=SE(C18<>"";CERCA(9999999999;1/((BACKUP!$C$2:$P$5000=Pronostici!C18)*(BACKUP!$J$2:$J$5000<>""));BACKUP!$J$2:$J$5000);"")



ho provato con
Codice: Seleziona tutto
=PICCOLO(INDICE(BACKUP!$J$2:$J$50000*(BACKUP!$C$2:$C$50000=C18););1+CONTA.SE(BACKUP!$C$2:$C$50000;"<>"&C18))


Help me.
Windows 7 - Office 2010
apocrimata75
Utente Senior
 
Post: 189
Iscritto il: 28/05/11 13:22

Sponsor
 

Re: Cerca valore minimo

Postdi CANAPONE » 29/03/14 18:22

Ciao,

non sono sicuro di aver capito: vado dietro il titolo. Ho solo aggiunto un conta.più.se alla formula

Codice: Seleziona tutto
=PICCOLO(INDICE(BACKUP!$J$2:$J$50000*(BACKUP!$C$2:$C$50000=C18););1+CONTA.SE(BACKUP!$C$2:$C$50000;"<>"&C18)+conta.più.se(BACKUP!$J$2:$J$50000;"<=0";BACKUP!$C$2:$C$50000;C18))


Restitutisce lo stesso risultato di un MIN(SE... matrice da confermare con control+maiusc+invio

Codice: Seleziona tutto
=MIN(SE(BACKUP!$C$2:$C$50000=C18;SE(BACKUP!$J$2:$J$50000>0;BACKUP!$J$2:$J$50000)))


Saluti
---------------
Excel 2004 su Mac
Excel 2010 su Windows 8
CANAPONE
Utente Senior
 
Post: 430
Iscritto il: 22/11/10 15:43
Località: Firenze

Re: Cerca valore minimo

Postdi apocrimata75 » 29/03/14 18:30

vorrei trovare il primo valore diverso da zero della colonna j soddisfatta l'ulteriore condizione
Codice: Seleziona tutto
BACKUP!$C$2:$P$5000=C18
. La formula postata restituisce errore (valore)
Windows 7 - Office 2010
apocrimata75
Utente Senior
 
Post: 189
Iscritto il: 28/05/11 13:22

Re: Cerca valore minimo

Postdi apocrimata75 » 29/03/14 18:31

sarebbe un cerca.vert a 2 condizioni "=c18" e valore di j maggiore di >0 (primo valore o valore minimo
Windows 7 - Office 2010
apocrimata75
Utente Senior
 
Post: 189
Iscritto il: 28/05/11 13:22

Re: Cerca valore minimo

Postdi CANAPONE » 29/03/14 18:58

Ciao,

cosa c'è in C18?

Basta che C18 sia presente anche solo una volta nel range -esempio- C4:P4?

Cerco di spiegarmi: non "vedo" chiaramente il layout del tuo file- me lo sto ricostruendo- nelle colonne dalla C alla P cerco C18 per andare a cercare un valore nella colonna J (che è fra le colonne C e P)



Saluti
---------------
Excel 2004 su Mac
Excel 2010 su Windows 8
CANAPONE
Utente Senior
 
Post: 430
Iscritto il: 22/11/10 15:43
Località: Firenze

Re: Cerca valore minimo

Postdi apocrimata75 » 29/03/14 19:10

la matrice funziona, grazie mille
Windows 7 - Office 2010
apocrimata75
Utente Senior
 
Post: 189
Iscritto il: 28/05/11 13:22

Re: Cerca valore minimo

Postdi CANAPONE » 29/03/14 19:28

Ciao,

il cerca.vert corrispondente a questa formula che cerca l'ultima corrispondenza


Codice: Seleziona tutto
=SE(C18<>"";CERCA(9999999999;1/((BACKUP!$C$2:$P$5000=Pronostici!C18)*(BACKUP!$J$2:$J$5000<>""));BACKUP!$J$2:$J$5000);"")


sarebbe

Codice: Seleziona tutto
=INDICE(BACKUP!$J$2:$J$5000;CONFRONTA(1;INDICE((BACKUP!$C$2:$C$5000=C18)*(BACKUP!$J$2:$J$5000>0););0))


che restituisce - come il cerca.vert il primo numero >0 in corrispondenza = C18 nella colonna C di backup

BACKUP!$C$2:$P$5000=C18

produce un errore.

Se servisse.
---------------
Excel 2004 su Mac
Excel 2010 su Windows 8
CANAPONE
Utente Senior
 
Post: 430
Iscritto il: 22/11/10 15:43
Località: Firenze

Re: Cerca valore minimo

Postdi apocrimata75 » 30/03/14 15:19

Ne approfitto per un consulto completo

la funzione
Codice: Seleziona tutto
=INDICE(BACKUP!$J$2:$J$5000;CONFRONTA(1;INDICE((BACKUP!$C$2:$C$5000=C17)*(BACKUP!$J$2:$J$5000>0););0))


restituisce il primo valore >0 della colonna J; volendo utilizzare la stessa formula, con "indice" e "confronta", come trovo l'ultimo valore >0 ed il penultimo? ed il terzultimo?
Windows 7 - Office 2010
apocrimata75
Utente Senior
 
Post: 189
Iscritto il: 28/05/11 13:22

Re: Cerca valore minimo

Postdi CANAPONE » 30/03/14 16:35

Ciao,

la formula più comune è questa

Codice: Seleziona tutto
=SE.ERRORE(INDICE(BACKUP!$J$2:$J$5000;PICCOLO(SE(BACKUP!$C$2:$C$5000=$C$17;SE(BACKUP!$J$2:$J$5000>0;RIF.RIGA($A$2:$A$5000)-1));RIGHE($A$1:$A1)));"")


è da confermare con control+maiusc+invio.

Una volta confermata, la copi in basso ed ottieni il secondo, il terzo valore...quando non ne trova più restituirebbe "errore", che viene gestito da SE.ERRORE e trasformato in "".

Saluti
---------------
Excel 2004 su Mac
Excel 2010 su Windows 8
CANAPONE
Utente Senior
 
Post: 430
Iscritto il: 22/11/10 15:43
Località: Firenze

Re: Cerca valore minimo

Postdi CANAPONE » 30/03/14 16:59

Ciao di nuovo,

se al posto di PICCOLO usi GRANDE, la formula recupera l'ultimo, poi il penultimo...


Codice: Seleziona tutto
=SE.ERRORE(INDICE(BACKUP!$J$2:$J$5000;GRANDE(SE(BACKUP!$C$2:$C$5000=$C$17;SE(BACKUP!$J$2:$J$5000>0;RIF.RIGA($A$2:$A$5000)-1));RIGHE($A$1:A1)));"")


Sempre in forma matrice.

Saluti
---------------
Excel 2004 su Mac
Excel 2010 su Windows 8
CANAPONE
Utente Senior
 
Post: 430
Iscritto il: 22/11/10 15:43
Località: Firenze

Re: Cerca valore minimo

Postdi apocrimata75 » 30/03/14 17:18

la formula restituisce il primo valore, ma io cercavo al contrario l'ultimo, il penultimo ed il terzultimo
Windows 7 - Office 2010
apocrimata75
Utente Senior
 
Post: 189
Iscritto il: 28/05/11 13:22

Re: Cerca valore minimo

Postdi CANAPONE » 30/03/14 17:23

Ciao,

mi ero corretto nel post successivo: sostituisci PICCOLO con GRANDE.

E' importante la corretta conferma con control+maiusc+invio per far funzionare le formule.

Saluti
---------------
Excel 2004 su Mac
Excel 2010 su Windows 8
CANAPONE
Utente Senior
 
Post: 430
Iscritto il: 22/11/10 15:43
Località: Firenze

Re: Cerca valore minimo

Postdi apocrimata75 » 30/03/14 17:30

scusa non avevo letto, perfetto grazie mille. Si può fare senza matrice?

Uso questa x l'lultimo

Codice: Seleziona tutto
=CERCA(9999999999;1/(BACKUP!$C$2:$C$50000=C3);BACKUP!$J$2:$J$50000)
Windows 7 - Office 2010
apocrimata75
Utente Senior
 
Post: 189
Iscritto il: 28/05/11 13:22

Re: Cerca valore minimo

Postdi CANAPONE » 30/03/14 17:36

Ciao,

vorrei essere smentito, ma temo che senza formula matrice si potrebbe fare solo con una colonna di servizio nel database di BACKUP.

Va aggiunta una colonna al database che conta progressivamente i valori>0 quando la colonna C = C17

Dei conta.più.se.

Saluti
---------------
Excel 2004 su Mac
Excel 2010 su Windows 8
CANAPONE
Utente Senior
 
Post: 430
Iscritto il: 22/11/10 15:43
Località: Firenze

Re: Cerca valore minimo

Postdi CANAPONE » 30/03/14 17:43

Ciao,

faccio un esempio C17 è nel primo foglio, nel foglio backup nella prima colonna vuota (la K per esempio) in K2

Codice: Seleziona tutto
=SE(E(Foglio1!$C$17=C2;J2>0);CONTA.PIÙ.SE(BACKUP!C2:$C$5000;C2;BACKUP!J2:$J$5000;">0");"")



Torni nel foglio1 e ti servi della colonna K

Codice: Seleziona tutto
=SE.ERRORE(INDICE(BACKUP!$J$2:$J$5000;CONFRONTA(RIF.RIGA(A1);BACKUP!$K$2:$K$5000;0));"")


Stessi risultati.

Saluti

EDIT: occhio alla prima formula =SE(E...
---------------
Excel 2004 su Mac
Excel 2010 su Windows 8
CANAPONE
Utente Senior
 
Post: 430
Iscritto il: 22/11/10 15:43
Località: Firenze

Re: Cerca valore minimo

Postdi Anthony47 » 30/03/14 18:15

apocrimata75 ha scritto:Si può fare senza matrice?
:?: :?:
Quale e' il motivo di questa richiesta? E' come chiedere di calcolare il totale di un intervallo senza usare la funzione Somma...
(comunque non perdere la risposta di canapone, sopra)

Ciao
Avatar utente
Anthony47
Moderatore
 
Post: 19196
Iscritto il: 21/03/06 16:03
Località: Ivrea

Re: Cerca valore minimo

Postdi apocrimata75 » 01/04/14 17:36

Era solo una curiosità. Le formule di canapone hanno funzionato alla perfezione. Grazie ancora.
Windows 7 - Office 2010
apocrimata75
Utente Senior
 
Post: 189
Iscritto il: 28/05/11 13:22


Torna a Applicazioni Office Windows


Topic correlati a "Cerca valore minimo":

BTp Valore
Autore: MarioLombardi
Forum: Forum off-topic
Risposte: 2

Chi c’è in linea

Visitano il forum: Nessuno e 26 ospiti