Intervallo di selezione

[cd7019]

Ciao,

come posso risolvere questo problema:
se il mio intervallo di selezione è compreso nell'intervallo A1:Z100 allora posso eliminare queste righe.

if ...
Selection.EntireRow.Delete
end if

Grazie.

[Anthony47]

Se vuoi verificare che tutta la selezione sia compresa in quel range allora potresti usare

Codice: Seleziona tutto

If Application.Intersect(Range("A1:Z1000"), Selection).Count = Selection.Count Then
    Selection.EntireRow.Select
End If

Collaudare su una copia dei tuoi importanti dati...

Ciao

[cd7019]

ciao,
ho eseguito una selezione all'interno dell'intervallo e funziona perfettamente, ma quando ho una selezione completamente al di fuori dell'intervallo mi genera un errore. "errore #91: variabile del blocco with non impostata".
Come posso eliminare tale errore?

Codice: Seleziona tutto

If Application.Intersect(Range("A14:V1000"), Selection).Count = Selection.Count Then
    Response = MsgBox("Sei sicuro di voler eliminare queste righe?", vbYesNo)
    If Response = vbYes Then
        Selection.EntireRow.Delete
        ActiveCell.Select
    End If
End If


Grazie

[Anthony47]

E' vero (e lo dice anche l' help on line...); devi quindi usare un artificio:

Codice: Seleziona tutto

Set iset = Application.Intersect(Range("A1:Z1000"), Selection)
If Not iset Is Nothing Then
'
'Il codice precedente
'
End If


Se dichiari la variabile iset essa deve essere "as Variant"

Ciao

[scossa]

Una variante:

Codice: Seleziona tutto

Public Sub prova()
  Dim rngInt As Range
  Set rngInt = Application.Intersect(Range("A14:V1000"), Selection)
  If Not rngInt Is Nothing Then
    If rngInt.Address = Selection.Address Then
      With Selection
        If MsgBox("Sei sicuro di voler eliminare le righe " & .EntireRow.Address(0, 0) & "?", vbYesNo) = vbYes Then
          'Application.EnableEvents = False 'attivare se necessario
          .EntireRow.Delete
          ActiveCell.Select
          'Application.EnableEvents = True 'attivare se necessario
        End If
      End With
    End If
  End If
  Set rngInt = Nothing


End Sub

[cd7019]

Grazie a tutti x l'aiuto.