excel2007 cercare 3 numeri consecutivi

[asterix55]

vorrei trovare 3 numeri in una colonna di altrettanti numeri però questi numeri li vorrei trovare solo se sono consecutivi in ordine di uscita
es. cercare 25 12 7 nella colonna A ma solo se sono usciti in quell'ordine
sarà possibile sapere come fare? grazie

[Flash30005]

Si, penso, ma bisogna avere i dati origine e una volta trovati cosa fare

ciao

[asterix55]

diciamo che li voglio cercare in colonna A e metti il numero successivo in b1

[Flash30005]

ah ecco!
Adesso diciamo che ho capito tutto!

[Anthony47]

Non hai detto dove sono elencati i tre numeri che vuoi cercare.
Immaginiamo che siano in D2-D3-D4
Creati un intervallo che chiami "intervallo" che contiene certamente tutti i dati di origine (non puo' essere l' intera colonna, ma lo puoi fare lungo anche per le esigenze future; ad esempio A1:A1000).
Poi in B1 metti la formula

Codice: Seleziona tutto

=SCARTO(A1;GRANDE((intervallo=$D$2)*(SCARTO(intervallo;1;0)=D$3)*(SCARTO(intervallo;2;0)=D$4)*RIF.RIGA(intervallo);1)+2;0)

Da confermare con Contr-Maiusc-Enter, non il solo Enter

Fai sapere.

[asterix55]

ora mi trovo cosi mi da questo errore
https://rapidshare.com/files/4179397706/Immagine1.jpg
https://rapidshare.com/files/2946048762/Immagine2.jpg

[Anthony47]

Hai creato "intervallo"?

[asterix55]

si ho fatto A1:A115
mi viene cosi però
https://rapidshare.com/files/1646402275/Immagine3.jpg

[Anthony47]

No, devi "definire un intervallo".
In XL2010: selezioni l' intervallo, es A1:A1000; tab Formule, gruppo Nomi definiti, Definisci nome; scrivi il nome (intervallo), premi Ok.
Poi usi la formula che ti ho dato.

Ciao

[asterix55]

ok ci sono finalmente dopo prova e riprova ci sono riuscito
grazie Anthony

[asterix55]

suppongo che se io volessi cercare un numero solo successivo la formula verrebbe tagliata , ho provato ma non sono riuscito .

[Anthony47]

suppongo che se io volessi cercare un numero solo successivo la formula verrebbe tagliata , ho provato ma non sono riuscito

Nell' ipotesi che tu ora voglia cercare "2 numeri consecutivi" e prendere il terzo della sequenza, userai

Codice: Seleziona tutto

=SCARTO(A1;GRANDE((intervallo=$D$2)*(SCARTO(intervallo;1;0)=D$3)*RIF.RIGA(intervallo);1)+1;0)


Mi sono accorto pero' che le formule proposte restituiscono un risultato verosimile ma non veritiero qualora la sequenza non esista in elenco.
Immagino che questo sia un problema, che si puo' aggirare modificando la formula iniziale in

Codice: Seleziona tutto

=SE(SOMMA((intervallo=$D$2)*(SCARTO(intervallo;1;0)=D$3)*(SCARTO(intervallo;2;0)=D$4))>0;SCARTO(A1;GRANDE((intervallo=$D$2)*(SCARTO(intervallo;1;0)=D$3)*(SCARTO(intervallo;2;0)=D$4)*RIF.RIGA(intervallo);1)+2;0);"###")


E quella per la sequenza di 2 in

Codice: Seleziona tutto

=SE(SOMMA((intervallo=$D$2)*(SCARTO(intervallo;1;0)=D$3))>0;SCARTO(A1;GRANDE((intervallo=$D$2)*(SCARTO(intervallo;1;0)=D$3)*RIF.RIGA(intervallo);1)+1;0);"###")


Ciao

PS: Per favore indica la tua configurazione di lavoro: viewtopic.php?f=26&t=97449