Cerca valore massimo

[apocrimata75]

Vorrei porre un quesito, data la seguente tabella nel foglio 1
A B
1 a 1
2 a 2
3 a 4
4 a 6
5 b 1
6 b 4
7 b 7
8 c 7
9 c 9


Dove le righe sia di a, b, c ecc. sono variabili e non definite (da 1 a 2000).

Nel foglio 2, vorrei la formula che restituisca il valore massimo di a.

Del tipo cerca a nella tabella del foglio 1 e restituisci il valore massimo.

Grazie.

[apocrimata75]

=MAX((foglio2!AB2:AB2000)*((foglio2!F2:F500=F7)+0))

dove ab2:ab2000 contiene il valore max da cercare, ma non mi funziona.

[Flash30005]

Non capisco perché se i dati ce li hai nel foglio1
la tua formula non lo menzioni affatto (il foglio1) e quindi non avrai mai un risultato
ora ti dò una formula da mettere in qualsiai cella del foglio1 (il range test va dalla riga 2 alla riga 10 ma adattalo alle tue esigenze)

Codice: Seleziona tutto

=MAX(INDICE((A2:A10=H1)*B2:B10;))

in colonna A hai le lettere in colonna B i valori
e in H1 la lettera che esamini

se devi inserire questa formula nel foglio due è sufficiente richiamare il Foglio1 prima del range della formula

ciao

[ricky53]

Ciao,
la formula di Flash nella cella "H1" si aspetta il valore del quale vuoi avere il MAX.

[apocrimata75]

Codice: Seleziona tutto

=MAX(INDICE((BACKUP!$F$2:$F$50000=F7)*BACKUP!$AB$2:$AB$50000;))

questa funziona, così come consigliata, ma per avere il valore minimo?

Codice: Seleziona tutto

=MIN(INDICE((BACKUP!$F$2:$F$50000=F7)*BACKUP!$AB$2:$AB$50000;))

questa restituisce solo 0, perchè?

[CANAPONE]

Ciao,

Se la colonna Ab non contiene numeri negativi

=PICCOLO(INDICE(BACKUP!$AB$2:$AB$50000*(BACKUP!$F$2:$F$50000=F7););1+CONTA.SE(BACKUP!$F$2:$F$50000;"<>"&F7))

In alternativa la formula matrice

+MIN(SE(BACKUP!$F$2:$F$50000=F7;BACKUP!$ab$2:$abF$50000))

da confermare con control+maiusc=invio


Spero sia d'aiuto

[apocrimata75]

grazie canapone, la prima funziona, la seconda no, ma va benissimo.

Vorrei chiedere un'altra cosa, fermo restando l'esempio di prima , è possibile creare una formula che restituisca non il valore minimo o massimo, ma il primo o l'ultimo, in considerazione del fatto, per esempio, le righe con valore a potrebbero essere 1 o 1000 ecc.

[CANAPONE]

Ciao,

mi e' scappata una f nella formula

Codice: Seleziona tutto

=MIN(SE(BACKUP!$F$2:$F$50000=F7;BACKUP!$AB$2:$AB$50000))

da confermare con control+maiusc+invio.

Hai bisogno del primo ed ultimo valore in corrispondenza di quello che scrivi in F7 in un intervallo variabile?

Un cerca.vert che peschi il primo valore e l'ultimo valore?

Prima corrispondenza

[cpde]=CERCA.VERT(F7;BACKUP!$F$2:$AB$50000;23;0)[/code]

ultima corrispondenza

Codice: Seleziona tutto

=CERCA(9999999999;1/(BACKUP!F2:F50000=F7);BACKUP!AB2:AB50000)

Non sono sicuro di aver capito.

Saluti

[Flash30005]

Avrei anche io una soluzione senza matrice (senza dover premere Ctrl+Alt+Enter)

Codice: Seleziona tutto

=INDICE(A2:B10;(CONFRONTA(H1;A2:A10;0)+1);(CONFRONTA(MIN(B2:B10);B2:B10;0)+1))

Adatta i range al foglio e in H1 ho il nome da trovare

ciao

EDIT: mi accorgo ora che questa formula ha un bug

[apocrimata75]

in base all'esempio dell'inizio, per la lettera "a" dovrebbe restituire i valori 1 (contenuto in B1) e 6 (contenuto in B4).

[CANAPONE]

Ciao,

il cerca.vert trova il primo valore corrispondente ad A

il cerca l'ultimo

sul tuo esempio

[CODE=CERCA.VERT("A";A$2:$B$50000;2;0)[/CODE]

Codice: Seleziona tutto

=CERCA(9999999999;1/(A$2:A$50000="A");B$2:B$50000)

Chiaramente devono essere adattati i riferimenti al proprio caso.

Saluti

[apocrimata75]

grazie canapone funzionano perfettamente!!

[apocrimata75]

Ciao ragazzi, avrei bisogno del vs aiuto, se possibile per ottenere un miglior risultato dalle ottime formule postate da canapone ed usate nell'immagine allegata.

Come potete vedere nell'esempio delle "mele", mentre l'ultimo valore dovrebbe essere 3, la formula giustamente restituisce zero in quanto la cella c10 è vuota.

Vista la vs esperienza e capacità è possibile invece ottenere il valore desiderato, cioè "3" come ultimo valore

http://image.forumfree.it/8/2/5/0/3/1/3/1359758939.png

p.s.: grazie anticipitamente.

[Flash30005]

Il link dell'immagine non è accessibile, riprova

[Anthony47]

Il link e' inutilizzabile, quindi non so a quale formula fai riferimento e quale e' la tua struttura dati. In una situazione come da immagine, la formula =MIN(SE(A1:A10=D1;SE(B1:B10>0;B1:B10;"");"")) da confermare con Contr-Maiusc-Enter (non il solo Enter) restituisce il valore corretto:


Uploaded with ImageShack.us

Prova ad adattare...

Ciao

[apocrimata75]

Eppure nell'anteprima mi dava l'immagine.

[apocrimata75]

le formule di canapone erano relative al primo ed ultimo valore, non più minimo e massimo.

[apocrimata75]

Purtroppo continua a non visualizzare l'immagine, cerco di spiegare diversamente:
avrei la necessità di trovare il primo e l'ultimo valore di una colonna ed uso queste formule:

Codice: Seleziona tutto

=CERCA.VERT(E4;B4:C10;2;FALSO)

Codice: Seleziona tutto

=CERCA(9999999999;1/(B4:B10=E4);C4:C10)

pertanto mi servono i valori che rispettano la condizione "=e4".

può capitare che l'ultima riga della colonna c (esempio la cella c10) sia vuota e la formula in questo caso mi restituisce zero e non va bene perkè a questo punto avrei bisogno non dell'ultimo ma del terzultimo e via dicendo (in pratica partendo da sotto il primo valore numerico). E' fattibile?

[CANAPONE]

Edit: scusa ho riscritto di nuovo la formula che stai già usando. Mi ha confuso il 99999

---------------------------------------

[CANAPONE]

Ciao,

prova così

Codice: Seleziona tutto

=CERCA(2;1/((B4:B10=E4)*(C4:C10<>""));C4:C10)

Saluti