Cerco una macro per una ricerca

[Rossi Vincenzo]

Salve a tutti,

In un file di excel 2007 dov'è riproposta una tabella nella quale sono configurate in

colonna C: da C4 a C10 delle date in ordine cronologico, e nel Range che va da D4 a H10 le località che alcuni

nostri incaricati si dovranno trovare per quelle date, mentre sul terzo rigo partendo da D3 fino a H3

sono elencati i relativi nomi.

Domanda con una macro: Fornendo in A5 una data ed in B5 una località è possibile con un messaggio, o evidenziarlo

in una cella come J5, sapere qual'è l'incaricato?

Grazie

[patel]

non c'è bisogno di una macro, basta la funzione cerca verticale, se istruzioni òe trovi cercando su google excel cerca verticale

[CANAPONE]

Ciao a tutti.

credo ci siano soluzioni più semplici.

Codice: Seleziona tutto

=SE.ERRRORE(INDICE($D$3:$H$3;CONFRONTA(B5;INDIRETTO("D"&CONFRONTA(A5;$C$4:$C$10;0)+3&":H"&CONFRONTA(A5;$C$4:$C$10;0)+3);0));"")

Saluti

[Rossi Vincenzo]

Vi chiedo solo una cortesia ma quel codice va inserito in quale cella?

[Rossi Vincenzo]

Ho provato ad inserirlo in J5 dove mi aspetto il nome dell'incaricato, dopo aver inserito

in A5 una data e in B5 una Località ma ottengo come risposta in J5 #NOME?

[wallace&gromit]

come sempre Canapone ci stupisce con effetti speciali:
devi inserire la sua formula in J5.
Prova a lasciare perdere la parte del se. errrore così:

Codice: Seleziona tutto

INDICE($D$3:$H$3;CONFRONTA(B5;INDIRETTO("D"&CONFRONTA(A5;$C$4:$C$10;0)+3&":H"&CONFRONTA(A5;$C$4:$C$10;0)+3);0))

e vedi se funziona. Ora dovrai semplicemente essere sicuro che i dati inseriti appaiano effettivamente nella tabella.

P.S. anche a me dava #nome perchè ho excel 2003

[CANAPONE]

Ciao a tutti,

ho scritto se.errore con tre erre (SE.ERRRORE): questo ha provocato la legittima protesta di Excel 2007 (#nome?).

Se servisse

[CANAPONE]

Ciao,

così la formula fa meno capriole

Codice: Seleziona tutto

=indice($D$3:$H$3;confronta(B5;indice($D$4:$H$10;confronta(A5;$C4:$C$10;0);0);0))

se hai Excel 2007 se.errore evita messaggi di errore se non esiste un nome per la data e la destinazione

Codice: Seleziona tutto

=se.errore(indice($D$3:$H$3;confronta(B5;indice($D$4:$H$10;confronta(A5;$C4:$C$10;0);0);0));"")

Spero si averle scritte correttanente.

Ciao a tutti

[Rossi Vincenzo]

Va benissimo,

ho inserito l'ultima, ma non ci sarei mai arrivato troppo complessa.

Grazie te ne sono molto grato.

Complimenti!!!!!!!!