Condividi:        

INCROCIO DI RIGHE E COLONNE

Vuoi potenziare i tuoi documenti Word? Non sai come si fa una macro in Excel? Devi creare una presentazione in PowerPoint?
Oppure sei passato a OpenOffice e non sei sicuro di come lavorare al meglio?

Moderatori: Anthony47, Flash30005

INCROCIO DI RIGHE E COLONNE

Postdi erryrox » 18/04/12 14:18

Ciao a tutti, ecco il mio nuovo problema:
ho una tabella come quella sottoriportata, dovrei riuscire tramite una formula a riportare per ogni riga il mese corrispondente alla X.
Sapete aiutarmi??? grazieee

A B C D E F G H I L M N O P Q R
GEN FEB MAR APR MAG GIU LUG AGO SET OTT NOV DIC formula
- X - - - - - - - - - - FEB
- - - - - - - - - - - -
- - - X - - - - - - - - APR
- - - - - - - - - - - -
- - - - - - X - - - - - LUG
- - - - - - - - X - - - SET
erryrox
Utente Junior
 
Post: 60
Iscritto il: 16/04/12 14:31

Sponsor
 

Re: INCROCIO DI RIGHE E COLONNE

Postdi Anthony47 » 18/04/12 14:51

Se l' intestazione e' su riga 1, allora in M2 usa la seguente formula
Codice: Seleziona tutto
=SE(CONTA.SE($A2:$L2;"X")>0;INDICE($A$1:$L$1;CONFRONTA("X";$A2:$L2;0));"")

copia poi verso il basso.

Fai sapere, ciao.
Avatar utente
Anthony47
Moderatore
 
Post: 19196
Iscritto il: 21/03/06 16:03
Località: Ivrea

Re: INCROCIO DI RIGHE E COLONNE

Postdi erryrox » 18/04/12 17:30

anthony perfetto, stupendo!!!!! mi mancava la funzione CONFRONTA che non riuscivo a trovare!!!!!

Ora però vorrei complicare le cose: se per caso avessi due X nella stessa riga, c'è un modo per ottenere i due diversi mesi (non necessariamente nella stessa cella)????????

grazie


gen feb mar apr mag giu lug ago set ott nov dic formula

x mar
x gen



x ago
x mag


x mag



x ott
erryrox
Utente Junior
 
Post: 60
Iscritto il: 16/04/12 14:31

Re: INCROCIO DI RIGHE E COLONNE

Postdi erryrox » 18/04/12 17:31

purtroppo non riesco a riportare qui la tabella come testo in modo decente :(
erryrox
Utente Junior
 
Post: 60
Iscritto il: 16/04/12 14:31

Re: INCROCIO DI RIGHE E COLONNE

Postdi Anthony47 » 18/04/12 22:29

Allora in M2 usa
Codice: Seleziona tutto
=SE(RIF.COLONNA(A1)<=CONTA.SE($A2:$L2;"X");INDICE($A$1:$L$1;PICCOLO(SE($A2:$L2="X";RIF.COLONNA($A2:$L2);"");RIF.COLONNA(A1)));"")
Da confermare con Contr-Maiusc-Enter (non solo Enter)
Poi copia verso dx per ottenere eventuali altri mesi marcati e infine copia verso il basso.

Fai sapere, ciao.
Avatar utente
Anthony47
Moderatore
 
Post: 19196
Iscritto il: 21/03/06 16:03
Località: Ivrea

Re: INCROCIO DI RIGHE E COLONNE

Postdi erryrox » 19/04/12 10:01

grazie ancora anthony, funziona alla grande!!!
grazie ai vostri consigli stò imparando moltissimo..
Come al solito però, complico ancora le cose:
Ora che ho ottenuto nella colonna i mesi corrispondenti alla X, vorrei in una colonna adiacente indicare con un numero progressivo l'ordine dei mesi.

Es:

LUG - 4
FEB - 2
MAG - 3
GEN - 1
DIC - 5

GRAZIE!
erryrox
Utente Junior
 
Post: 60
Iscritto il: 16/04/12 14:31

Re: INCROCIO DI RIGHE E COLONNE

Postdi wallace&gromit » 19/04/12 12:33

ciao, ho una soluzione che si suddivide in due tappe:
nella prima colonna accanto al nome del mese (assumo colonna B) immetti questa formula e trascini in giù:
Codice: Seleziona tutto
=CONFRONTA(AX;{"gen";"feb";"mar";"apr";"mag";"giu";"lug";"ago";"set";"ott";"nov";"dic"};0)

dove AX fa riferimento alla cella con il nome del mese

e nella colonna accanto questa:
Codice: Seleziona tutto
=RANGO(BX;B$X:B$Y;1)

BX è il punto dove hai inserito la formula precedente e BY è l'ultima cella in cui hai trascinato la formula
Office2016 + 2019 su win11
Avatar utente
wallace&gromit
Utente Senior
 
Post: 2174
Iscritto il: 16/01/12 14:21

Re: INCROCIO DI RIGHE E COLONNE

Postdi erryrox » 19/04/12 13:27

woww...funziona!!!! :)

però c'è un piccolo "bug": se ho due celle con lo stesso mese, questo algoritmo mi fornisce sempre lo stesso numero progressivo, cioè:

APR - 3
MAG - 4
GEN - 1
FEB - 2
FEB - 2
DIC - 5

C'è un modo per risolverlo????
grazie
erryrox
Utente Junior
 
Post: 60
Iscritto il: 16/04/12 14:31

Re: INCROCIO DI RIGHE E COLONNE

Postdi erryrox » 19/04/12 13:29

non importa quale dei due "mesi uguali" venga prima, l'importante è che la numerazione sia progressiva senza ripetizioni!!

grazie
erryrox
Utente Junior
 
Post: 60
Iscritto il: 16/04/12 14:31

Re: INCROCIO DI RIGHE E COLONNE

Postdi CANAPONE » 19/04/12 14:08

Ciao a tutti,

seguo lo schema di Wallace&Gromit (saluti)

Codice: Seleziona tutto
=RANGO(BX;B$X:B$Y;1)+CONTA.SE(B$X:BX;BX)-1



Se il riferimento fossero le righe 2:1000

Codice: Seleziona tutto
=RANGO(B2;B$2:B$1000;1)+CONTA.SE(B$2:B2;B2)-1


Spero sia d'aiuto
---------------
Excel 2004 su Mac
Excel 2010 su Windows 8
CANAPONE
Utente Senior
 
Post: 430
Iscritto il: 22/11/10 15:43
Località: Firenze

Re: INCROCIO DI RIGHE E COLONNE

Postdi erryrox » 19/04/12 14:28

grazie Canapone per l'interessamento, ma purtroppo con la tua correzione non riesco a risolvere il problema.
Infatti in quel modo se ho due mesi uguali, non riesco ad ottenere un numero progressivo per i 2 mesi ma ottengo lo stesso numero incrementato di 1 per tutti e due.

PROBLEMA ATTUALE:
APR - 3
MAG - 4
GEN - 1
FEB - 2
FEB - 2
DIC - 5

COME VORREI CHE FOSSE:
APR - 4
MAG - 5
GEN - 1
FEB - 2
FEB - 3
DIC - 6

"METODO CANAPONE": :)
APR - 4
MAG - 5
GEN - 1
FEB - 3
FEB - 3
DIC - 6

Mi sto esaurendo dietro questo problema....HELP!!! :)
erryrox
Utente Junior
 
Post: 60
Iscritto il: 16/04/12 14:31

Re: INCROCIO DI RIGHE E COLONNE

Postdi wallace&gromit » 19/04/12 14:42

strano!
a me invece la formula di Canapone (contraccambio i saluti e sono lusingato che tu abbia utilizzato il mio modello senza dover estrarre dal cilindro qualche formula speciale) da esattamente il risultato voluto.
Prova a verificare i riferimenti.
Office2016 + 2019 su win11
Avatar utente
wallace&gromit
Utente Senior
 
Post: 2174
Iscritto il: 16/01/12 14:21

Re: INCROCIO DI RIGHE E COLONNE

Postdi erryrox » 19/04/12 15:13

ricontrollerò allora, ma nel frattempo ci ragiono un pò con voi, visto che non sono qui per copiare e incollare le formule che mi scrivere ma per creare uno scambio di conoscenze!

Se ipotizziamo di avere due mesi uguali, la funzione RANGO ci da lo stesso valore (e questo era il problema iniziale). Aggiungendo il CONTA.SE, quando N mesi hanno lo stesso valore, lui incrementa di N-1 tutti i mesi con lo stesso valore.

Il mio ragionamento sembra dar ragione al fatto che non mi funzioni, ma probabilmente mi sbaglio. Sarei grato se mi spiegate dove sbaglio! :)
erryrox
Utente Junior
 
Post: 60
Iscritto il: 16/04/12 14:31

Re: INCROCIO DI RIGHE E COLONNE

Postdi erryrox » 19/04/12 15:18

ragionando si arriva sempre alla soluzione :)

ho trovato il mio errore: avevo messo come intervallo del conta.se per ogni riga tutta la colonna!!

GRAZIE A TUTTI!!!!!!!!!!!!!!
erryrox
Utente Junior
 
Post: 60
Iscritto il: 16/04/12 14:31

Re: INCROCIO DI RIGHE E COLONNE

Postdi wallace&gromit » 05/06/12 13:49

riprendo questo topic e rilancio un approfondimento:
oltre al set di dati iniziale con possibili doppioni ho due altri set di dati che mi servono per risolvere gli ex-aequo.

Quindi alla funzione rango sulla colonna B dovrei aggiungere il rango della colonna C e in caso di ulteriore parità il rango della colonna D. Il tutto (e qui sta il bello) senza colonne d'appoggio!

Si può fare?
Office2016 + 2019 su win11
Avatar utente
wallace&gromit
Utente Senior
 
Post: 2174
Iscritto il: 16/01/12 14:21

Re: INCROCIO DI RIGHE E COLONNE

Postdi Anthony47 » 05/06/12 14:00

oltre al set di dati iniziale con possibili doppioni ho due altri set di dati che mi servono per risolvere gli ex-aequo.

Quindi alla funzione rango sulla colonna B dovrei aggiungere il rango della colonna C e in caso di ulteriore parità il rango della colonna D. Il tutto (e qui sta il bello) senza colonne d'appoggio!
Scusa, stai dicendo che per risolvere gli ex-aequo usi due colonne di appoggio??
Avatar utente
Anthony47
Moderatore
 
Post: 19196
Iscritto il: 21/03/06 16:03
Località: Ivrea

Re: INCROCIO DI RIGHE E COLONNE

Postdi Anthony47 » 05/06/12 14:14

Comunque uno screenshot dei tuoi dati potrebbe aiutare a capire correttamente...

Ciao
Avatar utente
Anthony47
Moderatore
 
Post: 19196
Iscritto il: 21/03/06 16:03
Località: Ivrea

Re: INCROCIO DI RIGHE E COLONNE

Postdi wallace&gromit » 05/06/12 15:04

Immagine
ecco lo screenshot con il rango inserito a mano.
Vorrei che lo calcolasse una sola formula.
Office2016 + 2019 su win11
Avatar utente
wallace&gromit
Utente Senior
 
Post: 2174
Iscritto il: 16/01/12 14:21

Re: INCROCIO DI RIGHE E COLONNE

Postdi CANAPONE » 05/06/12 16:39

Ciao

in E2 la formula


Codice: Seleziona tutto
=MATR.SOMMA.PRODOTTO(--((B2+C2/100+D2/1000)<($B$2:$B$6+$C$2:$C$6/100+$D$2:$D$6/1000)))+MATR.SOMMA.PRODOTTO(--($B$2:B2&$C$2:C2&$D$2:D2=B2&C2&D2))


nel caso tu avessi tutte le serie uguali, scrive 1 2 3 4 5

la formula

Codice: Seleziona tutto
=MATR.SOMMA.PRODOTTO(--((B2+C2/100+D2/1000)<($B$2:$B$6+$C$2:$C$6/100+$D$2:$D$6/1000)))+1


produrrebbe 1 1 1 1 1

Saluti
---------------
Excel 2004 su Mac
Excel 2010 su Windows 8
CANAPONE
Utente Senior
 
Post: 430
Iscritto il: 22/11/10 15:43
Località: Firenze

Re: INCROCIO DI RIGHE E COLONNE

Postdi wallace&gromit » 05/06/12 20:33

Magico Canapone!!!
funziona alla grande, adesso passerò il resto della serata a cercare di capire come fa a funzionare.
Office2016 + 2019 su win11
Avatar utente
wallace&gromit
Utente Senior
 
Post: 2174
Iscritto il: 16/01/12 14:21

Prossimo

Torna a Applicazioni Office Windows


Topic correlati a "INCROCIO DI RIGHE E COLONNE":


Chi c’è in linea

Visitano il forum: Gianca532011 e 37 ospiti