Condividi:        

[Excel] Conteggio giorni fra due date (con complicazione)

Vuoi potenziare i tuoi documenti Word? Non sai come si fa una macro in Excel? Devi creare una presentazione in PowerPoint?
Oppure sei passato a OpenOffice e non sei sicuro di come lavorare al meglio?

Moderatori: Anthony47, Flash30005

[Excel] Conteggio giorni fra due date (con complicazione)

Postdi Venerdi » 24/03/09 15:46

Un ciao a tutti :)

Nuova questioncina, per la quale effettivamente una soluzione sarei riuscito già a trovarla, ma in una maniera che trovo raccapricciante e che quindi evito di raccontare per la vergogna :undecided: . Cerco una soluzione più leggera ed elegante... :)

Gli elementi sono i seguenti:
Ho due colonne: data inizio e data fine.
Tutte le date sono comprese fra 01/01/2000 e 31/12/2015
A seguire queste due colonne, altre con intestazione dell'anno, ovvero... 2000, 2001, 2002 etc fino a 2015

Avrei necessità di avere per ciascun intervallo di date, il conteggio dei giorni che cadono in ciascun anno.

Esempio (ridotto)

Data_inizio...........Data_fine.............2007.... 2008....2009....2010....2011
15/5/2008..........18/09/2010..............0........231.....365......261.......0


Entrambi i giorni indicati dalle date, devono essere conteggiati.


Grazie anticipato

V.
Avatar utente
Venerdi
Utente Junior
 
Post: 63
Iscritto il: 18/03/02 20:05
Località: Roma

Sponsor
 

Re: [Excel] Conteggio giorni fra due date (con complicazione)

Postdi Venerdi » 24/03/09 16:03

dimenticavo...

Data inizio e data fine possono appartenere anche allo stesso anno. Lo preciso perchè questa cosa impediscce l'utilizzo di alcune soluzioni abbastanza semplici basate sulla funzione SE

V.
Avatar utente
Venerdi
Utente Junior
 
Post: 63
Iscritto il: 18/03/02 20:05
Località: Roma

Re: [Excel] Conteggio giorni fra due date (con complicazione)

Postdi Tribuno » 24/03/09 21:56

Ciao Venerdì,

le celle in riga 1 dove inserisci gli anni (da C1 a K1), formattale come data personalizzata, mettendo aaaa, poi scrivi per il 2007 31/12/2007, per il 2008 31/12/2008, ecc.
le celle da C2 a K2 formattale come numeri.

In C2 inserisci questa formula

=SE(E(ANNO(C$1)>=ANNO($A2);ANNO(C$1)<=ANNO($B2));SE(ANNO(C$1)=ANNO($A2);C$1-$A2+1;SE(ANNO(C$1)=ANNO($B2);$B2-DATA(ANNO($B2);1;1)+1;C$1-DATA(ANNO(C$1);1;1)+1));0)

trascinandola fino a cella K2.

Prova e fai sapere se va bene.

Ciao
Tribuno
Avatar utente
Tribuno
Utente Senior
 
Post: 181
Iscritto il: 22/08/08 19:24

Re: [Excel] Conteggio giorni fra due date (con complicazione)

Postdi pietrol » 25/03/09 01:46

Ciao Venerdì,
ti propongo un'alternativa alla soluzione di Tribuno (che saluto), funziona utilizzando la stessa impostazione indicata da lui per quanto riguarda le celle con gli anni
Codice: Seleziona tutto
=SE($B2>=DATA(ANNO(C$1);1;1);MIN(C$1;$B2)+1;DATA(ANNO(C$1);1;1))-SE($A2>=C$1;C$1+1;MAX($A2;DATA(ANNO(C$1);1;1)))

solo per dimostrare in excel che ci sono molte strade diverse per arrivare allo stesso punto e non bisogna mai scoraggiarsi.

ciao
pietrol
il lupo ululà, il castello ululì
pietrol
Utente Senior
 
Post: 270
Iscritto il: 07/01/09 14:34

Re: [Excel] Conteggio giorni fra due date (con complicazione)

Postdi Anthony47 » 25/03/09 10:56

Contribuisco anche io con queste due soluzioni:
-inizio/fine in A2/B2 e sottostanti
-in C1:K1 il solo anno (2000, 2001, etc)
-in C2 la formula
Codice: Seleziona tutto
=MATR.SOMMA.PRODOTTO(--(ANNO($A2-1+RIF.RIGA(INDIRETTO("1:"&$B2-$A2+1)))=C$2))

-oppure sempre in C2
Codice: Seleziona tutto
=(MIN(DATA(C$2;12;31);$B2)-MAX(DATA(C$2;1;1);$A2)+1)*($B2>=DATA(C$2;1;1))*($A2<=DATA(C$2;12;31)+1)

-copiare la formula su D2:K2, poi copiare C2:K2 verso il basso q.b.
Io preferisco la prima, e' piu' diretta.

Ciao.
Avatar utente
Anthony47
Moderatore
 
Post: 19196
Iscritto il: 21/03/06 16:03
Località: Ivrea

Re: [Excel] Conteggio giorni fra due date (con complicazione)

Postdi Anthony47 » 25/03/09 15:26

HO SBAGLIATO A POSTARE LE FORMULE: per provarle insieme con le soluzioni di Tribuno e pietrol avevo inserito l' intestazione dell' anno su riga 2 (cioe' C2:K2, mentre su riga 1 avevo inserito le date 31 dic xxxx necessarie per le soluzioni precedenti).
Se le intestazioni sono in C1:K1, le due formule sono rispettivamente
Codice: Seleziona tutto
=MATR.SOMMA.PRODOTTO(--(ANNO($A2-1+RIF.RIGA(INDIRETTO("1:"&$B2-$A2+1)))=C$1))
=(MIN(DATA(C$1;12;31);$B2)-MAX(DATA(C$1;1;1);$A2)+1)*($B2>=DATA(C$1;1;1))*($A2<=DATA(C$1;12;31)+1)

Le altre istruzioni sono sempre valide.

Ciao a tutti.
Avatar utente
Anthony47
Moderatore
 
Post: 19196
Iscritto il: 21/03/06 16:03
Località: Ivrea

Re: [Excel] Conteggio giorni fra due date (con complicazione)

Postdi Venerdi » 25/03/09 16:17

Grazie a tutti per le molteplici soluzioni proposte; siete come sempre molto gentili e disponibili.
Le provo tutte e vi faccio sapere.

V.
Avatar utente
Venerdi
Utente Junior
 
Post: 63
Iscritto il: 18/03/02 20:05
Località: Roma

Re: [Excel] Conteggio giorni fra due date (con complicazione)

Postdi Venerdi » 30/03/09 14:58

...tutte O.K...
Vi ringrazio... Immagine

V.
Avatar utente
Venerdi
Utente Junior
 
Post: 63
Iscritto il: 18/03/02 20:05
Località: Roma


Torna a Applicazioni Office Windows


Topic correlati a "[Excel] Conteggio giorni fra due date (con complicazione)":


Chi c’è in linea

Visitano il forum: Gianca532011, Marius44 e 57 ospiti