EXCEL macro somma tra piu' fogli

[rosy2]

ciao a tutti, sono nuova qui, una mia amica mi ha detto che qui ci sono delle persone che sanno tantissimo di Excel, mentre io sono un po' alle prime armi con le macro....
Posso chiedervi aiuto?

ho la necessita' di fare una somma della stessa cella (ad es. B5)presente su un centinaio di fogli nello stesso xls, e di posizionare il risultato in una cella (es. A1) del primo foglio. Il problema e' che non sempre devo sommare tutti i fogli, a volte solo i primi 30, a volte gli ultimi 45, etc. Per ora me la sono cavata con un ' istruzione tipo :

=SOMMA(Foglio3:Foglio1!B5)

modificando la formula ogni volta, ma sarebbe bello se potessi semplicemente selezionare piu' fogli, (quelli che mi interessa sommare) e poi chiamare una macro. Cosi' potrei anche selezionare dei fogli non continui (dal 1 al 23 e poi dal 30 al 45, ad es.)

Pensate che si possa fare o e' complicato?
Grazie mille per ogni aiuto e suggerimento!

[ricky53]

Ciao Rosy,
prima di tutto benvenuta nel nostro forum.

Veniamo al tuo quesito: la tua effettiva necessità è solo quella di sommare la stessa cella di tutti i fogli selezionati di un tuo file excel ed i fogli selezionati cambiano di volta in volta ?

Che versione di Office utilizzi?
Conosci la programmazione?
Conosci il VBA?


Commento: con excel si può fare quasi tutto ma occorre avere chiare le necessità e ...

[rosy2]

Grazie ricky53!

si, la cella da sommare e' sempre la stessa, ma i fogli sono sempre diversi, a volte dall'1 al 30 (i fogli hanno nomi diversi) a volte devo sommarne solo alcuni, ad es il foglio 23 , il foglio 34 e i fogli dal 57 in poi... quindi forse la cosa piu' comoda e' selezionare tutti e solo i fogli che dovrei sommare..

le altre domande: ho Office 2003 in ufficio
Non so scrivere un programma in Visual basic, sto imparando a usare le macro in excel.

Grazie

[ricky53]

Ciao,
mi sfugge l'utilizzo che si può fare di questa somma della stessa cella dei vari fogli ...

Comunque io, in un foglio "Riepilogo", riporterei in colonna "A" il nome del foglio e in colonna "B" il contenuto della cella "B5" del corrispondente foglio e poi in una colonna di appoggio (es. "C") scriverei "SI" in corrispondenza del nome del foglio da considerare nella somma e poi con il filtro filtrerei per "SI" nella colonna "C" ed infine, in colonna "B", inserirei la funzione "SUBTOTALE" e .... il gioco è fatto.

Manca solo il primo passo: riportare i dati dei vari fogli nel foglio "Riepilogo" che si può fare con del codice VBA


A proposito VBA non è il Visual Basic classico ma è un Visual Basic specifico per Office.

[ricky53]

Ciao,
quanto ti avevo scritto nel mio precedente intervento si può tradurre in questo modo

Codice: Seleziona tutto

Option Explicit
Sub Elabora_Dati()
    Dim WS As Worksheet, FGL As Worksheet, I As Integer, UR As Integer
   
    I = 2
    Set FGL = Sheets("Riepilogo")
    FGL.Select
    Cells.AutoFilter Field:=1, Criteria1:="<>"
    ActiveSheet.ShowAllData
   
    FGL.Cells.ClearContents
    FGL.[A1] = "Nome Foglio"
    FGL.[B1] = "Valore contenuto in B5"
    For Each WS In Worksheets
        FGL.Cells(I, 1) = WS.Name
        FGL.Cells(I, 2) = WS.[B5]
        I = I + 1
    Next WS
    Set FGL = Nothing
    UR = Range("A" & Rows.Count).End(xlUp).Row
    Cells(UR + 2, 2).FormulaR1C1 = "=SUBTOTAL(9,R[" & -UR & "]C:R[-2]C)"
    Cells.AutoFilter
End Sub

[Anthony47]

Credo che l' approccio suggerito da Ricky (vedi sopra), che porta tutti i dati che ti interessano su uno stesso foglio dove poi spunti cosa vuoi sommare e cosa no, sia vantaggioso e dovresti valutarne l' adozione.
Se invece ti interessa rimanere sulla selezione dei fogli, allora prova con questa macro:

Codice: Seleziona tutto

Sub multisum()
Addend = "B5"    '<< Le celle da sommare
Set Result = Sheets("Foglio1").Range("A2") '<< Foglio/Cella del risultato
For Each Ws In ActiveWindow.SelectedSheets
    mySum = mySum + Ws.Range(Addend).Value
Next Ws
Result.Value = mySum
End Sub


Ciao a tutti.

[rosy2]

grazie mille ricky53 e Anthony47!

siete stati gentilissimi, ho utilizzato la macro di Anthony47 perche' mi risultava piu' immediato l'utilizzo, e funziona alla grandissima... la macro di ricky53 la studio domani con calma cosi' imparo cose nuove sulle macro.... intanto grazie ancora tantissimo a tutti e due per l'aiuto!!

[ricky53]

Ciao,
io ti avevo proposto una soluzione alternativa alla tua richiesta facendoti vedere i dati contenuti nei vari fogli e poi consentendoti di sommare i dati desiderati sfruttando il "Filtro" ...
Attendo i risultati delle tue prove

Anthony (un caro saluto) dal canto suo ti ha proposto quanto avevi chiesto che come hai detto tu è di più immediato utilizzo.

[rosy2]

Ciao ricky53,

ho fatto le prove e la tua macro che crea un riepilogo funziona molto bene, grazie!

Posso farti una domanda? alla fine della macro la colonna "C" , quella con l'indicativo della scelta del foglio, viene ripulita. come potrei fare per mantenere il "si" che ho inserito prima?

Grazie mille ancora sia a te che an Anthony47 per l'aiuto e la pazienza

[ricky53]

Caio,
le colonne vengono "ripulite" ad inizio macro con l'istruzione

Codice: Seleziona tutto

FGL.Cells.ClearContents

Tu vuoi conservare i dati di tutte e tre le colonne?
Se la risposta è "SI" allora cancella questa istruzione dalla macro, altrimenti ... sono QUI.