[vba2003] scrivere su foglio nascosti

[karug64]

Salve a tutti.
Nella mia cartella ho vari fogli di appoggio per elaborazioni (che all'utente non interessano). Se provo a nasconderli quando cerco di effettuare operazioni del tipo sheets("Foglio_app1").select ricevo errore.
C'e' un sistema per poter operare su quelli nascosti senza dover ogni volta "scoprirli" e poi nasconderli ?
Grazie

[Anthony47]

Nella stragrande maggioranza dei casi la ".Select" non e' necessaria; ad esempio puoi benissimo scrivere

Codice: Seleziona tutto

Sheets("FoglioNascosto").Range("A2").Value = Valore


Tu che operazione vorresti fare?

Ciao

[karug64]

Nella stragrande maggioranza dei casi la ".Select" non e' necessaria; ad esempio puoi benissimo scrivere

Codice: Seleziona tutto

Sheets("FoglioNascosto").Range("A2").Value = Valore


Tu che operazione vorresti fare?

Ciao

Ciao.
Utilizzo il codice postato a suo tempo da flash3005 presente in questa discussione
http://www.pc-facile.com/forum/viewtopic.php?f=26&t=82607

Tutti e quattro i fogli possono essere tranquillamente nascosti all'utente.

Ciao

[Anthony47]

Mi hai linkato una discussione che comincia a Ottobre 2009 e finisce a Febbraio 2011; un riferimento un po' vago...
Se non arrivano altri suggerimenti ti chiederei di pubblicare un file esemplificativo contenente la macro in uso.

Ciao

[karug64]

Mi hai linkato una discussione che comincia a Ottobre 2009 e finisce a Febbraio 2011; un riferimento un po' vago...
Se non arrivano altri suggerimenti ti chiederei di pubblicare un file esemplificativo contenente la macro in uso.

Ciao

Scusa. Il codice che utilizzo e che dovrei adattare e' questo:

Codice: Seleziona tutto

[code]
    Sub Confronta()
    ' Foglio1 Vecchio Catalogo
    ' Foglio2 Nuovo Catalogo
    ' Foglio3 Prodotti che non sono più nel nuovo catalogo
    ' Foglio4 Nuovi prodotti (non erano nel vecchio catalogo)
    Call CopiaF
    URS = Worksheets("Foglio1").Range("A" & Rows.Count).End(xlUp).Row   '<<<< alias Foglio3
    URA = Worksheets("Foglio2").Range("A" & Rows.Count).End(xlUp).Row  '<<< alias Foglio4
    For RS = 2 To URS
        For RA = URA To 2 Step -1
            If Worksheets("Foglio1").Cells(RS, 1).Value = Worksheets("Foglio4").Cells(RA, 1).Value Then Worksheets("Foglio4").Rows(RA & ":" & RA).Delete
        Next RA
    Next RS
    For RA = 2 To URA
        For RS = URS To 2 Step -1
            If Worksheets("Foglio2").Cells(RA, 1).Value = Worksheets("Foglio3").Cells(RS, 1).Value Then Worksheets("Foglio3").Rows(RS & ":" & RS).Delete
        Next RS
    Next RA
    End Sub
    Sub CopiaF()
        Sheets("Foglio3").Select
        Cells.Select
        Selection.Clear
        Range("D10").Select
        Sheets("Foglio4").Select
        Cells.Select
        Selection.Clear
        Range("A1").Select
        Sheets("Foglio1").Select
        Cells.Select
        Selection.Copy
        Sheets("Foglio3").Select
        Cells.Select
        ActiveSheet.Paste
        Range("A1").Select
        Sheets("Foglio2").Select
        Cells.Select
        Application.CutCopyMode = False
        Selection.Copy
        Sheets("Foglio4").Select
        Range("A1").Select
        ActiveSheet.Paste
        Range("A1").Select
        Sheets("Foglio3").Select
    End Sub[/code]

Grazie

[Anthony47]

Prova a sostituire la tua Sub CopiaF con questa:

Codice: Seleziona tutto

Sub CopiaF()
Sheets("Foglio3").Cells.Clear
Sheets("Foglio4").Cells.Clear
Sheets("Foglio1").Cells.Copy Destination:=Sheets("Foglio3").Range("A1")
Sheets("Foglio2").Cells.Copy Destination:=Sheets("Foglio4").Range("A1")
End Sub


Ciao