Valutazione 4.87/ 5 (100.00%) 5838 voti

Condividi:        

Somma numeri tra loro (?)

Vuoi potenziare i tuoi documenti Word? Non sai come si fa una macro in Excel? Devi creare una presentazione in PowerPoint?
Oppure sei passato a OpenOffice e non sei sicuro di come lavorare al meglio?

Moderatori: Anthony47, Flash30005

Somma numeri tra loro (?)

Postdi luigi99 » 23/06/11 00:55

Scusate il titolo...
Devo sommare i numeri di 5 caselle fra loro:
b+c c+d d+e e+f
b+d c+e d+f
b+e c+f
b+f
ho provato a unire questa:
SE(RESTO((b+c;90)=0;90;RESTO((b+c);90)):SE ecc. ecc. e ho condizionato la casella per evidenziare se il risultato ero quello aspettato: 25
ma chiaramente non funziona!!!!
Visto che devo evidenziare se il risultato di una delle somme è 25 ho tentato con somma se.....ma non vengo a capo di niente!!
'notte
Luigi
ex Autodidatta, ma ancora in cerca di grane con il computer
luigi99
Utente Senior
 
Post: 563
Iscritto il: 21/11/01 01:00
Località: Vigliano Biellese

Sponsor
 

Re: Somma numeri tra loro (?)

Postdi Anthony47 » 23/06/11 09:17

Si potrebbe fattorizzare il 25, oppure usare la serie di Taylor o, potendo semplificare, lo sviluppo di Mac Laurin.
Anthony
Win7 + Office 2010 Ita; Win 7 + Office 2013 Ita
Xp + Office 2003 Ita
E voi cosa usate? (per istruzioni vedere viewtopic.php?f=26&t=97449)
Avatar utente
Anthony47
Moderatore
 
Post: 13899
Iscritto il: 21/03/06 16:03
Località: Ivrea

Re: Somma numeri tra loro (?)

Postdi luigi99 » 23/06/11 10:34

Anthony47 ha scritto:Si potrebbe fattorizzare il 25, oppure usare la serie di Taylor o, potendo semplificare, lo sviluppo di Mac Laurin.


Antony, ormai mi conosci (ti ho rotto le scatole così tanto che.... :D ), ma potresti parlare italiano?

Come applico questa: T(x) = \sum_{n=0}^{\infin} \frac{f^{(n)}(a)}{n!} (x-a)^{n}. :eeh: :eeh: del caro Tylor
o questa: f(0) + f'(0)x + f"(0)x2/2! + f'''(0)x3/3! + ... + f(n)(0)xn/n! :cry: :cry: dell'ancor più caro Mac Laurin ? (sempre che siano quelle che intendi tu :?: :?: )

A parte gli scherzi, ho comprato "Funzioni con Excel" di Craig Stinson e Dodge della Mondadori, ma anche qui non capisco come arrivare alla soluzione.
Attendo fiducioso :lol: :lol: .
Luigi
ex Autodidatta, ma ancora in cerca di grane con il computer
luigi99
Utente Senior
 
Post: 563
Iscritto il: 21/11/01 01:00
Località: Vigliano Biellese

Re: Somma numeri tra loro (?)

Postdi Flash30005 » 23/06/11 11:07

Se ho capito bene vorresti la somma delle possibili combinazioni tra due di questi 5 numeri (combinazioni totali = 10)

Supponendo che tu abbia i numeri in B1, C1, D1, E1, F1
In H1 inserisci questa formula
Codice: Seleziona tutto
=SE(RESTO($B1+C1;90)=0;90;RESTO($B1+C1;90))

Trascinala fino a K1
poi in J1 inserisci
Codice: Seleziona tutto
=SE(RESTO($C1+D1;90)=0;90;RESTO($C1+D1;90))

Trascia fino a N1
poi in O1 inserisci questa formula
Codice: Seleziona tutto
=SE(RESTO($D1+E1;90)=0;90;RESTO($D1+E1;90))

trascini fino a P1
in Q1 inserisci
Codice: Seleziona tutto
=SE(RESTO($E1+F1;90)=0;90;RESTO($E1+F1;90))

Formatti queste 10 celle (H1:Q1) con la formattazione condizionale che, in caso di valore 25, colori la cella

Ciao
Flash
Win7 + Office 2010 Ita
"Fotografica" al servizio dell'immagine

Ottime opportunità di lavoro (part-time o full-time) con guadagni immediati. Info in MP
Avatar utente
Flash30005
Moderatore
 
Post: 8460
Iscritto il: 27/09/07 11:44
Località: Roma +o-

Re: Somma numeri tra loro (?)

Postdi Anthony47 » 23/06/11 12:56

luigi99 ha scritto:Attendo fiducioso :lol: :lol:
Eh no, stavolta ti deludo... Diciamo che ho dato una risposta incomprensibile :diavolo: a un quesito incomprensibile :D
Quindi se Flash non ha indovinato il quesito e la risposta allora devi spiegare bene bene. Diciamo che io mi sono sconfuso molto guardando il come hai provato a risolvere l' arcano...

Ciao!
Anthony
Win7 + Office 2010 Ita; Win 7 + Office 2013 Ita
Xp + Office 2003 Ita
E voi cosa usate? (per istruzioni vedere viewtopic.php?f=26&t=97449)
Avatar utente
Anthony47
Moderatore
 
Post: 13899
Iscritto il: 21/03/06 16:03
Località: Ivrea

Re: Somma numeri tra loro (?)

Postdi luigi99 » 24/06/11 23:32

Anthony47 ha scritto:
luigi99 ha scritto:Attendo fiducioso :lol: :lol:
Eh no, stavolta ti deludo... Diciamo che ho dato una risposta incomprensibile :diavolo: a un quesito incomprensibile :D
Quindi se Flash non ha indovinato il quesito e la risposta allora devi spiegare bene bene. Diciamo che io mi sono sconfuso molto guardando il come hai provato a risolvere l' arcano...

Ciao!

Figurati...e io che pensavo di aver spiegato benissimo il problema :eeh: :eeh:
Devo dire che Flash, ha capito il problema, ma io volevo una soluzione che non mi occupasse 10 celle (avrei potuto inserire 10 formule/combinazioni in 10 celle).
Ecco perchè ho cercato di concatenare diversi SE e CONTA in una casella sola dove avrebbe dovuto apparire il risultato. Formattando quell'unica cella se il risultato fosse stato quello voluto.
Ma forse per una cosa così bisogna ricorrere al VBA?
Ciao e buonanotte.
Luigi.
ex Autodidatta, ma ancora in cerca di grane con il computer
luigi99
Utente Senior
 
Post: 563
Iscritto il: 21/11/01 01:00
Località: Vigliano Biellese

Re: Somma numeri tra loro (?)

Postdi Flash30005 » 25/06/11 07:17

Vorrei capire solo una cosa

Vorresti la somma di tutte le combinazioni in una unica cella?

Perché se vuoi questo è sufficiente questa formula
Codice: Seleziona tutto
=SE(RESTO(SOMMA(B1:F1)*4;90)=0;90;RESTO(SOMMA(B1:F1)*4;90))


Fai sapere
Ciao
Flash
Win7 + Office 2010 Ita
"Fotografica" al servizio dell'immagine

Ottime opportunità di lavoro (part-time o full-time) con guadagni immediati. Info in MP
Avatar utente
Flash30005
Moderatore
 
Post: 8460
Iscritto il: 27/09/07 11:44
Località: Roma +o-

Re: Somma numeri tra loro (?)

Postdi luigi99 » 26/06/11 22:25

no, vorrei che fosse fatta la somma 2 a 2 (10 combinazioni), ma che venisse evidenziata se una delle somme è 25 (ma potrebbe essere anche 50 o 33!!!).
Per questo avevo tentato concatenando i diversi SE.. ma poi ho capito che se anche se ci fossi riuscito non avrei potuto superare il limite delle 7 nidificazioni che penso si applichi anche a questo caso.
Per ora ho condizionato 10 celle con dieci formule....se poi mi giunge un'altra soluzione Immagine
'notte.
Luigi
ex Autodidatta, ma ancora in cerca di grane con il computer
luigi99
Utente Senior
 
Post: 563
Iscritto il: 21/11/01 01:00
Località: Vigliano Biellese

Re: Somma numeri tra loro (?)

Postdi Anthony47 » 26/06/11 23:31

Non so se puo' essere di tuo interesse, ma questa formula ti potrebbe dire quante coppie rispecchiano la condizione impostata in G1:
Codice: Seleziona tutto
=SOMMA(--(RESTO(((B2:F2)+MATR.TRASPOSTA(B2:F2))*((B2:F2)<>MATR.TRASPOSTA(B2:F2));90)=G1))/2
Da confermare con Contr-Maiusc-Enter; considera i 5 numeri in B2:F2
Mentre puoi vedere quali sono le coppie impostando una formattazione condizionale su B2:F2 con Condizione1=La formula è, e con questa formula
Codice: Seleziona tutto
=SOMMA(--(RESTO(((B2)+MATR.TRASPOSTA($B2:$F2))*((B2)<>MATR.TRASPOSTA($B2:$F2));90)=$G$1))>0
Sempre Contr-Maiusc-Enter
Per "rispecchiano la condizione" intendo "sommando i due numeri con Modulo 90 danno il valore in G1", che e' la mia migliore interpretazione del problema.

Ciao
Anthony
Win7 + Office 2010 Ita; Win 7 + Office 2013 Ita
Xp + Office 2003 Ita
E voi cosa usate? (per istruzioni vedere viewtopic.php?f=26&t=97449)
Avatar utente
Anthony47
Moderatore
 
Post: 13899
Iscritto il: 21/03/06 16:03
Località: Ivrea

Re: Somma numeri tra loro (?)

Postdi Flash30005 » 26/06/11 23:38

A questo punto potresti usare questa formula
Codice: Seleziona tutto
=SE(O(SE(B1+C1>90;B1+C1-90;B1+C1)=25;SE(B1+D1>90;B1+D1-90;B1+D1)=25;SE(B1+E1>90;B1+E1-90;B1+E1)=25;SE(B1+F1>90;B1+F1-90;B1+F1)=25;SE(C1+D1>90;C1+D1-90;C1+D1)=25;SE(C1+E1>90;C1+E1-90;C1+E1)=25;SE(C1+F1>90;C1+F1-90;C1+F1)=25;SE(D1+E1>90;D1+E1-90;D1+E1)=25;SE(D1+F1>90;D1+F1-90;D1+F1)=25;SE(E1+F1>90;E1+F1-90;E1+F1)=25)=VERO;25;"")


Ciao
Flash
Win7 + Office 2010 Ita
"Fotografica" al servizio dell'immagine

Ottime opportunità di lavoro (part-time o full-time) con guadagni immediati. Info in MP
Avatar utente
Flash30005
Moderatore
 
Post: 8460
Iscritto il: 27/09/07 11:44
Località: Roma +o-

Re: Somma numeri tra loro (?)

Postdi luigi99 » 27/06/11 12:07

Flash30005 ha scritto:A questo punto potresti usare questa formula
Codice: Seleziona tutto
=SE(O(SE(B1+C1>90;B1+C1-90;B1+C1)=25;SE(B1+D1>90;B1+D1-90;B1+D1)=25;SE(B1+E1>90;B1+E1-90;B1+E1)=25;SE(B1+F1>90;B1+F1-90;B1+F1)=25;SE(C1+D1>90;C1+D1-90;C1+D1)=25;SE(C1+E1>90;C1+E1-90;C1+E1)=25;SE(C1+F1>90;C1+F1-90;C1+F1)=25;SE(D1+E1>90;D1+E1-90;D1+E1)=25;SE(D1+F1>90;D1+F1-90;D1+F1)=25;SE(E1+F1>90;E1+F1-90;E1+F1)=25)=VERO;25;"")


Ciao

Flash....un nome un destino :D :D
hai centrato il problema, devo solo modificare la formula perchè i dati sono in un altro foglio, ma funziona benissimo!!!!!!!!!!!! :lol: :lol: :lol:
Quella di Anthony invece mi può servire per appurare proprio se ci sono due coppie che danno lo stesso risultato :)
Due piccioni con una fava ;)
Grazie a tutti e due 8) 8)
Luigi

p.s.=non voglio farvi perdere tempo più del dovuto, ma qualche volta mi piacerebbe capire il senso delle formule :oops:
come posso fare per arrivarci?
Mi spiego: B1+C1>90;B1+C1-90=25 dovrebbe essere: se 50+60 è maggiore di 90, allora restituisci 50+60-90, se uguale a 25 restituisci 25.
Ma a questa: SOMMA(--(RESTO(((B2:F2)+MATR.TRASPOSTA(B2:F2))*((B2:F2)<>MATR.TRASPOSTA(B2:F2));90)=G1))/2
non ci arrivo :oops:
Funzioni con Excel che ho non aiuta molto negli adattamenti delle formule (o, mi ripeto, sono io che non ci arrivo)
ex Autodidatta, ma ancora in cerca di grane con il computer
luigi99
Utente Senior
 
Post: 563
Iscritto il: 21/11/01 01:00
Località: Vigliano Biellese

Re: Somma numeri tra loro (?)

Postdi Anthony47 » 28/06/11 01:19

Con tutto il rispetto dovuto alla tastiera di Flash, se vuoi vedere “25” nel caso ci sia una corrispondenza, puoi usare
Codice: Seleziona tutto
=se(SOMMA(--(RESTO(((B2:F2)+MATR.TRASPOSTA(B2:F2))*((B2:F2)<>MATR.TRASPOSTA(B2:F2));90)=G1))>1;25;"")
(La formula in realta' confronta col vaore scritto in G1 e quindi come risultato non riporta "25" ma il valore contenuto in G1)

In quanto al significato della mia formula:
((B2:F2)+MATR.TRASPOSTA(B2:F2)) somma ognuno dei termini in B2:F2 con tutti gli altri (quindi 25 somme)
*((B2:F2)<>MATR.TRASPOSTA(B2:F2)) annulla le somma tra gli stessi termini (B2+B2, C2+C2, etc)
Si calcola il "Resto" col divisore 90 e si confronta con l' ipotetico 25 in G1
Poiche' si calcola sia B2+C2 che C2+B2 il risultato va diviso per 2

Piu' chiaro, vero?

Ciao
Anthony
Win7 + Office 2010 Ita; Win 7 + Office 2013 Ita
Xp + Office 2003 Ita
E voi cosa usate? (per istruzioni vedere viewtopic.php?f=26&t=97449)
Avatar utente
Anthony47
Moderatore
 
Post: 13899
Iscritto il: 21/03/06 16:03
Località: Ivrea

Re: Somma numeri tra loro (?)

Postdi luigi99 » 28/06/11 11:58

CHIARISSIMO :( :( :( :eeh: :eeh:
a parte gli scherzi, il risultato che ottengo è: #VALORE!
Chiedendo: Mostra passaggi del calcolo - Valuta ho come primo passaggio:
SE(SOMMA(--(RESTO(((#VALORE!)+MATR.TRASPOSTA(B2:F2))*(B2:F2)<>MATR.TRASPOSTA(B2:F2));90=G1>1:25;"")
poi l'indicazione: #VALORE! si sposta sempre al posto di (B2:F2)....
può essere che i numeri delle caselle B2-F2 sono ripresi da un'altro foglio? oppure che inserisco la formula in una casella sbagliata? o ancora che la casella G1 è vuota (ma anche se ci scrivo 25 non cambia niente)?
dove sta l'inghippo?
Buon appetito.
Luigi
ex Autodidatta, ma ancora in cerca di grane con il computer
luigi99
Utente Senior
 
Post: 563
Iscritto il: 21/11/01 01:00
Località: Vigliano Biellese

Re: Somma numeri tra loro (?)

Postdi Anthony47 » 28/06/11 12:43

Probabilmente non hai usato Contr-Maiusc-Enter, come avevo detto la volta prima ma non avevo ripetuto ieri sera.

Inoltre la formula che ti ho segnato confronta con G1 ma poi scrive "25"; una versione piu' lineare e' questa:
Codice: Seleziona tutto
=SE(SOMMA(--(RESTO(((B2:F2)+MATR.TRASPOSTA(B2:F2))*((B2:F2)<>MATR.TRASPOSTA(B2:F2));90)=G1))>1;G1;"")

ANCORA Contr-Maiusc-Enter.

Ciao
Anthony
Win7 + Office 2010 Ita; Win 7 + Office 2013 Ita
Xp + Office 2003 Ita
E voi cosa usate? (per istruzioni vedere viewtopic.php?f=26&t=97449)
Avatar utente
Anthony47
Moderatore
 
Post: 13899
Iscritto il: 21/03/06 16:03
Località: Ivrea

Re: Somma numeri tra loro (?)

Postdi luigi99 » 29/06/11 10:59

Anthony47 ha scritto:Probabilmente non hai usato Contr-Maiusc-Enter, come avevo detto la volta prima ma non avevo ripetuto ieri sera.

Inoltre la formula che ti ho segnato confronta con G1 ma poi scrive "25"; una versione piu' lineare e' questa:
Codice: Seleziona tutto
=SE(SOMMA(--(RESTO(((B2:F2)+MATR.TRASPOSTA(B2:F2))*((B2:F2)<>MATR.TRASPOSTA(B2:F2));90)=G1))>1;G1;"")

ANCORA Contr-Maiusc-Enter.

Ciao

non ho usato Contr-Maiusc-Enter per disattenzione :oops: :oops: , ma anche adesso non riesco a capire quando usarlo!!!
Appena copio la formula in una casella esce #VALORE......e poi la sequenza non da effetti.
Ho provato a usarlo in fase di copiatura, ma chiaramente non ha esito.
Scusa se ho la testa dura, ma sul libro non ho trovato spiegazioni sulla sequenza di tasti.
Ciao
ex Autodidatta, ma ancora in cerca di grane con il computer
luigi99
Utente Senior
 
Post: 563
Iscritto il: 21/11/01 01:00
Località: Vigliano Biellese

Re: Somma numeri tra loro (?)

Postdi Anthony47 » 29/06/11 11:54

Prova a copiare il testo della formula all' interno della "barra della formua" (l' area sopra le intestazioni di colonna dove viene replicato quello che scrivi nella cella); quando il testo e' ok, non pigiare Enter (o come si chiama sulla tua tastiera), ma premi prima Contr, poi Maiusc, poi clicca Enter, poi rilasci Contr e Maiusc.
Nella barra della formula vedrai la formula racchiusa tra parentesi graffe.

Oppure, se il testo e' gia' nella cella: seleziona cella, F2 (edit), poi Contr-Maiusc-Enter.

Per curiosita' segui come la formula viene elaborata tramite "Valuta formula".

Questa modalita' va usata per le "formule a matrice", dove cioe' non viene elaborato 1 solo dato ma un insieme di dati.

Ciao
Anthony
Win7 + Office 2010 Ita; Win 7 + Office 2013 Ita
Xp + Office 2003 Ita
E voi cosa usate? (per istruzioni vedere viewtopic.php?f=26&t=97449)
Avatar utente
Anthony47
Moderatore
 
Post: 13899
Iscritto il: 21/03/06 16:03
Località: Ivrea

Re: Somma numeri tra loro (?)

Postdi luigi99 » 29/06/11 17:24

c'era anche nel libro come fare :D , solo che era al termine del capitolo che tratta le matrici e io non l'ho letto fino in fondo :oops: :oops:
ora funziona!!!
scusa, potevo evitare 8) 8)
Ciao.
ex Autodidatta, ma ancora in cerca di grane con il computer
luigi99
Utente Senior
 
Post: 563
Iscritto il: 21/11/01 01:00
Località: Vigliano Biellese


Torna a Applicazioni Office Windows


Topic correlati a "Somma numeri tra loro (?)":


Chi c’è in linea

Visitano il forum: Nessuno e 6 ospiti

cron