Valutazione 4.87/ 5 (100.00%) 5838 voti

Condividi:        

[EXCEL] Macro complessa per ricerca e compilazione

Vuoi potenziare i tuoi documenti Word? Non sai come si fa una macro in Excel? Devi creare una presentazione in PowerPoint?
Oppure sei passato a OpenOffice e non sei sicuro di come lavorare al meglio?

Moderatori: Anthony47, Flash30005

[EXCEL] Macro complessa per ricerca e compilazione

Postdi Bruder » 06/06/11 18:46

Buongiorno a tutti,
sono nuovo del forum e scrivo perchè sono (purtroppo) completamente ignorante in materia di programmazione. Non conosco la sintassi di VBA e devo scrivere una macro abbastanza complicata (per me).

So che non è carino piombare dal nulla e chiedere favori ma tant'è :undecided:
Le operazione che ho bisogno di eseguire sono, in sequenza, le seguenti:

Supponiamo di avere un classico file con 3 fogli.

FASE1: partendo dalla riga "2" di "Foglio1" esegui le seguenti operazioni

leggi un codice alfanumerico (formattato come testo) riportato in colonna "E"
leggi una quantità (formattata come numero) riportato in colonna "J"
leggi una data (formattata come data) riportato in colonna "M"
passa alla FASE successiva


FASE2: partendo dalla riga "2" di "Foglio2 esegui i seguenti CHECK

CHECK1: confronta il codice alfanumerico di "Foglio1" con un altro codice alfanumerico (formattato come testo) riportato in colonna "L"
se il codice non corrisponde, prosegui nella "scansione" passando alla riga successiva e ripetendo il CHECK1
se corrisponde passa al CHECK successivo
CHECK2: calcola la differenza tra il valore della colonna "X" meno il valore della colonna "Z" della riga di "Foglio2" che ha superato CHECK1
formatta come numero il valore ottenuto dalla differenza (i due valori in "X" e "Z" sono formattati come testo)
confronta la quantità di "Foglio1" con la differenza appena calcolata
se le due quantità non corrispondono, prosegui nella "scansione" passando alla riga successiva e ripartendo da CHECK1
se corrispondono passa al CHECK successivo
CHECK3: se la riga che rispetta sia CHECK1 che CHECK2 è già stata "usata", passa alla riga successiva e riparti da CHECK1
(mi spiego: se su "Foglio1" esistono due combinazioni codice/quantità uguali, anche su "Foglio2" ci saranno due combinazioni codice/quantità uguali. Ciò che voglio evitare è che la macro stupidamente, leggendo il foglio dall'alto verso il basso, finisca con l'assegnare sempre il primo risultato valido trovato ignorando gli altri)
se la riga non è stata mai "usata" esegui le seguenti operazioni

leggi un codice numerico (formattato come testo) riportato in colonna "C"
leggi un codice numerico (formattato come testo) riportato in colonna "D"
passa alla FASE successiva


FASE3: partendo dalla riga "2" di "Foglio3" esegui le seguenti operazioni

scrivi in colonna "A" il codice numerico letto in colonna "C" al punto sopra
scrivi in colonna "B" il codice numerico letto in colonna "D" al punto sopra
scrivi in colonna "C" la data del Martedì della settimana successiva rispetto alla settimana in cui cade la data di "Foglio1"
formatta la data suddetta come testo e nel seguente modo "ggmmaaaa" (es. 10/06/2011 deve diventare 10062011)

FASE4: riparti da FASE1, questa volta leggi le informazioni presenti sulla riga "3" di "Foglio1"
la FASE2 riparte sempre dalla riga "2"
la FASE3 riparte invece dalla riga "3"

FASE5: il ciclo termina nel momento in cui incontro la prima cella vuota della colonna "E" di "Foglio1"


NOTA: se un codice non dovesse avere corrispondenze non voglio che lo script si blocchi, ma che semplicemente questo passi al codice successivo.


Perdonate il WOT, spero di essere stato abbastanza chiaro. Per riassumere: voglio che in maniera iterativa la macro prenda il codice sul foglio1 e cerchi una corrispondenza sul foglio2, se il codice corrisponde controllo la quantità, se la quantità corrisponde prelevo 3 celle con i dati veri e propri dalle righe di foglio1 e foglio2 interessate e li copio su foglio3. Attenzione ai valori doppi, ad ogni combinazione codice/quantità di foglio2 deve corrispondere una sola combinazione codice/quantità di foglio1 e viceversa.

Tanta tanta tanta ma tanta tanta stima ed ammirazione a chi saprà aiutarmi o per lo meno indirizzarmi sulla strada giusta.

Graziegraziegrazie!!


Bruder
Bruder
Utente Junior
 
Post: 29
Iscritto il: 06/06/11 18:30

Sponsor
 

Re: [EXCEL] Macro complessa per ricerca e compilazione

Postdi Avatar3 » 06/06/11 19:28

Ho letto con tanto tanto tanto ma tanto interesse ciò che hai scritto ma
per quanta volontà e pazienza abbia (tanta tanta tanta ma tanta) :D
mi risulta difficile poter simulare uno schema dei dati origine come li hai tu e, vista la complessità, vorrei evitare di rimettere le mani su un progetto mal impostato.
Se puoi invia il file (o facsimile senza dati sensibili) e qualche esempio esaustivo
Per il funzionamento delle macro si deve impostare la protezione a Bassa o Media.
Menu Strumenti -> Macro -> Protezione...
Avatar utente
Avatar3
Utente Senior
 
Post: 569
Iscritto il: 04/04/11 09:04

Re: [EXCEL] Macro complessa per ricerca e compilazione

Postdi Bruder » 06/06/11 20:37

Un esempio vale più di mille parole come al solito! :D

Domani mattina posto un file excel di come sono strutturati i dati e di come vorrei venissero fuori.

Intanto grazie per l'attenzione!!
Bruder
Utente Junior
 
Post: 29
Iscritto il: 06/06/11 18:30

Re: [EXCEL] Macro complessa per ricerca e compilazione

Postdi Avatar3 » 06/06/11 20:40

Da regolamento, sembra che, devi avere almeno tre post per inviare un link procurabile seguendo la procedura riportata
qui
http://www.pc-facile.com/forum/viewtopic.php?f=26&t=80395
Per il funzionamento delle macro si deve impostare la protezione a Bassa o Media.
Menu Strumenti -> Macro -> Protezione...
Avatar utente
Avatar3
Utente Senior
 
Post: 569
Iscritto il: 04/04/11 09:04

Re: [EXCEL] Macro complessa per ricerca e compilazione

Postdi Bruder » 07/06/11 07:24

Quindi sono costretto a scrivere un terzo messagio di puro spam solo per poter essere abilitato all'inserimento di file?

Ops.. :roll:
Bruder
Utente Junior
 
Post: 29
Iscritto il: 06/06/11 18:30

Re: [EXCEL] Macro complessa per ricerca e compilazione

Postdi Bruder » 07/06/11 08:30

https://rapidshare.com/files/1167268985/Esempio.xlsx

Allora, sopra trovate il link al file d'esempio da scaricare.
Ci sono tutte le informazioni essenziali.
Su Foglio1 c'e' anche una riga, evidenziata in rosso, che non ha alcuna corrispondenza su Foglio2 (serve per testare se lo script si impalla quando non trova un valore).

Ho inoltre aggiunto Foglio4, dove potete vedere il risultato che mi aspetto di avere dall'applicazione dello script.


Adesso vediamo se qualcuno raccoglie la sfida, e soprattutto se qualcuno è in grado di portarla a termine ;)
Bruder
Utente Junior
 
Post: 29
Iscritto il: 06/06/11 18:30

Re: [EXCEL] Macro complessa per ricerca e compilazione

Postdi Avatar3 » 07/06/11 09:41

Se era questo quello che volevi... non mi sembra molto complicato
Codice: Seleziona tutto
Sub CompilaTab()
Dim Ws1, Ws2, Ws3 As Worksheet
Set Ws1 = Worksheets("Foglio1")
Set Ws2 = Worksheets("Foglio2")
Set Ws3 = Worksheets("Foglio3")
UR1 = Ws1.Range("E" & Rows.Count).End(xlUp).Row
UR2 = Ws2.Range("C" & Rows.Count).End(xlUp).Row
UR3 = Ws3.Range("A" & Rows.Count).End(xlUp).Row
If UR3 < 2 Then UR3 = 2
Ws3.Cells.ClearContents
For RR1 = 2 To UR1
Cod1 = Ws1.Range("E" & RR1).Value
Val1 = Ws1.Range("J" & RR1).Value
    For RR2 = 2 To UR2
        Cod2 = Ws2.Range("L" & RR2).Value
Val2 = Ws2.Range("X" & RR2).Value - Ws2.Range("Z" & RR2).Value
        If Cod1 = Cod2 And Val1 = Val2 Then
        Ws3.Cells(Rows.Count, 1).End(xlUp).Offset(1, 0).Value = Ws2.Range("C" & RR2).Value
        Ws3.Cells(Rows.Count, 2).End(xlUp).Offset(1, 0).Value = Ws2.Range("D" & RR2).Value
        Ws3.Cells(Rows.Count, 3).End(xlUp).Offset(1, 0).Value = Ws1.Range("M" & RR2).Value
        GoTo SaltaRR1
        End If
    Next RR2
SaltaRR1:
Next RR1
End Sub

Devi solo formattare la colonna B del foglio2 così: "00000"
L'unica cosa che non ho capito sono le date che hai riportato sul foglio4 :roll:
Per il funzionamento delle macro si deve impostare la protezione a Bassa o Media.
Menu Strumenti -> Macro -> Protezione...
Avatar utente
Avatar3
Utente Senior
 
Post: 569
Iscritto il: 04/04/11 09:04

Re: [EXCEL] Macro complessa per ricerca e compilazione

Postdi Bruder » 07/06/11 10:02

Non ci posso credere.. adesso provo, ma se hai già risolto sei ufficialmente il mio idolo..

Le date di Foglio4 se ci fai caso cadono tutte di martedì, in particolare cadono sul martedì della settimana successiva rispetto alla settimana in cui cade la data letta su Foglio1.

Ora provo e ti faccio sapere se ha funzionato!
Bruder
Utente Junior
 
Post: 29
Iscritto il: 06/06/11 18:30

Re: [EXCEL] Macro complessa per ricerca e compilazione

Postdi Avatar3 » 07/06/11 10:15

A proposito di date devi correggere questa riga

Codice: Seleziona tutto
        Ws3.Cells(Rows.Count, 3).End(xlUp).Offset(1, 0).Value = Ws1.Range("M" & RR1).Value '<<< correggere
        GoTo SaltaRR1  '<<<<<  esistente

Se ti occorre il primo martedì della settimana successiva ci possiamo provare
Per il funzionamento delle macro si deve impostare la protezione a Bassa o Media.
Menu Strumenti -> Macro -> Protezione...
Avatar utente
Avatar3
Utente Senior
 
Post: 569
Iscritto il: 04/04/11 09:04

Re: [EXCEL] Macro complessa per ricerca e compilazione

Postdi Avatar3 » 07/06/11 10:28

Ecco!
Ora verrà inserita la data del primo Martedì della settimana successiva
e ho aggiunto un paio di linee-codice per accelerare il processo
Codice: Seleziona tutto
Sub CompilaTab()
Application.ScreenUpdating = False
Application.Calculation = xlManual
Dim Ws1, Ws2, Ws3 As Worksheet
Set Ws1 = Worksheets("Foglio1")
Set Ws2 = Worksheets("Foglio2")
Set Ws3 = Worksheets("Foglio3")
UR1 = Ws1.Range("E" & Rows.Count).End(xlUp).Row
UR2 = Ws2.Range("C" & Rows.Count).End(xlUp).Row
UR3 = Ws3.Range("A" & Rows.Count).End(xlUp).Row
If UR3 < 2 Then UR3 = 2
Ws3.Cells.ClearContents
For RR1 = 2 To UR1
Cod1 = Ws1.Range("E" & RR1).Value
Val1 = Ws1.Range("J" & RR1).Value
    For RR2 = 2 To UR2
        Cod2 = Ws2.Range("L" & RR2).Value
Val2 = Ws2.Range("X" & RR2).Value - Ws2.Range("Z" & RR2).Value
        If Cod1 = Cod2 And Val1 = Val2 Then
        Ws3.Cells(Rows.Count, 1).End(xlUp).Offset(1, 0).Value = Ws2.Range("C" & RR2).Value
        Ws3.Cells(Rows.Count, 2).End(xlUp).Offset(1, 0).Value = Ws2.Range("D" & RR2).Value
        Ga = 9 - Weekday(Ws1.Range("M" & RR1).Value, 2)
        Ws3.Cells(Rows.Count, 3).End(xlUp).Offset(1, 0).Value = Ws1.Range("M" & RR1).Value + Ga
        GoTo SaltaRR1
        End If
    Next RR2
SaltaRR1:
Next RR1
Application.ScreenUpdating = True
Application.Calculation = xlCalculationAutomatic
End Sub
Per il funzionamento delle macro si deve impostare la protezione a Bassa o Media.
Menu Strumenti -> Macro -> Protezione...
Avatar utente
Avatar3
Utente Senior
 
Post: 569
Iscritto il: 04/04/11 09:04

Re: [EXCEL] Macro complessa per ricerca e compilazione

Postdi Bruder » 07/06/11 10:34

Bon, ho effettuato il primo run.
Lo script ha girato senza errori.
Su 331 codici è riuscito a trovare 293 corrispondenze, il che mi sembra un risultato davvero notevole.
Ora me le spulcio una per una e controllo che siano tutte corrette.

Nel frattempo, se non chiedo troppo, avrei bisogno di due piccole modifiche:
La prima riguarda i codici di "Foglio1" per i quali non è stato possibile trovare corrispondenze: è possibile evidenziarli in rosso?
La seconda riguarda la colonna "B" di "Foglio3", sono scomparsi gli "0" davanti al numero, mi spiego "00023" diventa semplicemente "23", io avrei bisogno che rimanesse di 5 cifre quel codice. E' possibile aggiugnere gli 0 mancanti in automatico (cioè senza dover formattare, come suggerivi tu, una colonna come "00000")?

Ora verifico la correttezza dell'assegnazione e ti faccio sapere.. cmq sei un drago, mi aspettavo quintali di spaghetti code invece è venuto fuori una macro elegantissima!! Complimenti davvero!!
Bruder
Utente Junior
 
Post: 29
Iscritto il: 06/06/11 18:30

Re: [EXCEL] Macro complessa per ricerca e compilazione

Postdi Avatar3 » 07/06/11 10:38

Per quanto riguarda la formattazione della colonna B la devi effettuare una sola volta selezionando l'intera colonna
Per il nuovo problema riguardante l'evidenziazione ci penserò...
Per il funzionamento delle macro si deve impostare la protezione a Bassa o Media.
Menu Strumenti -> Macro -> Protezione...
Avatar utente
Avatar3
Utente Senior
 
Post: 569
Iscritto il: 04/04/11 09:04

Re: [EXCEL] Macro complessa per ricerca e compilazione

Postdi Avatar3 » 07/06/11 10:46

Questa macro fa tutto ciò che hai chiesto finora
(compresa la formattazione della colonnaB del foglio3 e evidenzia nel foglio1 ciò che non trova nel foglio2)
Codice: Seleziona tutto
Sub CompilaTab()
Application.ScreenUpdating = False
Application.Calculation = xlManual
Dim Ws1, Ws2, Ws3 As Worksheet
Set Ws1 = Worksheets("Foglio1")
Set Ws2 = Worksheets("Foglio2")
Set Ws3 = Worksheets("Foglio3")
UR1 = Ws1.Range("E" & Rows.Count).End(xlUp).Row
UR2 = Ws2.Range("C" & Rows.Count).End(xlUp).Row
UR3 = Ws3.Range("A" & Rows.Count).End(xlUp).Row
Ws1.Range("A2:O" & UR1).Interior.ColorIndex = xlNone
If UR3 < 2 Then UR3 = 2
Ws3.Cells.ClearContents
For RR1 = 2 To UR1
Tr = 0
Cod1 = Trim(Ws1.Range("E" & RR1).Value)
Val1 = Ws1.Range("J" & RR1).Value
    For RR2 = 2 To UR2
        Cod2 = Trim(Ws2.Range("L" & RR2).Value)
Val2 = Ws2.Range("X" & RR2).Value - Ws2.Range("Z" & RR2).Value
        If Cod1 = Cod2 And Val1 = Val2 Then
        Ws3.Cells(Rows.Count, 1).End(xlUp).Offset(1, 0).Value = Ws2.Range("C" & RR2).Value
        Ws3.Cells(Rows.Count, 2).End(xlUp).Offset(1, 0).Value = Ws2.Range("D" & RR2).Value
        Ga = 9 - Weekday(Ws1.Range("M" & RR1).Value, 2)
        Ws3.Cells(Rows.Count, 3).End(xlUp).Offset(1, 0).Value = Ws1.Range("M" & RR1).Value + Ga
        Tr = 1
        GoTo SaltaRR1
        End If
    Next RR2
SaltaRR1:
If Tr = 0 Then Ws1.Range("A" & RR1 & ":O" & RR1).Interior.ColorIndex = 3
Next RR1
Ws3.Columns("B:B").NumberFormat = "00000"
Application.ScreenUpdating = True
Application.Calculation = xlCalculationAutomatic
End Sub


P.s. Ho aggiunto la pulizia dei campi codice con la funzione Trim che serve a togliere eventuali spazi inizio e fine riga che possono essere erroneamente entrati (e non sono visibili) nella digitazione o l'importazione dei codici stessi
Per il funzionamento delle macro si deve impostare la protezione a Bassa o Media.
Menu Strumenti -> Macro -> Protezione...
Avatar utente
Avatar3
Utente Senior
 
Post: 569
Iscritto il: 04/04/11 09:04

Re: [EXCEL] Macro complessa per ricerca e compilazione

Postdi Bruder » 07/06/11 11:10

Splendido, grazie mille davvero!!

Una cosa soltanto, nel controllare le assegnazioni mi sono reso conto che c'e' un problema:
prendiamo ad esempio il file che ho postato sopra; la riga 2 e la riga 6 di Foglio3 non vanno bene, infatti riportano lo stesso codice sia in colonna A (123456789) che in colonna B (00003). Le corrispondenze dovrebbero essere invece univoche.

L'assegnazione della riga 2 è corretta, ma per quanto riguarda quella della riga 6 mi sarei aspettato di avere 00005 in colonna B.

Immagino ciò sia dovuto, come pensavo, al fatto che la macro legge il foglio dall'alto verso il basso e si ferma appena incontra il primo valore "valido". Va bene che alla riga 2 di Foglio1 venga assegnata la riga 4 di Foglio2, ma la riga 7 di Foglio1 (che ha codice e quantità uguali all'altra) andrebbe assegnata alla riga 6 di Foglio2.

Per fare in modo che la macro "salti" i risultati già trovati, potresti ad esempio effettuare un confronto tra i codici delle colonne C e D (Foglio2) della riga che si sta per assegnare, e quelli delle colonne A e B (Foglio3) delle righe già assegnate.

Mi sono espresso in maniera poco chiara temo, ma confido nella tua abilità!!
Bruder
Utente Junior
 
Post: 29
Iscritto il: 06/06/11 18:30

Re: [EXCEL] Macro complessa per ricerca e compilazione

Postdi Avatar3 » 07/06/11 11:31

Il problema è che con due codici (o valori) da riscontrare se ambedue sono uguali non puoi discriminarli come vorresti
Dici di riportare la colonna D del foglio2 ma nel foglio1 non esiste la colonna con questo valore pertanto se non saltassi alla riga successiva ti troveresti il campo B del foglio2 con due valori a 00005 invece che due valori a 00003 come hai adesso.
Quindi occorre un altro codice che permette di ottenere un codice univoco.
Questo codice deve essere in entrambi i fogli (1 e 2) per la comparazione
Per il funzionamento delle macro si deve impostare la protezione a Bassa o Media.
Menu Strumenti -> Macro -> Protezione...
Avatar utente
Avatar3
Utente Senior
 
Post: 569
Iscritto il: 04/04/11 09:04

Re: [EXCEL] Macro complessa per ricerca e compilazione

Postdi Avatar3 » 07/06/11 11:43

Ho trovato un espediente utilizzando la colonna AC del foglio2
prova questa macro
Codice: Seleziona tutto
Sub CompilaTab()
Application.ScreenUpdating = False
Application.Calculation = xlManual
Dim Ws1, Ws2, Ws3 As Worksheet
Set Ws1 = Worksheets("Foglio1")
Set Ws2 = Worksheets("Foglio2")
Set Ws3 = Worksheets("Foglio3")
UR1 = Ws1.Range("E" & Rows.Count).End(xlUp).Row
UR2 = Ws2.Range("C" & Rows.Count).End(xlUp).Row
UR3 = Ws3.Range("A" & Rows.Count).End(xlUp).Row
Ws1.Range("A2:O" & UR1).Interior.ColorIndex = xlNone
Ws2.Columns("AC:AC").ClearContents
If UR3 < 2 Then UR3 = 2
Ws3.Cells.ClearContents
For RR1 = 2 To UR1
Tr = 0
Cod1 = Trim(Ws1.Range("E" & RR1).Value)
Val1 = Ws1.Range("J" & RR1).Value
    For RR2 = 2 To UR2
        Cod2 = Trim(Ws2.Range("L" & RR2).Value)
Val2 = Ws2.Range("X" & RR2).Value - Ws2.Range("Z" & RR2).Value
        If Cod1 = Cod2 And Val1 = Val2 And Ws2.Range("AC" & RR2).Value = "" Then
        Ws3.Cells(Rows.Count, 1).End(xlUp).Offset(1, 0).Value = Ws2.Range("C" & RR2).Value
        Ws3.Cells(Rows.Count, 2).End(xlUp).Offset(1, 0).Value = Ws2.Range("D" & RR2).Value
        Ga = 9 - Weekday(Ws1.Range("M" & RR1).Value, 2)
        Ws3.Cells(Rows.Count, 3).End(xlUp).Offset(1, 0).Value = Ws1.Range("M" & RR1).Value + Ga
        Ws2.Range("AC" & RR2).Value = 1
        Tr = 1
        GoTo SaltaRR1
        End If
    Next RR2
SaltaRR1:
If Tr = 0 Then Ws1.Range("A" & RR1 & ":O" & RR1).Interior.ColorIndex = 3
Next RR1
Ws3.Columns("B:B").NumberFormat = "00000"
Ws2.Columns("AC:AC").ClearContents
Application.ScreenUpdating = True
Application.Calculation = xlCalculationAutomatic
End Sub
Per il funzionamento delle macro si deve impostare la protezione a Bassa o Media.
Menu Strumenti -> Macro -> Protezione...
Avatar utente
Avatar3
Utente Senior
 
Post: 569
Iscritto il: 04/04/11 09:04

Re: [EXCEL] Macro complessa per ricerca e compilazione

Postdi Bruder » 07/06/11 11:45

Forse non ho capito il tuo messaggio ma la soluzione che proponevo io non è fattibile?
Prima di riportare il risultato dell'assegnazione su Foglio3 si verifica che quel risultato non sia già presente su tale foglio.

Ossia quando la macro sta per scrivere "123456789" "00003" sul Foglio3 si accorge che "123456789" "00003" esiste già e quindi ritorna all'inizio dello script, scala in giù di una riga rispetto a dove era arrivato e ricomincia la "scansione" da lì.

Cioè si tratta di fare un confronto prima tra foglio1 e foglio2 ed in un secondo tempo tra foglio2 e foglio3.

Spero di essere stato chiaro :eeh:
Bruder
Utente Junior
 
Post: 29
Iscritto il: 06/06/11 18:30

Re: [EXCEL] Macro complessa per ricerca e compilazione

Postdi Bruder » 07/06/11 11:45

Ops, ho visto solo ora la tua risposta. Controllo se funziona!
Bruder
Utente Junior
 
Post: 29
Iscritto il: 06/06/11 18:30

Re: [EXCEL] Macro complessa per ricerca e compilazione

Postdi Bruder » 07/06/11 11:51

Questa volta niente valori duplicati; coerentemente il numero delle assegnazioni è sceso a 278 su 331.
Le righe non assegnate sono evidenziate in maniera corretta ed anche i dati sono formattati come volevo.
Sembrerebbe perfetto!

Ora vado a pranzare, appena torno provo a rifare il controllo riga per riga e vediamo.

Per il momento ti ringrazio infinitamente per l'aiuto!! Ne sai davvero tante!!
Bruder
Utente Junior
 
Post: 29
Iscritto il: 06/06/11 18:30

Re: [EXCEL] Macro complessa per ricerca e compilazione

Postdi Avatar3 » 07/06/11 12:05

Beh avrai capito in cosa consiste l'espediente
quando avviene la scrittura nel foglio3 (quindi codici e valori rispettati)
vado ad inserire il valore 1 nella colonna AC del foglio2 in corrispondenza del codice trascritto
a questo punto ho modificato la scrittura aggiungendo la condizione che la colonna Ac del foglio2 deve essere vuota
in questa maniera il ciclo continua per le rimanenti righe del foglio2
(che senza condizione avrebbe saltato riproponendo il codice precedente)
alla fine della macro cancello la colonna AC (veramente la cancello anche all'inizio: per sicurezza)
Per il funzionamento delle macro si deve impostare la protezione a Bassa o Media.
Menu Strumenti -> Macro -> Protezione...
Avatar utente
Avatar3
Utente Senior
 
Post: 569
Iscritto il: 04/04/11 09:04

Prossimo

Torna a Applicazioni Office Windows


Topic correlati a "[EXCEL] Macro complessa per ricerca e compilazione":


Chi c’è in linea

Visitano il forum: Nessuno e 9 ospiti