Condividi:        

Conteggio automatico

Vuoi potenziare i tuoi documenti Word? Non sai come si fa una macro in Excel? Devi creare una presentazione in PowerPoint?
Oppure sei passato a OpenOffice e non sei sicuro di come lavorare al meglio?

Moderatori: Anthony47, Flash30005

Conteggio automatico

Postdi tutamimetica » 16/05/10 07:17

Al solito ho bisogno di aiuto.
Ho un calendario sviluppato in verticale a partire dalla riga A6 (mese: settembre), in B6 (giorno della settimana: mer) e C6 (il giorno del mese:1).
Nella cella D3 ho un numero (per esempio 4) e nella cella D4 specificato il giorno della settimana (per esempio mer).
Come risultato finale da conteggio automatico dovrebbe segnarmi con una “X” in corrispondenza di mer 22 settembre, di merc 20 ottobre, di merc 17 novembre e così via.
Grazie.
tuta
tutamimetica
Utente Senior
 
Post: 209
Iscritto il: 10/06/08 17:25

Sponsor
 

Re: Conteggio automatico

Postdi Anthony47 » 16/05/10 23:16

Prova in D6
Codice: Seleziona tutto
=SE(E(RESTO(CONTA.SE(B$6:B6;$D$4);$D$3)=0;B6=$D$4;CONTA.SE(B$6:B6;$D$4)>0);"X";"")

Poi copia verso il basso.

Ciao
Avatar utente
Anthony47
Moderatore
 
Post: 19181
Iscritto il: 21/03/06 16:03
Località: Ivrea

Re: Conteggio automatico

Postdi tutamimetica » 17/05/10 15:43

Funziona tutto, grazie.
Purtroppo si sono verificati altri problemi, a cui non avevo pensato.
Il primo: alla colonna D seguono altre colonne(fino a M) e a volte le condizioni coincidono per cui in un determinato giorno sicuramente le "X" coincidono. Basterebbe far contare dalla settimana dopo, tanto deve riempirmi tutte le settimane.
Il secondo problema deriva dal fatto che ci sono dei multipli e le "X" coincidono.
Grazie anticipatamente.
tuta
tutamimetica
Utente Senior
 
Post: 209
Iscritto il: 10/06/08 17:25

Re: Conteggio automatico

Postdi Anthony47 » 17/05/10 23:16

Perdona, la prima descrizione "forse" l' avevo interpretata, ma questa seconda "certamente" mi sfugge: ad esempio che significa "a volte le condizioni coincidono per cui in un determinato giorno sicuramente le "X" coincidono", visto che c' e' una X ogni 4 settimane? Il che ovviamente contrasta anche con "tanto deve riempirmi tutte le settimane".

Probabilmmente puo' esserci d' aiuto uno screenshot con le tue informazioni.

Ciao.
Avatar utente
Anthony47
Moderatore
 
Post: 19181
Iscritto il: 21/03/06 16:03
Località: Ivrea

Re: Conteggio automatico

Postdi tutamimetica » 18/05/10 11:48

Anthony ti invio il file
http://rapidshare.com/files/388705235/S ... o.xls.html
Volevo dire che se per Francese scelgo "gio" in I4 il risultato giustamente mi darà una X il 16.
Purtroppo questo non mi va bene perché ho già occupata quell'ora per il recupero.
Grazie
tutamimetica
Utente Senior
 
Post: 209
Iscritto il: 10/06/08 17:25

Re: Conteggio automatico

Postdi tutamimetica » 17/09/10 20:55

Ho al solito bisogno di un aiutino in D22, in E22 e F22 mi appaiano delle "X" ho bisogno che la X si sposti in E29 e in F36 tenendo conto delle condizioni della riga 5. In parole povere nella prima colonna mi deve contare i Gio a partire dal primo nella prima colonna, dal secondo GIO nella seconda colonna e dal terzo GIO nella terza colonna.Grazie anticipato. Allego il file http://rapidshare.com/files/419661017/Prova.xls
tuta
tutamimetica
Utente Senior
 
Post: 209
Iscritto il: 10/06/08 17:25

Re: Conteggio automatico

Postdi Anthony47 » 19/09/10 01:50

Un problema cosi' lo avevamo gia' discusso, ma non ricordo come si concluse; vedo che pero' la domanda precedente era rimasta abbandonata e senza seguito... me ne scuso.
Venendo a questa domanda, usando la numerazione progressiva che hai inserito in D5-E5-F5, puoi mettere in D7 la formula
Codice: Seleziona tutto
=SE(RIF.RIGA()=PICCOLO(SE($B$7:$B$300=D$4;RIF.RIGA($B$7:$B$300);"");D$5+D$3-1+CONTA.SE(D$6:D6;"X")*3);"X";"")
Da confermare con Contr-Maiusc-Enter.
Poi copi su E7-F7; infine copi D7:F7 verso il basso.
Se invece dei valori che hai in col A-B-C avessi una vera data (magari formattata "personalizzato", "mmmm-ggg-gg", per vedere ad esempio Settembre-dom-19) forse la formula poteva essere semplificata.

Ciao
Avatar utente
Anthony47
Moderatore
 
Post: 19181
Iscritto il: 21/03/06 16:03
Località: Ivrea

Re: Conteggio automatico

Postdi tutamimetica » 19/09/10 09:11

Anthony grazie della risposta, al solito va benissimo e già mi basta per il mio lavoro.
Sinceramente non avevo pensato alla data personalizzata e la cosa mi incuriosisce. Nel caso in cui io eliminerei le colonne B e C e la data personalizzata resta in A come verrebbe la formula per il confronto?
Anthony se nel listato delle date ci sono alcune che sono festive (es. 8/12 che è un lunedì) è possibile non farle marcare dalla X? Se si come posso fare?
Grazie tuta
tutamimetica
Utente Senior
 
Post: 209
Iscritto il: 10/06/08 17:25

Re: Conteggio automatico

Postdi Anthony47 » 19/09/10 15:36

Eh, mi sembrava strano che non si parlasse di festivi...
Per semplificare (a me) la vita, facciamo che in col A mettiamo una data; quindi in A7 metti la data "1 sett 2010" (nella sintassi richiesta dal tuo excel); in A8 metti
Codice: Seleziona tutto
=A7+1
e poi copi verso il basso.
In B7 metti
Codice: Seleziona tutto
=TESTO(A7;"ggg")
e copi verso il basso.
In una colonna del tuo foglio (o anche in un foglio diverso del file), fatti un elenco di giorni festivi (gg + mese + anno; quindi inserirai ad ese 25 dic 2010 e 1 gen 2011); assegna il nome "festivi" a questo intervallo, magari lasciando in coda un bel po' di celle vuote per aggiungere "feste" imprevedibili quali assenze per gite, sciopero dei docenti, etc).
In C7 metti la formula
Codice: Seleziona tutto
=SE(VAL.ERRORE(CERCA.VERT(A7;festivi;1;0));"";"F")
e copi verso il basso.
In questo modo in col B hai il giorno della settimana e in col C hai F per Festivo oppure vuoto.
Fin qui sono valide le stesse formule che ti ho dato, ovviamente ignorando ancora il flag "festivo".

Se invece usi in D7 la formula
Codice: Seleziona tutto
=SE(RIF.RIGA()=PICCOLO(SE(($B$7:$B$300=D$4)*($C$7:$C$300<>"F");RIF.RIGA($B$7:$B$300);"");D$5+D$3-1+CONTA.SE(D$6:D6;"X")*3);"X";"")
(sempre Contr-Maiusc-Enter) e poi copi in largo e lungo allora i giorni marcati F saranno ignorati.

Ovviamente l' uso della data in col A avrebbe potuto farci dimenticare la col B (giorno della settimana), perche' questo dato e' intrinseco nella data; ma per ora ho voluto evitare di complicarmi la vita (come da preambolo), perche' vorrei che prima fossero chiare le regole da considerare; in particolare credo, ma dovresti confermarlo o smentirlo tu, che l' obiettivo sia quello di evitare che due X finiscano sulla stessa riga in colonna diversa; ma con l' intestazione attuale del foglio si possono impostare periodicita' diverse tra le varie colonne, es D3=3, E3=4, F3=4 (o altre combinazioni a piacere), e questo ora ti porterebbe prima o poi ad evere piu' X nella stessa riga. Quindi spiega se l' obiettivo e' quello che ho scritto e se la situazione di valori diversi tra loro in D3:F3 e' possibile o no, poi vedro cosa si puo' fare.

Ciao, fai sapere.
Avatar utente
Anthony47
Moderatore
 
Post: 19181
Iscritto il: 21/03/06 16:03
Località: Ivrea

Re: Conteggio automatico

Postdi tutamimetica » 19/09/10 19:12

Anthony così come hai sviluppato le mie richieste hai esaudito tutti i miei desideri. Il lavoro è perfetto, non ho doppioni e lo sviluppo mi scala la X nei giorni festivi. Grazie di cuore.
tuta.
tutamimetica
Utente Senior
 
Post: 209
Iscritto il: 10/06/08 17:25


Torna a Applicazioni Office Windows


Topic correlati a "Conteggio automatico":


Chi c’è in linea

Visitano il forum: Nessuno e 45 ospiti