[excel] Ordinamento dinamico

[m4tteo]

salve,
ho una lista di nomi e altre colonne dove vengono inseriti i punteggi parziali di ogni gara effettuata. L'ultima colonna dopo il punteggio di ogni singola gara ho una colonna chiamata totale che non è altro che la somma dei punteggi delle gare della riga.

Io vorrei, magari in un foglio diverso, creare una classifica che si aggiorna (in automatico possibilmente) man mano che i punteggi, dopo ogni gara, vengono aggiunti.

E' possibile farlo senza macro? Altrimenti sapete guardi sulla creazione di una macro apposita?

Grazie

[tutamimetica]

Ipotizzando che in Z10 ci sia il totale;
in A10 inserisci la seguente formula:
=SE(Z10="";"";RANGO(Z10;$Z$100:$Z$200;1))
Ti verrà evidenziato la posizione in classifica (ho previsto 200 concorrenti,
puoi sempre correggere quel $Z$200 incrementandolo o decrementandolo)
io copierei il tutto in un altro foglio
selezioni l’area da copiare
vai in un alto foglio e incolli
poi MODIFICA\incolla spciale\valore
selezioni l’area copiata nel nuovo foglio
DATI\ORDINA
Scegli le opzioni che ti interessano OK
Ciao tuta

[Anthony47]

In alternativa a quanto suggerito da tuta potresti valutare questa soluzione:
-supponiamo che i nomi siano in col A e il punteggio totale in col H, dalla riga 2 alla 30.
-in una colonna libera del tuo foglio, in riga 2, es in M2, metti questa formula:

Codice: Seleziona tutto

=CONFRONTA(GRANDE($H$2:$H$30-RIF.RIGA($H$2:$H$30)/1000;RIF.RIGA(A1));($H$2:$H$30-RIF.RIGA($H$2:$H$30)/1000);0)

Confermerai la formula NON con Enter ma con Contr-Maiusc-Enter (vedrai la formula racchiusa tra parentesi graffe)
Questa formula ti indica su quale riga compare il primo classificato; a parita' di punteggio e' primo chi compare prima nell' elenco.
-nella colonna adiacente, N2, inserisci

Codice: Seleziona tutto

=SCARTO($A$1;$M2;0)

Questa ti restituira' il col A del primo classificato; copia N2 nelle colonne adiacenti, modificando di volta in volta lo "scarto orizzontale" (il valore messo a "0" nella formula di N2) per portare in quella posizione altre informazioni del primo classificato (1=col B, 2=col C etc).

Se vuoi queste informazioni in un foglio diverso, seleziona M2:XX2 (cioe' le celle con formule), Contr-x, seleziona un nuovo foglio e in questo la cella di destinazione, Enter.
Copia infine le formule in verticale, per tutte le posizioni in classifica che vuoi estrarre.

Volendo, la formula di M2 puo' essere scritta direttamente in quella di N2 (in sostituzione del parametro $M2), ottenendo quindi qualcosa come

Codice: Seleziona tutto

=SCARTO($A$1;CONFRONTA(GRANDE($H$2:$H$30-RIF.RIGA($H$2:$H$30)/1000;RIF.RIGA(A1));($H$2:$H$30-RIF.RIGA($H$2:$H$30)/1000);0);0)

Sempre da confermare con Contr-Maiusc-Enter.

Spero di non avervi confuso oltre le mie intenzioni... il metodo di tuta in questo e' piu' semplice da seguire.

Ciao.