Condividi:        

Data Query da web impossibile

Vuoi potenziare i tuoi documenti Word? Non sai come si fa una macro in Excel? Devi creare una presentazione in PowerPoint?
Oppure sei passato a OpenOffice e non sei sicuro di come lavorare al meglio?

Moderatori: Anthony47, Flash30005

Data Query da web impossibile

Postdi xilofono » 24/10/18 20:09

Buonasera,

In un sito, risulta imposssibile fare data query in quanto appena si apre la pagina, dà questo errore e impalla excel, esistono rimedi? :cry:

Immagine
Windows 11 - Office 2016 Ita
Avatar utente
xilofono
Utente Junior
 
Post: 80
Iscritto il: 27/11/17 09:52

Sponsor
 

Re: Data Query da web impossibile

Postdi Anthony47 » 25/10/18 01:45

Le web query, per definizione di Microsoft, possono andare in tilt sulle pagine web generate dinamicamente tramite script (la quasi totalita').
Il messaggio mostra che nel tuo sito ci sono javascripts, pero' spesso rispondendo Si (o forse anche No) la query alla fine si riesce ad eseguire.
Abbiamo pubblicato varie soluzioni alternative alle webquery, ma bisognerebbe conoscere l'url del sito e che cosa si vuole importare; senza ti posso ad esempio rimandare alla Sub GetTabbbSub suggerita ad altro utente in quest'altra discussione: viewtopic.php?f=26&t=105843#p619587

Ciao
Avatar utente
Anthony47
Moderatore
 
Post: 19196
Iscritto il: 21/03/06 16:03
Località: Ivrea

Re: Data Query da web impossibile

Postdi xilofono » 28/10/18 08:23

ciao anthony, il sito è questo https://www.easyinfogas.it

ma il problema è che prima di estrarre, devo fare login una volta manualmente, in modo che il browser di excel abbia l'accesso alle pagine successivamente, ma il login risulta impossibile in quanto blocca excel :aaah
Windows 11 - Office 2016 Ita
Avatar utente
xilofono
Utente Junior
 
Post: 80
Iscritto il: 27/11/17 09:52

Re: Data Query da web impossibile

Postdi Anthony47 » 28/10/18 12:33

Non conosco il comportamento del sito, comunque ti suggerisco di provare con questo codice, che e' una variazione di quanto presentato nella discussione che ti avevo linkato:
Codice: Seleziona tutto
Public IE As Object

Sub GetTabbbSub(ByVal myURL As String)
'Va Chiamata passandogli l'URL da leggere
''' Set IE = CreateObject("InternetExplorer.Application")  'NO, lo facciamo nella macro principale
With IE
    .navigate myURL
    .Visible = True
    Do While .Busy: DoEvents: Loop    'Attesa not busy
    Do While .readyState <> 4: DoEvents: Loop 'Attesa documento
End With
'
myStart = Timer  'attesa addizionale
Do
    DoEvents
    If Timer > myStart + 2 Or Timer < myStart Then Exit Do
Loop

'''ESCE SE HO CHIAMATO LA PAGINA DI LOGIN:
If myURL = "https://www.easyinfogas.it/" Then Exit Sub

'Leggi le tabelle SUL FOGLIO ATTIVO
''Sheets("Classifica Home").Select
''Cells.Clear
Set mycoll = IE.document.getElementsByTagName("TABLE")
For Each myItm In mycoll
    For Each trtr In myItm.Rows
        For Each tdtd In trtr.Cells
            Cells(i + 1, j + 1) = tdtd.innerText
            j = j + 1
        Next tdtd
        i = i + 1: j = 0
    Next trtr
i = i + 1
Next myItm

''Stop     'Vedi testo

'''Chiusura IE  'NO, anche questo lo facciamo nella macro principale
'''IE.Quit
'''Set IE = Nothing
End Sub

Sub Principale()
Set IE = CreateObject("InternetExplorer.Application")
    Sheets("FoglioSuCuiFareL'Importazione").Select
    Cells.ClearContents
    Call GetTabbbSub("https://www.easyinfogas.it/")         'Chiamo la pagina iniziale e mi loggo a mano
    Stop
    Call GetTabbbSub("https://www.easyinfogas.it/L'URL-DA-CUI-IMPORTARE-LE-TABELLE")    'Chiamo la pagina con le tabelle
Stop                   'SOLO PER TEST, POI CANCELLALO
IE.Quit
Set IE = Nothing
End Sub
Va messo tutto in un "nuovo Modulo standard" del vba.

La macro da lanciare e' la Sub Principale; in testa contiene le istruzioni per selezionare il foglio su cui vuoi importare le tabelle, e per AZZERARLO (cancella l'istruzione o modificala, se non vuoi cancellare tutto il foglio quando cominci).
Poi si richiama la pagina del login e la macro si stoppa.
Si puo' ora eseguire manualmente il login (nella pagina IE appena creata) e poi riprendi l'esecuzione della macro col tasto F5.
Prima del competamento, la macro va nuovamente in Stop per consentirti di capire se il risultato e' corretto (confronto pagina IE con foglio Excel); quando sei tranquillo sui risultati puoi eliminare quello Stop

Ciao
Avatar utente
Anthony47
Moderatore
 
Post: 19196
Iscritto il: 21/03/06 16:03
Località: Ivrea

Re: Data Query da web impossibile

Postdi xilofono » 28/10/18 20:40

La macro gira, nel senso che apre su ie il link, faccio login, faccio ripartire, apre la seconda pagina, faccio ripartire, chiude ie senza importare niente :oops: forse banalmente non ho capito esattamente come utilizzarla

io l'ho declinata così

Codice: Seleziona tutto
Public IE As Object

Sub GetTabbbSub(ByVal myURL As String)
'Va Chiamata passandogli l'URL da leggere
''' Set IE = CreateObject("InternetExplorer.Application")  'NO, lo facciamo nella macro principale
With IE
    .navigate myURL
    .Visible = True
    Do While .Busy: DoEvents: Loop    'Attesa not busy
    Do While .readyState <> 4: DoEvents: Loop 'Attesa documento
End With
'
myStart = Timer  'attesa addizionale
Do
    DoEvents
    If Timer > myStart + 2 Or Timer < myStart Then Exit Do
Loop

'''ESCE SE HO CHIAMATO LA PAGINA DI LOGIN:
If myURL = "https://www.easyinfogas.it/" Then Exit Sub

'Leggi le tabelle SUL FOGLIO ATTIVO
''Sheets("Classifica Home").Select
''Cells.Clear
Set mycoll = IE.document.getElementsByTagName("TABLE")
For Each myItm In mycoll
    For Each trtr In myItm.Rows
        For Each tdtd In trtr.Cells
            Cells(i + 1, j + 1) = tdtd.innerText
            j = j + 1
        Next tdtd
        i = i + 1: j = 0
    Next trtr
i = i + 1
Next myItm

''Stop     'Vedi testo

'''Chiusura IE  'NO, anche questo lo facciamo nella macro principale
'''IE.Quit
'''Set IE = Nothing
End Sub

Sub Principale()
Set IE = CreateObject("InternetExplorer.Application")
    Sheets("[b]Foglio2[/b]").Select
    Cells.ClearContents
    Call GetTabbbSub("[b]https://www.easyinfogas.it/[/b]")         'Chiamo la pagina iniziale e mi loggo a mano
    Stop
    Call GetTabbbSub("[b]https://www.easyinfogas.it/reader_mod.php?id=3765[/b]")    'Chiamo la pagina con le tabelle
Stop                   'SOLO PER TEST, POI CANCELLALO
IE.Quit
Set IE = Nothing
End Sub


in teoria io vorrei fare esattamente la stessa cosa esposta qui

viewtopic.php?f=26&t=109229&p=640986#p640988

cioè metto in foglio 1 colonna a una serie di link (non necessariamente collegamenti), e la macro estrae incollando come valori in foglio 2 una pagina per colonna, dunque il link presente in a1 in colonna a, quello di a2 in colonna b etc

solo che il nuovo sito impalla il browser di excel :undecided:
Windows 11 - Office 2016 Ita
Avatar utente
xilofono
Utente Junior
 
Post: 80
Iscritto il: 27/11/17 09:52

Re: Data Query da web impossibile

Postdi Anthony47 » 29/10/18 15:00

Purtroppo senza avere l'accesso alla pagina web non sono in grado di fare ipotesi sensate...
Solo a scopo di prova:
Codice: Seleziona tutto
Sub Principale()
Set IE = CreateObject("InternetExplorer.Application")
    Sheets("Foglio1").Select
    Cells.ClearContents
    Call GetTabbbSub("https://www.corriere.it/")         'Chiamo la pagina iniziale e mi loggo a mano
    Stop
    Call GetTabbbSub("https://borsa.corriere.it/borsa-italiana/azioni/listino-completo?topicGroupIndex=A")    'Chiamo la pagina con le tabelle
Stop                   'SOLO PER TEST, POI CANCELLALO
IE.Quit
Set IE = Nothing
End Sub
Questa versione di "Sub Principale" (con questi URL), apre la home di corriere.it; dopo l'ipotetico login (che in questo caso non e' necessario), continuando a eseguire la macro verranno importati su Foglio1 i titoli di borsa alla lettera A (quelli visualizzati).
Quindi se con i tuoi indirizzi non importa niente e' possibile che la pagina non contenga "tabelle" (quelle catturabili con la QueryWeb oppure dalla mia Sub GetTabbbSub), ma strutture che le simulano; oppure che le "nascondono" in "iframes"; ma anche la lettura del contenuto di un iframe dipende dal sito.

Questo per ribadire che "senza avere l'accesso alla pagina web non sono in grado di fare ipotesi sensate"

Sorry...
Avatar utente
Anthony47
Moderatore
 
Post: 19196
Iscritto il: 21/03/06 16:03
Località: Ivrea

Re: Data Query da web impossibile

Postdi xilofono » 30/10/18 21:09

quello funziona sì :aaah
:( purtroppo non posso fornire le chiavi, fosse per me lo farei pure :)

però non so se può aiutare a comprendere la struttura della pagina uno screen della sorgente, nella quale ci sono evidenziate le due parti da estrarre (ma se estrae tutta la pagina senza distinzioni meglio ancora francamente)

Immagine
Windows 11 - Office 2016 Ita
Avatar utente
xilofono
Utente Junior
 
Post: 80
Iscritto il: 27/11/17 09:52

Re: Data Query da web impossibile

Postdi Anthony47 » 30/10/18 23:14

Da quella pagina una webquery non estrarra' mai niente.
La mia macro potrebbe essere modificata in questo modo e forse estrae le informazioni che chiedi; dico "forse" perche' non potendo controllare quanti Class "DataContent" ci sono nel sorgente vado alla cieca:

Codice: Seleziona tutto
Sub GetTabbbSub(ByVal myURL As String)
'Va Chiamata passandogli l'URL da leggere
''' Set IE = CreateObject("InternetExplorer.Application")  'NO, lo facciamo nella macro principale
With IE
    .navigate myURL
    .Visible = True
    Do While .Busy: DoEvents: Loop    'Attesa not busy
    Do While .readyState <> 4: DoEvents: Loop 'Attesa documento
End With
'
myStart = Timer  'attesa addizionale
Do
    DoEvents
    If Timer > myStart + 2 Or Timer < myStart Then Exit Do
Loop

'''ESCE SE HO CHIAMATO LA PAGINA DI LOGIN:
If myURL = "https://www.easyinfogas.it/" Then Exit Sub

'Leggi i dati (alla cieca):
''Sheets("Classifica Home").Select
''Cells.Clear
Dim my2Coll As Object
Set mycoll = IE.document.getElementsByClassName("dataContent")
Set my2Coll = mycoll(0).getElementsByClassName("clmn box1")
Cells(2, 1) = my2Coll(0).getElementsByClassName("intStrng title")(0).innerText
Cells(2, 2) = my2Coll(0).getElementsByClassName("intStrng")(0).innerText
Cells(2, 3) = my2Coll(0).getElementsByClassName("intStrng")(1).innerText

Set my2Coll = mycoll(0).getElementsByClassName("clmn box2")
Cells(2, 4) = my2Coll(0).getElementsByClassName("intStrng")(0).innerText
Cells(2, 5) = my2Coll(0).getElementsByClassName("intStrng")(1).innerText

''Stop     'Vedi testo

'''Chiusura IE  'NO, anche questo lo facciamo nella macro principale
'''IE.Quit
'''Set IE = Nothing
End Sub


Ciao
Avatar utente
Anthony47
Moderatore
 
Post: 19196
Iscritto il: 21/03/06 16:03
Località: Ivrea

Re: Data Query da web impossibile

Postdi xilofono » 31/10/18 08:47

anthony ti ringrazio perchè in realtà, per quanto alla cieca, funziona, mette sulla riga due le info richieste (tranne il numero di matricola, ma credo di riuscire a trovare la stringa da richiamare anche io) :D
francamente per me sarebbe stata fantascienza arrivarci :undecided:

ora il mio problema è che in realtà, dopo il login iniziale a mano, io avrei una lista di link (non ipertestuali), che possono essere fino a 20mila, in cui fare questa operazione in continuo, messi su una colonna A, come nella vecchia macro :oops:

una struttura così, con pagina coi link e pagina estrazioni
http://www.filedropper.com/querygas

edit. infatti per richiamare la matricola serviva solo sostituire
Cells(2, 3) = my2Coll(0).getElementsByClassName("intStrng")(1).innerText
con
Cells(2, 3) = my2Coll(0).getElementsByClassName("intStrng")(2).innerText
ho fatto almeno questo :neutral:
Windows 11 - Office 2016 Ita
Avatar utente
xilofono
Utente Junior
 
Post: 80
Iscritto il: 27/11/17 09:52

Re: Data Query da web impossibile

Postdi Anthony47 » 31/10/18 20:05

Alla luce dei risultati ottenuti ho rivisto l'intero codice; in particolare ho portato tutto all'interno di una unica Sub (Sub GetTabbbXyl); quindi sostituisci tutto il codice precedente con questo:
Codice: Seleziona tutto
Public IE As Object

Sub GetTabbbXyl()
Dim ESh As Worksheet, LSh As Worksheet, I As Long
Dim my2Coll As Object, myColl As Object
'
Set ESh = Sheets("Estrazioni")      '<<< Il foglio dei risultati
Set LSh = Sheets("Link")            '<<< Il foglio con i LINK
'
If IE Is Nothing Then Set IE = CreateObject("InternetExplorer.Application")
ESh.Cells.ClearContents             '!!! AZZERA foglio dei risultati
'
For I = 1 To LSh.Cells(Rows.Count, 1).End(xlUp).Row
    myURL = LSh.Cells(I, 1)
    With IE
        .navigate myURL
        .Visible = True
        Do While .Busy: DoEvents: Loop    'Attesa not busy
        Do While .readyState <> 4: DoEvents: Loop 'Attesa documento
    End With
    '
    myStart = Timer  'attesa addizionale
    Do
        DoEvents
        If Timer > myStart + 1 Or Timer < myStart Then Exit Do
    Loop
'
'''ESCE SE DEVO FARE LOGIN:
    If IE.LOCATIONUrL = "https://www.easyinfogas.it/index.php" Then
        MsgBox ("Eseguire il Login e rilanciare la macro")
        Exit Sub
    End If
    '
'Leggi i dati (alla cieca):
    Set myColl = IE.document.getElementsByClassName("dataContent")
    Set my2Coll = myColl(0).getElementsByClassName("clmn box1")
    Cells(I + 1, 1) = Replace(myURL, "https://www.easyinfogas.it/reader_mod.php?", "", , , vbTextCompare)
    Cells(I + 1, 2) = my2Coll(0).getElementsByClassName("intStrng title")(0).innerText
    Cells(I + 1, 3) = my2Coll(0).getElementsByClassName("intStrng")(0).innerText
    Cells(I + 1, 4) = my2Coll(0).getElementsByClassName("intStrng")(1).innerText
    Cells(I + 1, 5) = my2Coll(0).getElementsByClassName("intStrng")(2).innerText
'secondo gruppo
    Set my2Coll = myColl(0).getElementsByClassName("clmn box2")
    Cells(I + 1, 6) = my2Coll(0).getElementsByClassName("intStrng")(0).innerText
    Cells(I + 1, 7) = my2Coll(0).getElementsByClassName("intStrng")(2).innerText
Next I
'
'Stop     'Vedi testo

'''Chiusura IE
IE.Quit
Set IE = Nothing
End Sub

Va lanciata la Sub GetTabbbXyl.

La macro contiene un'attesa aggiuntiva, rispetto a quando la pagine IE dovrebbe essere stabile, di 1 secondo; questo significa che per 17mila codici ragionevolmente aspetterai 6-7 ore.

Ti suggerisco pertanto di provare inizialmente con un centinaio di Id, e poi copiare le estrazioni in altro foglio e ripetere la stessa prova ma accorciando l'attesa a 0.3 secondi:
Codice: Seleziona tutto
If Timer > myStart + 0.3 Or Timer < myStart Then Exit Do


Se le estrazioni sono identiche alle prime allora puoi lasciare "0.3" secondi e lanciare l'importazione dei 17mila Id; oppure (meglio) dividere le importazioni in piu' lotti.

Buona fortuna...
Avatar utente
Anthony47
Moderatore
 
Post: 19196
Iscritto il: 21/03/06 16:03
Località: Ivrea

Re: Data Query da web impossibile

Postdi xilofono » 31/10/18 20:23

che dire anthony
ho praticamente provato la macro due secondi dopo che l'hai postata e non posso fare altro che ringraziarti davvero di cuore, perchè ovviamente funziona alla perfezione
in questa come altre occasioni rimango davvero stupito di come si possano trovare soluzioni in questo forum :oops: e per quanto limitate possano essere le mie capacità di dare il mio contributi ad altri quando posso
poi magari per te è un gioco da ragazzi fare queste cose, ma rimane valido quanto sopra :D
Windows 11 - Office 2016 Ita
Avatar utente
xilofono
Utente Junior
 
Post: 80
Iscritto il: 27/11/17 09:52

Re: Data Query da web impossibile

Postdi xilofono » 16/12/18 15:50

Nel tempo ho sviluppato questa macro per automatizzare il lavoro. funziona perfettamente grazie ad anthony, attraverso altre macro ho creato un sistema per ovviare alle interruzioni, in modo da ripartire in modo semiautomatico da dove si era interrotta, salvando il pregresso in un registro a parte in maniera sedimentaria e riaprtendo dall'id successivo

ho un solo piccolo problema, credo di facile risoluzione, sostanzialmente una e una sola riga di queste estrazioni, può dare errore in quanto non richiama alcuna fonte (In quanto manca, in alcune pagine, l'informazione sul telefono, mentre in altre è presente)

dovrei fare in modo che, qualora questo errore si presenti relativamente a questa riga, venga ignorato e la macro non importi niente nella cella di destinazione ma continui a lavorare... purtroppo non so come fare :oops:

Codice: Seleziona tutto
Public IE As Object

Sub EstraiID()
Dim ESh As Worksheet, LSh As Worksheet, i As Long
Dim my2Coll As Object, myColl As Object
'
Set ESh = Sheets("Estrazioni")     
Set LSh = Sheets("Link")           
'
If IE Is Nothing Then Set IE = CreateObject("InternetExplorer.Application")
    Range("A2:S18001").Select
    Selection.ClearContents           
'
For i = 2 To LSh.Cells(Rows.Count, 1).End(xlUp).Row
    myURL = LSh.Cells(i, 1)
    With IE
        .navigate myURL
        .Visible = True
        Do While .Busy: DoEvents: Loop   
        Do While .readyState <> 4: DoEvents: Loop
    End With
    '
    myStart = Timer
    Do
        DoEvents
        If Timer > myStart + 1 Or Timer < myStart Then Exit Do
    Loop
'

    If IE.LOCATIONUrL = "https://www.easyinfogas.it/index.php" Then
        MsgBox ("Eseguire il Login e rilanciare la macro")
        Exit Sub
    End If
    '

    Set myColl = IE.document.getElementsByClassName("dataContent")
    Set my2Coll = myColl(0).getElementsByClassName("clmn box1")
    Cells(i + 0, 1) = Replace(myURL, "https://www.easyinfogas.it/reader_mod.php?id=", "", , , vbTextCompare) 'ID
    Cells(i + 0, 2) = my2Coll(0).getElementsByClassName("intStrng")(0).innertext 'PDR
    Cells(i + 0, 3) = my2Coll(0).getElementsByClassName("intStrng")(1).innertext 'Cod. Cliente
    Cells(i + 0, 4) = my2Coll(0).getElementsByClassName("intStrng")(2).innertext 'Matricola
    Cells(i + 0, 9) = my2Coll(0).getElementsByClassName("intfield")(0).innertext 'Note
    Cells(i + 0, 12) = my2Coll(0).getElementsByClassName("lastModify")(0).innertext 'Ultima Modifica
    Cells(i + 0, 14) = my2Coll(0).getElementsByClassName("intStrngTitle")(2).innertext 'Utente
    Cells(i + 0, 15) = my2Coll(0).getElementsByClassName("intStrngDesc")(0).innertext 'Zona
    Cells(i + 0, 16) = my2Coll(0).getElementsByClassName("intStrngDesc")(1).innertext 'Indirizzo
    Cells(i + 0, 17) = my2Coll(0).getElementsByClassName("intStrngDesc")(2).innertext 'Interno
    Cells(i + 0, 18) = my2Coll(0).getElementsByClassName("intStrngDesc")(3).innertext 'Posizione
    Cells(i + 0, 19) = my2Coll(0).getElementsByClassName("intStrng")(3).innertext 'Telefono   '<<<<<-------
   
   

    Set my2Coll = myColl(0).getElementsByClassName("clmn box2")
    Cells(i + 0, 5) = my2Coll(0).getElementsByClassName("intStrng")(1).innertext 'Data Ultima Lettura
    Cells(i + 0, 7) = my2Coll(0).getElementsByClassName("selectLong")(0).innertext 'Stato Lettura
    Cells(i + 0, 8) = my2Coll(0).getElementsByClassName("intfield inline")(0).innerhtml 'Cartolina
    Cells(i + 0, 10) = my2Coll(0).getElementsByClassName("intStrng")(2).innertext 'Data Lettura Attuale
    Cells(i + 0, 6) = my2Coll(0).getElementsByClassName("intStrng")(0).innertext 'Lettura Precedente
    Cells(i + 0, 11) = my2Coll(0).getElementsByClassName("intfield")(0).innerhtml 'Lettura Attuale
    Cells(i + 0, 13) = my2Coll(0).getElementsByClassName("file-wrapper")(0).innertext 'Immagine

   
       
Next i



IE.Quit
Set IE = Nothing
End Sub


la riga in questione è la quella marcata con '<<<<<------- cioè
Cells(i + 0, 19) = my2Coll(0).getElementsByClassName("intStrng")(3).innertext 'Telefono


EDIT: ho constatato che mettendo prima della riga On Error Resume Next salta l'errore
ma potete confermarmi che non salta anche altri eventuali errori mandando in vacca il risultato? :lol: perchè non vorrei che se si inceppa salta un id...
Windows 11 - Office 2016 Ita
Avatar utente
xilofono
Utente Junior
 
Post: 80
Iscritto il: 27/11/17 09:52

Re: Data Query da web impossibile

Postdi Anthony47 » 16/12/18 22:52

Per evitare soprese dovresti ripristinare la gestione degli errori dopo la riga che sai puo' andare in errore:
Codice: Seleziona tutto
On Error Resume Next
Cells(i + 0, 19) = my2Coll(0).getElementsByClassName("intStrng")(3).innertext 'Telefono
On Error GoTo 0


Pero' secondo me mettere On Error Resume Next quando cominci la compilazione delle celle per poi mettere On Error GoTo 0 subito prima di Next I e' equivalente: in un caso ti accorgi che qualcosa e' andato storto perche' hai dei run time error, nell'altro te ne accorgi perche' hai delle celle vuote.

"Andato storto" potrebbe essere la definizione sbagliata: infatti potrebbe essere andato tutto bene nella macro ma il sito ha modificato la sua struttura html (cosa che certamente succedera', prima o poi); e quando succedera' devi riesaminare il sorgente e individuare dove sono finite le informazioni.

Ciao
Avatar utente
Anthony47
Moderatore
 
Post: 19196
Iscritto il: 21/03/06 16:03
Località: Ivrea

Re: Data Query da web impossibile

Postdi xilofono » 18/12/18 19:44

grazie come sempre ;) la soluzione che preferisco è quella del run time error perchè non mi interessa tanto il lavoro veloce (con le righe vuote la macro non si ferma mai, poi gli id mancanti si possono recuperare in un secondo momento, sarebbe decisamente più veloce) ma che sia completo al primo colpo, anche a costo di riavviare la macro ogni tanto quando si inceppa e quindi una verifica ogni 30/60 minuti... a volte scarica 10k id senza incepparsi, altre volte va in errore dopo 300... basta un piccolo rallentamento di connessione

per quanto riguarda la struttra del sito, ovviamente può cambiare (è già cambiata) ma me ne accorgo in quanto chi la cambia esegue i lavori (male... altrimenti questa macro non servirebbe neanche... ci sono problemi in fase di scaricamento dei dati, e parliamo di un resp. it di una università... è già il secondo programma che fa e si son ripresentati gli stessi problemi, non dico altro) per conto della società, che purtroppo non ha personale con le competenze per gestire autonomamente tutto
Windows 11 - Office 2016 Ita
Avatar utente
xilofono
Utente Junior
 
Post: 80
Iscritto il: 27/11/17 09:52


Torna a Applicazioni Office Windows


Topic correlati a "Data Query da web impossibile":


Chi c’è in linea

Visitano il forum: Nessuno e 85 ospiti