Condividi:        

word-numerare pagine una sì ed una no

Vuoi potenziare i tuoi documenti Word? Non sai come si fa una macro in Excel? Devi creare una presentazione in PowerPoint?
Oppure sei passato a OpenOffice e non sei sicuro di come lavorare al meglio?

Moderatori: Anthony47, Flash30005

word-numerare pagine una sì ed una no

Postdi patel » 05/09/17 11:38

Devo preparare un Libro Verbali Assemblea Soci, le pagine devono essere 100 vuote e numerate con intestazione, ma il retro della pagina deve essere sbarrato e non numerato e senza intestazione. Pensavo quindi di fare 200 pagine alternando una vuota e una sbarrata e poi stampare fronte/retro ma non so come fare ad alternarle ed a numerare una pagina sì ed una no.
Altre idee sono ben accette.
Grazie
patel
Utente Senior
 
Post: 309
Iscritto il: 24/04/12 16:03

Sponsor
 

Re: word-numerare pagine una sì ed una no

Postdi patel » 05/09/17 12:05

Potete ttrovare un esempio di risultato desiderato qui http://www.filedropper.com/esempio_6
patel
Utente Senior
 
Post: 309
Iscritto il: 24/04/12 16:03

Re: word-numerare pagine una sì ed una no

Postdi wallace&gromit » 05/09/17 15:40

È una soluzione troppo banale stampare tutto quello che va stampato sulla faccia anteriore, poi rimettere il fascicolo girato nella stampante e stampare solo le barrature?
Office2016 + 2019 su win11
Avatar utente
wallace&gromit
Utente Senior
 
Post: 2174
Iscritto il: 16/01/12 14:21

Re: word-numerare pagine una sì ed una no

Postdi patel » 05/09/17 15:55

Grazie, ma ci avevo già pensato anche io, ma chi lo deve fare non è abbastanza vispo da fare una cosa del genere.
patel
Utente Senior
 
Post: 309
Iscritto il: 24/04/12 16:03

Re: word-numerare pagine una sì ed una no

Postdi wallace&gromit » 05/09/17 16:07

Ho provato a creare dei campi con delle formule in cui il numero di pagina viene dimezzato, ma per ora ho fallito miseramente, ci provo ancora e ti faccio sapere.
Office2016 + 2019 su win11
Avatar utente
wallace&gromit
Utente Senior
 
Post: 2174
Iscritto il: 16/01/12 14:21

Re: word-numerare pagine una sì ed una no

Postdi FRIEDRICH » 05/09/17 20:14

Ciao a tutti, :)

un tentativo di numerare solo le pagine dispari secondo le istruzioni trovate qui https://answers.microsoft.com/en-us/msoffice/forum/msoffice_word-mso_other/number-only-odd-pages-consecutively/825db5cf-55b5-4049-b4cc-e77f8bc62301?auth=1


Da notare che le parentesi graffe nel codice di campo non possono essere digitate ma devono essere create con Ctrl+F9.
Inoltre nella formula

{=MOD({PAGE},2) \# "'{=INT({PAGE}/2)+1}';;"} occorre sostituire la prima virgola con un punto e virgola
{=MOD({PAGE};2) \# "'{=INT({PAGE}/2)+1}';;"}

Per le pagine pari ho mantenuto la soluzione adottata da Patel.
File esempio:
http://www.filedropper.com/provaforum-copia
Avatar utente
FRIEDRICH
Utente Junior
 
Post: 32
Iscritto il: 09/07/17 17:14

Re: word-numerare pagine una sì ed una no

Postdi Anthony47 » 06/09/17 01:21

Hai gia' la proposta low-tech /high-efficiency di w&g, piu' la bella proposta di Friederich; ne propongo una terza basata su un file di partenza e una macro.

In dettaglio...
Creati le prime due pagine del documento "utile" e inseriscici quegli elementi che ti interessano (intestazioni, pie' di pagina, filigrana,...)
Poi la macro PatelPrint si occupera' di:
-inserire ulteriori pagine fino ad arrivare al numero di pagine utili desiderate
-inserire una ulteriore pagina "dummy" senza header e senza footer e con la barra trasversare
-stampare una per una le N pagini utili accoppiandola alla pagina dummy

Su questa ultima parte tuttavia non sono certissimo del suo funzionamento, perche' bisogna impostare la stampante affinche' lavori in Duplex (fronte /Retro), ma non ho trovato il comando che imposta questa proprieta' tramite vba (ne' io ho una stampante duplex).
Prova a registrare una macro mentre, sulla tua stampante, mandi in esecuzione una stampa fronte /retro e vedi se il relativo comando viene inserito; poi modifica di conseguenza l'istruzione Application.PrintOut (in fondo alla macro).

In alternativa mandi in stampa su una stampante virtuale. Io ho usato pdfcreator; alla prima stampa ho dato il comando "Metti in coda", quindi tutte le successive stampe sono andate in coda sulla stampante; alla fine ho fatto "Unisci tutti i documenti" e "Stampa documento", ottenendo cosi' un file pdf che contiene una pagina "utile" e una pagina barrata, fino alla fine delle pagine.
Se il risultato piace si manda in stampa il file pdf.

Ho fatto le prove sul file scaricabile qui:
https://www.dropbox.com/s/uh3m6j95arakw ... .docm?dl=0

Il codice della Sub PatelPrint:
Codice: Seleziona tutto
Sub PatelPrint()
Dim hHead As HeaderFooter, cSc As Long
Dim pWidth As Long, pLength As Long
Dim cPages As Long, totPages As Long
'
totPages = 20           '<<< Le pagini utili da stampare
'
'Controlla ci sia una sola Sezione:
cSc = ActiveDocument.Sections.Count
If cSc > 1 Then
    MsgBox ("Il documento contiene piu' Sezioni, l'operazione non puo' essere completata")
    Exit Sub
End If
'
cPages = ActiveDocument.BuiltInDocumentProperties(wdPropertyPages)
'agiunge nuove pagine per arrivare a totPages:
Selection.EndKey Unit:=wdStory
For i = 1 To totPages - cPages
    Selection.InsertBreak Type:=wdPageBreak
Next i
'Aggiunge la pagina "dummy", in fondo:
Selection.EndKey Unit:=wdStory
Selection.InsertBreak Type:=wdPageBreak
Selection.InsertBreak Type:=wdSectionBreakContinuous
cSc = ActiveDocument.Sections.Count
'elimina Headerd e Footers dalla pagina Dummy:
If cSc = 2 Then
    For Each hHead In ActiveDocument.Sections(cSc).Headers
        hHead.LinkToPrevious = False
        hHead.Range.Delete
    Next hHead
    For Each hHead In ActiveDocument.Sections(cSc).Footers
        hHead.LinkToPrevious = False
        hHead.Range.Delete
    Next hHead
Else
'qui non dovremmo arrivarci...
    MsgBox ("Il documento non contiene 2 Sezioni, l'operazione non puo' essere completata")
    Exit Sub
End If
'Inserisce la linea trasversale e la formatta:
Dim nLine As Shape
pWidth = ActiveDocument.PageSetup.PageWidth
pLength = ActiveDocument.PageSetup.PageHeight
Set nLine = ActiveDocument.Shapes.AddLine(beginX:=pWidth * 0.15, beginy:=pLength * 0.15, endx:=pWidth * 0.85, endY:=pLength * 0.85)
  nLine.Line.Weight = 3
  nLine.Line.ForeColor = RGB(0, 0, 0)
  Set nLine = Nothing
'Infine stampa ogni pagina con la Dummy:
For i = 1 To totPages
    Application.PrintOut FileName:="", Range:=wdPrintRangeOfPages, Item:= _
        wdPrintDocumentWithMarkup, Copies:=1, Pages:=i & "," & (totPages + 1), PageType:= _
        wdPrintAllPages, Collate:=True, Background:=False, PrintToFile:=False, _
        PrintZoomColumn:=0, PrintZoomRow:=0, PrintZoomPaperWidth:=0, _
        PrintZoomPaperHeight:=0
Next i
MsgBox ("Stampa completata; chiudere il file SENZA SALVARLO...")
End Sub
La riga marcata <<< va compilata secondo commento; io per prova ho usato 20 pagine

Dopo l'esecuzione della macro suggerisco di non salvare il file, in modo da averlo disponibile per altre personalizzazioni.

Ciao
Avatar utente
Anthony47
Moderatore
 
Post: 19196
Iscritto il: 21/03/06 16:03
Località: Ivrea

Re: word-numerare pagine una sì ed una no

Postdi patel » 06/09/17 07:07

grazie a tutti per le ottime soluzioni, quella di w&g è impraticabile visto che si tratta di una stampante condivisa in un ufficio, proverò le altre 2 anche se mi piace di più quella di Anthony che mi permette di usare soltanto 2 pagine.
Tutto dipende se sarà possibile attivare le macro sul word del pc dell'utilizzatore
patel
Utente Senior
 
Post: 309
Iscritto il: 24/04/12 16:03

Re: word-numerare pagine una sì ed una no

Postdi patel » 06/09/17 09:01

ho testato anche quella di Friederich e funziona prefettamente, occorre inserire le pagine una ad una, ma è da fare una sola volta, quindi ottima in caso di macro disabilitate.
Grazie a tutti
patel
Utente Senior
 
Post: 309
Iscritto il: 24/04/12 16:03

Re: word-numerare pagine una sì ed una no

Postdi Anthony47 » 07/09/17 00:42

La mia macro accoda tante stampe quante sono le pagine fronte/retro; se la tua stampante e' condivisa non si potrebbe escludere che qualche pagina vada perduta (finendo nei fascicoli di altri utenti), se si stampa nell'ora di punta.

Ho quindi modificato la parte finale, quella che procede alla stampa, in modo da stampare a blocchi di circa 25-20 fogli, piu' difficili da perdersi.
Il file disponibile su Dropbox ora ha questa modifica:
Codice: Seleziona tutto
[code]'Infine stampa ogni pagina con la Dummy:
For i = 1 To totPages
    pList = pList & i & "," & (totPages + 1) & ","
    If Len(pList) > 220 Then
        Debug.Print i, Len(pList)
        pList = Left(pList, Len(pList) - 1)
        Application.PrintOut FileName:="", Range:=wdPrintRangeOfPages, Item:= _
            wdPrintDocumentWithMarkup, Copies:=1, Pages:=pList, PageType:= _
            wdPrintAllPages, Collate:=True, Background:=False, PrintToFile:=False, _
            PrintZoomColumn:=0, PrintZoomRow:=0, PrintZoomPaperWidth:=0, _
            PrintZoomPaperHeight:=0
        pList = ""
    End If
Next i
'Stampa l'ultimo blocco di pagine
If Len(pList) > 0 Then
    Debug.Print i, Len(pList)
    pList = Left(pList, Len(pList) - 1)
    Application.PrintOut FileName:="", Range:=wdPrintRangeOfPages, Item:= _
        wdPrintDocumentWithMarkup, Copies:=1, Pages:=pList, PageType:= _
        wdPrintAllPages, Collate:=True, Background:=False, PrintToFile:=False, _
        PrintZoomColumn:=0, PrintZoomRow:=0, PrintZoomPaperWidth:=0, _
        PrintZoomPaperHeight:=0
End If
MsgBox ("Stampa completata; chiudere il file SENZA SALVARLO...")
End Sub[/code]

Ciao
Avatar utente
Anthony47
Moderatore
 
Post: 19196
Iscritto il: 21/03/06 16:03
Località: Ivrea

Re: word-numerare pagine una sì ed una no

Postdi patel » 07/09/17 05:42

Grazie Anthony e Friederich, quando ho detto che l'utente che userà la soluzione non è troppo vispo sono stato troppo buono, scopro ora che non ha Word installato ma OpenOffice, con questo non funziona neanche la formula di Friederich.
Siete per caso esperti anche di Writer ?
patel
Utente Senior
 
Post: 309
Iscritto il: 24/04/12 16:03

Re: word-numerare pagine una sì ed una no

Postdi Anthony47 » 07/09/17 15:24

OpenOffice so che esiste, e so che vale piu' del suo costo, nulla di piu'...
Potresti dargli un file Pdf ottenuto dalla stampa del foglio di Friederich o del mio e alla bisogna si stampa le N pagine che gli servono.

Ciao
Avatar utente
Anthony47
Moderatore
 
Post: 19196
Iscritto il: 21/03/06 16:03
Località: Ivrea

Re: word-numerare pagine una sì ed una no

Postdi patel » 09/09/17 09:48

per chi fosse interessato qui trovate la soluzione su Writer https://forum.openoffice.org/it/forum/v ... 493#p46118
patel
Utente Senior
 
Post: 309
Iscritto il: 24/04/12 16:03

Re: word-numerare pagine una sì ed una no

Postdi patel » 14/09/17 08:37

Ciao Anthony, mi hanno proposto su Writer la macro seguente che crea le pagine invece di stamparle, forse ti può interessare l'approccio
Codice: Seleziona tutto
    doc = thiscomponent
    T = doc.Text
    dim props(1) as new com.sun.star.beans.PropertyValue
    props(0).Name = "BreakType"
    props(0).Value = com.sun.star.style.BreakType.PAGE_BEFORE
    props(1).Name = "PageNumberOffset"
    numpag = int(inputbox("Numero di pagine:"))
    for page = 2 to numpag*2
        if (page mod 2) = 1 then
            pageoffset = int(page/2)+1
        else
            pageoffset = 0
        end if
        props(1).Value = pageoffset
        T.appendParagraph(props())
    next page
patel
Utente Senior
 
Post: 309
Iscritto il: 24/04/12 16:03

Re: word-numerare pagine una sì ed una no

Postdi Anthony47 » 15/09/17 01:46

Ciao Anthony, mi hanno proposto su Writer la macro seguente che crea le pagine invece di stamparle, forse ti può interessare l'approccio
Grazie, ogni trucco e' "buono a sapersi".

Ciao!
Avatar utente
Anthony47
Moderatore
 
Post: 19196
Iscritto il: 21/03/06 16:03
Località: Ivrea


Torna a Applicazioni Office Windows


Topic correlati a "word-numerare pagine una sì ed una no":

consumo pagine web
Autore: nikita75
Forum: Software Windows
Risposte: 4

Chi c’è in linea

Visitano il forum: Nessuno e 78 ospiti