Condividi:        

Rinomina Immagini

Vuoi potenziare i tuoi documenti Word? Non sai come si fa una macro in Excel? Devi creare una presentazione in PowerPoint?
Oppure sei passato a OpenOffice e non sei sicuro di come lavorare al meglio?

Moderatori: Anthony47, Flash30005

Rinomina Immagini

Postdi nicola_na78 » 01/02/17 09:08

Salve a tutti, gentilmente mi date una mano a risolvere questo problema....

Mediante una macro riesco a sapere nella colonna "A" di un foglio excel tutti i nomi delle immagini presenti in una cartella. Ora queste immagini le vorrei rinominare associando nella colonna "B" il nuovo nome da attribuire es.

Colonna "A" immagine1.jpg
Colonna "B" immagine_Rinominata.jpg

Come si puo' fare???

Vi ringrazio a tutti anticipatamente

Buona Giornata....
Nicola

Win7
Office 2007
nicola_na78
Utente Senior
 
Post: 186
Iscritto il: 11/06/10 15:26

Sponsor
 

Re: Rinomina Immagini

Postdi patel » 01/02/17 09:45

Codice: Seleziona tutto
Sub listrename()
    Dim r As Range, fn As String, msg As String
    Const myDir As String = "D:\DATI\prova\" ' <<<<<<<< da modificare
    For Each r In Range("a2", Range("a" & Rows.Count).End(xlUp))
        fn = Dir(myDir & r.Value)
        If fn <> "" Then
            Name myDir & r.Value As myDir & r(, 2).Value
        Else
            msg = msg & vbLf & r.Value
        End If
    Next
    If Len(msg) Then MsgBox "Files not found" & msg
End Sub
patel
Utente Senior
 
Post: 309
Iscritto il: 24/04/12 16:03

Re: Rinomina Immagini

Postdi nicola_na78 » 01/02/17 11:18

Ciao Patel,
Grazie per aver risposto....

ho copiato la macro sostituendo il percorso "Const myDir As String = "D:\DATI\prova\"" con il mio, eseguo la procedura ma non succede nulla mi compare il msgbox"File not found"
nicola_na78
Utente Senior
 
Post: 186
Iscritto il: 11/06/10 15:26

Re: Rinomina Immagini

Postdi patel » 01/02/17 11:31

hai terminato il tuo percorso con \ ?
se non riesci posta un link al tuo file
patel
Utente Senior
 
Post: 309
Iscritto il: 24/04/12 16:03

Re: Rinomina Immagini

Postdi ricky53 » 01/02/17 12:42

Ciao,
se non hai fatto quanto ti ha scritto Patel ... controlla ed avrai risolto.


Se il messaggio è in questa forma:
Files not found
elenco dei nomi dei file contenuti nel tuo intervallo
...
...

allora le possibilità sono due:

1. manca la "\" finale in "myDir"

2. i nomi scritti nella colonna "A" sono diversi (tutti o alcuni) da quelli presenti nella cartella che hai scritto in "myDir"
Dice il vecchio saggio provare e riprovare è l'unica strada per imparare

Più chiara è la vostra spiegazione
Più immediata sarà la nostra soluzione


. . . . . . . . . .
S.O. W10; Office 2003-10-13-16-19
Avatar utente
ricky53
Utente Senior
 
Post: 4565
Iscritto il: 11/04/09 19:29
Località: Italia

Re: Rinomina Immagini

Postdi nicola_na78 » 01/02/17 19:20

Provo e vi faccio sapere

Grazie
nicola_na78
Utente Senior
 
Post: 186
Iscritto il: 11/06/10 15:26

Re: Rinomina Immagini

Postdi nicola_na78 » 01/02/17 19:26

Funziona alla perfezione.... era \ il problema :lol:

Grazie a tutti, alla prossima

Nicola
nicola_na78
Utente Senior
 
Post: 186
Iscritto il: 11/06/10 15:26

Re: Rinomina Immagini

Postdi scanacc » 02/02/17 22:27

Scusa Nicola potresti postare la macro mediante la quale riesci a sapere nella colonna "A" di un foglio excel tutti i nomi delle immagini presenti in una cartella? Ciao e grazie
scanacc
Utente Senior
 
Post: 350
Iscritto il: 06/12/15 10:30

Re: Rinomina Immagini

Postdi ricky53 » 02/02/17 23:28

Ciao,
prova questo codice
Codice: Seleziona tutto
Option Explicit

Sub Elenco_file_in_Percorso()
    Dim RR As Integer, MioPercorso As String, MioFile As String, Nome_Precedente As String
   
    Application.ScreenUpdating = False
    Sheets("Foglio1").Select ' <<=== QUI devi scrivere il nome del foglio sul quale scrivere i vari dati
    RR = Range("A" & Rows.Count).End(xlUp).Row
    Range("A1:A" & RR).ClearContents
    Range("A1") = "Nome File"
   
    MioPercorso = "E:\Temp\" ' <<===== QUI devi scrivere il tuo percorso
    RR = 2
    MioFile = Dir(MioPercorso & "*.xls*")
    Do While MioFile <> ""
        Cells(RR, "A") = MioFile
        RR = RR + 1
        MioFile = Dir()
    Loop
    Columns("A:A").EntireColumn.AutoFit
   
    Application.ScreenUpdating = True
    MsgBox "Elaborazione Terminata. Trovati " & RR - 2 & "  file"
End Sub


Per provarlo utilizza un nuovo file excel
Dice il vecchio saggio provare e riprovare è l'unica strada per imparare

Più chiara è la vostra spiegazione
Più immediata sarà la nostra soluzione


. . . . . . . . . .
S.O. W10; Office 2003-10-13-16-19
Avatar utente
ricky53
Utente Senior
 
Post: 4565
Iscritto il: 11/04/09 19:29
Località: Italia

Re: Rinomina Immagini

Postdi nicola_na78 » 07/02/17 10:36

Ciao Scanacc, scusa se non ti ho risposto prima...
ecco il codice per visualizzare nella colonna "A" il nome di tutti i file presenti in una cartella:

Codice: Seleziona tutto
Sub leggiCartella()
Dim riga As Integer, fs As String
Percorso = "C:\Users\....\"   '------->Metti la tua directory
ChDir percorso
riga = 0
Columns("A:A").ClearContents
fs = Dir("*.*")
If fs = "" Then Exit Sub
While fs <> ""
riga = riga + 1
Cells(riga, 1) = fs
fs = Dir
Wend
End Sub


Buona giornata
nicola_na78
Utente Senior
 
Post: 186
Iscritto il: 11/06/10 15:26

Re: Rinomina Immagini

Postdi ricky53 » 07/02/17 11:54

Ciao,
io ti avevo proposto la ricerca solo dei file "excel",
Nicola quella di tutti i file.

Se vuoi avere solo i file delle immagini cambia
Codice: Seleziona tutto
MioFile = Dir(MioPercorso & "*.xls*")


con
Codice: Seleziona tutto
MioFile = Dir(MioPercorso & "*.jpg")

per avere i file con estensione "jpg"

oppure utilizza l'estensione che ti occorre: bmp, png, ....
Dice il vecchio saggio provare e riprovare è l'unica strada per imparare

Più chiara è la vostra spiegazione
Più immediata sarà la nostra soluzione


. . . . . . . . . .
S.O. W10; Office 2003-10-13-16-19
Avatar utente
ricky53
Utente Senior
 
Post: 4565
Iscritto il: 11/04/09 19:29
Località: Italia


Torna a Applicazioni Office Windows


Topic correlati a "Rinomina Immagini":


Chi c’è in linea

Visitano il forum: Nessuno e 152 ospiti